Macos javafxpackager在Mac OS X上不正确地定位应用程序文件夹

我正在使用MacOSXMavericks和JDK1.7.45使用javafxpackager工具为Mac打包Swing应用程序。不幸的是，最终结果如下（隐藏图标/名称）：

向右滚动一点可以澄清图片：

---

显然，应用程序映像在DMG中的位置不正确。我不知道这是怎么发生的，也不知道我可能做了什么触发了这一点，我只是使用了标准的NetBeans打包脚本。任何提示或指示都将不胜感激。

好的，结果很简单，工具似乎生成了脚本：

tell application "Finder"
  tell disk "MyApplication"
    open
    set current view of container window to icon view
    set toolbar visible of container window to false
    set statusbar visible of container window to false

    -- size of window should match size of background
    set the bounds of container window to {400, 100, 917, 370}

    set theViewOptions to the icon view options of container window
    set arrangement of theViewOptions to not arranged
    set icon size of theViewOptions to 128
    set background picture of theViewOptions to file ".background:background.png"

    -- Create alias for install location
    make new alias file at container window to POSIX file "/Applications" with properties {name:"Applications"}

    -- First, move all files far enough to be not visible if user has "show hidden files" option set
    -- Note: this only make sense if "hidden" files are also visible on the build system
    --   otherwise command below will only return list of non-hidden items
    set filesToHide to the name of every item of container window
    repeat with theFile in filesToHide
         set position of item theFile of container window to {1000, 0}
    end repeat

    -- Now position application and install location
    set position of item "MyApplication" of container window to {120, 135}
    set position of item "Applications" of container window to {390, 135}

    close
    open
    update without registering applications
    delay 5
  end tell
end tell

这是有问题的，因为它只延迟5秒（我假设是秒），所以我把它增加到20秒，它就工作了。脚本应放在

package/macosx/MyApplication dmg setup.scpt

下