gnuplot-如何使zmin等于z轴上的zmax保持自动缩放

如何使z轴上的缩放结果在xy平面上对称：zmax=zmin，保持z轴上的自动缩放处于启用状态？（GNUplot 5.0）

GNUplot中是否存在这种可能性，或者只能使用固定范围的cbrange

用于极性热图绘制的示例：

reset
set terminal pngcairo size 800,800
set output '3d-polar.png'
set lmargin at screen 0.05
set rmargin at screen 0.85
set bmargin at screen 0.1
set tmargin at screen 0.9

set pm3d map
unset key
set multiplot

set parametric
set grid xtics ytics

set angles degree
set autoscale xfix
set autoscale yfix
set autoscale zfix
set palette model RGB defined ( 0"black", 1"white", 2"grey")
splot '_FullWV.dat' u ($2*cos($1)):($2*sin($1)):3
unset multiplot

---

_FullWV.dat文件是。

您可以使用

stats

提取第三列的最小值和最大值，并相应地定义cbrange

reset
set terminal pngcairo size 800,800
set output '3d-polar.png'
set lmargin at screen 0.05
set rmargin at screen 0.85
set bmargin at screen 0.1
set tmargin at screen 0.9

set pm3d map
unset key
set multiplot

stats '_FullWV.dat' using 3
max(a,b) = (a>b) ? a : b

Z_MAX = max(-STATS_min, STATS_max)

set parametric
set grid xtics ytics

set angles degree
set autoscale xfix
set autoscale yfix
#set zrange [-Z_MAX : Z_MAX]
set cbrange [-Z_MAX : Z_MAX]

set palette model RGB defined ( 0"black", 1"white", 2"grey")
splot '_FullWV.dat' u ($2*cos($1)):($2*sin($1)):3
unset multiplot

---

谢谢你的主意！为了结束这个问题-你知道如何在重做时替换输出png文件吗？非常感谢，你救了我一天）如果你能帮我做另一件事，你将非常感谢。一旦我被允许（当我在这里的声誉超过15分时），我会很高兴向上投票