Excel 嵌套VLOOKUP函数

我试图得到一个

VLOOKUP

，如果发现一个大于$100的值，那么给出的值是0

然后，我希望函数执行以下操作：从表中计算值，然后执行另一个

VLOOKUP

以确定要添加的附加值。我还需要一个

IFERROR

语句，以允许将错误显示为空白

到目前为止我有

=IFERROR(IF(VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)>100,
         "$0.00",
         (VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE) +
         VLOOKUP(B27,'Delivery Calculator'!A14:C17,2,False)))),
         "")

---

有人能告诉我这个/可能的解决方案有什么问题吗？我得到一个关于参数太少的错误，可能只是在这个函数上花费了太多时间。额外的眼睛将不胜感激

你的后背有问题。如果我们将格式设置得更具可读性，则您的公式就是这样的：

=IFERROR(
    IF(
        VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)>100,
        "$0.00",
        (
            VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)+
            VLOOKUP(B27,'Delivery Calculator'!A14:C17,2,False)
        )
    )
),"")

您只将一个参数传递给

IFERROR

，最后的

，“”）

在

IFERROR

之外。。。应该是：

=IFERROR(
    IF(
        VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)>100,
        "$0.00",
        VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)+
        VLOOKUP(B27,'Delivery Calculator'!A14:C17,2,False)
    )
,"")

或者，如果没有空格：

=IFERROR(IF(VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)>100,"$0.00",VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)+VLOOKUP(B27,'Delivery Calculator'!A14:C17,2,False)),"")

---

如果添加空格/换行符以将公式分成逻辑部分（按语法），则可以很容易地看到主要错误发生的位置

=IFERROR(
    IF(
        VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)>100,
        "$0.00",
        (
            VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)
            +
            VLOOKUP(B27,'Delivery Calculator'!A14:C17,2,False)
        )
        )
    ),
    ""
)

注意，在同一级别上有两个右括号？很明显，这是一个错误，其中一个应该删除

因此，您的公式变成：

=IFERROR(
    IF(
        VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)>100,
        "$0.00",
        (
            VLOOKUP(F43,'Delivery Calculator'!A6:B11,2,TRUE)
            +
            VLOOKUP(B27,'Delivery Calculator'!A14:C17,2,False)
        )
    ),
    ""
)

作为旁注，您应该验证

VLOOKUP

中的

TRUE

值实际上是

TRUE

。这些值通常表示为

FALSE