如何使用提供的工具而不是规则构建的工具编写Bazel测试规则？

我有一个测试工具（大致上是一个差分工具），它接受两个输入，并返回一个输出（两个输入之间的差异）和一个返回代码（如果两个输入匹配，则返回0，否则返回1）。它内置于Kotlin中，可在my repo中的

//java/fr/enoint/phosphore

上获得

我想编写一个规则，测试由某个对象生成的文件是否与存储库中已经存在的引用文件相同。我用

ctx.actions.run

尝试了一些东西，问题是设置了

test=True

的规则需要返回由该规则生成的可执行文件（因此不是规则提供的工具）。然后，我尝试将其包装在shell脚本中，如下所示：

def _phosphorus_test_impl(ctx):
    output = ctx.actions.declare_file("{name}.phs".format(name = ctx.label.name))
    script = phosphorus_compare(
        ctx,
        reference = ctx.file.reference,
        comparison = ctx.file.comparison,
        out = output,
    )

    ctx.actions.write(
        output = ctx.outputs.executable,
        content = script,
    )

    runfiles = ctx.runfiles(files = [ctx.executable._phosphorus_tool, ctx.file.reference, ctx.file.comparison])
    return [DefaultInfo(runfiles = runfiles)]

phosphorus_test = rule(
    _phosphorus_test_impl,
    attrs = {
        "comparison": attr.label(
            allow_single_file = [".phs"],
            doc = "File to compare to the reference",
            mandatory = True,
        ),
        "reference": attr.label(
            allow_single_file = [".phs"],
            doc = "Reference file",
            mandatory = True,
        ),
        "_phosphorus_tool": attr.label(
            default = "//java/fr/enoent/phosphorus",
            executable = True,
            cfg = "host",
        ),
    },
    doc = "Compares two files, and fails if they are different.",
    test = True,
)

（

p\u compare

只是一个生成实际命令的宏。）

然而，这种方法有两个问题：

• 输出不能以这种方式声明。它与任何行动都没有联系（Bazel对此表示不满）。也许我真的不需要为测试声明输出？当测试失败时，Bazel是否使测试文件夹中的任何内容可用
• 测试运行时，运行工具所需的运行文件似乎不可用：

  java/fr/enoint/phosphone/phosphone:line 359:/home/kernald/.cache/bazel/_bazel_kernald/58c025fbb926eac6827117ef80f7d2fa/sandbox/linux sandbox/1979/execroot/fr_enoint/bazel out/k8 fastbuild/bin/tools/phosphone/tests/should_pass.runfiles/remotejdk11_linux/bin/java:没有这样的文件或目录

---

总的来说，我觉得使用shell脚本只是添加了一个不必要的间接寻址，并丢失了一些上下文（例如工具的运行文件）。理想情况下，我只使用

ctx.actions.run

并依赖其返回代码，但这似乎不是一个选项，因为测试显然需要生成一个可执行文件。编写这样一个规则的正确方法是什么？

事实证明，生成脚本是正确的方法，据我所知，不可能返回指向

ctx.actions.run的某种指针。测试规则需要有一个可执行的输出

关于工具生成的输出文件：根本不需要声明它。我只需要确保它是在
$TEST\u UNDECLARED\u OUTPUTS\u DIR
中生成的。此目录中的每个文件都将由Bazel添加到名为
output.zip
的存档中。这是（部分）记录的

关于运行文件，我有这个工具的二进制文件，但没有自己的运行文件。以下是固定规则：

def _phosphorus_test_impl(ctx):
    script = phosphorus_compare(
        ctx,
        reference = ctx.file.reference,
        comparison = ctx.file.comparison,
        out = "%s.phs" % ctx.label.name,
    )

    ctx.actions.write(
        output = ctx.outputs.executable,
        content = script,
    )

    return [
        DefaultInfo(
            runfiles = ctx.runfiles(
                files = [
                    ctx.executable._phosphorus_tool,
                    ctx.file.reference,
                    ctx.file.comparison,
                ],
            ).merge(ctx.attr._phosphorus_tool[DefaultInfo].default_runfiles),
            executable = ctx.outputs.executable,
        ),
    ]

def phosphorus_test(size = "small", **kwargs):
    _phosphorus_test(size = size, **kwargs)

_phosphorus_test = rule(
    _phosphorus_test_impl,
    attrs = {
        "comparison": attr.label(
            allow_single_file = [".phs"],
            doc = "File to compare to the reference",
            mandatory = True,
        ),
        "reference": attr.label(
            allow_single_file = [".phs"],
            doc = "Reference file",
            mandatory = True,
        ),
        "_phosphorus_tool": attr.label(
            default = "//java/fr/enoent/phosphorus",
            executable = True,
            cfg = "target",
        ),
    },
    doc = "Compares two files, and fails if they are different.",
    test = True,
)

关键部分是返回的
DefaultInfo
中的
.merge（ctx.attr.\u工具[DefaultInfo].default\u运行文件）

我在配置上也犯了一个小错误，因为这个测试是在目标配置上运行的，而不是在主机上运行，它已经被相应地修复了