Asp classic 如何在经典asp中检查internet的可用性？

我正在我的代码中调用一个Web服务。我想添加验证以检查internet连接是否可用

如果internet连接不可用，则应提示internet连接不可用

---

请向我提供检查此问题的代码。

尝试ping目标服务器并查看结果，如果您得到答复，请继续您的请求

---

请参阅以下url使用此功能抓取网页，调整超时以满足您的需要。这假设网站返回有效的200请求，如果网站关闭或返回404或您可能需要调整的内容

Function GetPage(inURL) ' scrapes the URL page, HTML, XML, JSON, whatever
  Dim O(2), xmlServerHttp, error, ServerStatus, responseText
  Error = False
  Set xmlServerHttp = Server.CreateObject("Msxml2.ServerXMLHTTP.6.0")
    lResolve = 1000
    lConnect = 3500
    lSend = 1000
    lReceive = 2000
  xmlServerHttp.setTimeouts lResolve, lConnect, lSend, lReceive
    On Error Resume Next
  xmlServerHttp.open "GET", inURL, false
  xmlServerHttp.send()
  If Err.Number <> 0 Then
    ServerStatus="timeout"
    error=True
  Else
    ServerStatus = xmlServerHttp.status
    If ServerStatus = 200 Then responseText=xmlServerHttp.responseText Else error=true
  End If
  On Error GoTo 0
  O(0) = responseText
  O(1) = Error
  O(2) = ServerStatus
  Set xmlServerHttp = nothing
  GetPage=O
End function

---

她要求使用经典的ASP，所以也许可以改为：您可以使用我的

CheckServerPulse

方法，可以找到它。（只需传递承载web服务的服务器的IP）我无法访问承载web服务的服务器。请建议我另一种方法。你不需要访问服务器，你只需要它的IP地址。其余部分由经典的ASP代码完成。

 data = GetPage(url)
 body = data(0)
 error = data(1)
 ServerStatus = data(2)

 if error then
   response.write "Sorry no internet"
 else
   response.write "Internet found!"
 end if