Gnuplot和非结构化数据有可能吗

到目前为止，我已经能够使用

pm3d

为二维结构化数据生成二维等高线图。但是，我有一些数据文件，其中包含一些非结构化网格的流

可视化

，我正试图在结构化数据旁边绘制这些非结构化网格。到目前为止，我找到了一些指向如何生成等高线图的脚本的链接，但似乎唯一的方法是通过

dgrid3d

，它只生成等高线，而不是像图中这样的曲面流

我只是想知道是否有更好的方法使用

gnuplot工具生成类似的绘图

非常感谢你的帮助
 dgrid3d只生成线是不正确的。这是数据的预处理步骤，可以使用所需的任何样式打印数据

下面是一个使用预先生成的高斯分布随机点集的示例。所显示的代码应适用于gnuplot 5.2或更高版本。在当前的gnuplot版本中，一个稍微简单的plot命令是可能的，但所示的命令仍然有效

set view map
unset key
set cbtics format ""  # no tic labels on the colorbar
set palette cubehelix negative

#
# Generate a grid from point density of previously-generated Gaussian
#
set dgrid3d 50,50 gauss kdensity

#
# Make all contour lines black
#
set contour base
set cntrparam levels incremental 0,200
set cntrparam firstlinetype 101
set for [L=101:110] linetype L linecolor "black" dashtype solid
set style textbox opaque noborder

set pm3d explicit at b

#
# Order of drawing is important.
# First the surface, then the lines, then the labels
#
splot $random using 1:2:(1) with pm3d, \
      '' using 1:2:(1) with lines nosurface, \
      '' using 1:2:(1):("") with labels boxed

你好，伊桑，非常感谢你的帮助！在测试上面的脚本时，它似乎不喜欢设置cntrparm firstlinetype 101。您使用的是哪个版本的gnuplot？我使用的是5.4~怪异。在发布之前，我测试了5.2.6的所有版本。随附的图I是使用5.4.0生成的。好的，你可以注释掉那些线，但它会以默认的颜色顺序绘制轮廓。你说你的结果“类似于上面的绘图”，这反过来又类似于你提供的示例绘图。请显示您当前的绘图，并描述错误、意外、缺失或与您想要的不同之处。因为我不知道你的目标是什么，仅仅发送数据是没有帮助的。