Stata：合并多个estpost结果

我试图将我从estpost表格中获得的cumpct结果与我从estpost tabstat中获得的汇总统计数据结合在一个esttab输出中。但是，我使用下面的代码得到一个空的cumpct列。我相信问题源于我存储cumpct矩阵的方式，但不幸的是，我找不到解决方案

clear
input float A wage
1 100
3 450
2 180
2 190
1  70
4 880
3  65
5  40
1  144
4  28
5  110
end



     * tabulation
        estpost tabulate A
        matrix cumpct=e(cumpct)

     * Summary Stats
        estpost tabstat wage, ///
        statistics(mean sd p25 p50 p75) ///
        columns(statistics) by(A) 

     * Esttab
        esttab ., replace  ///
        cells("cumpct mean sd p25 p50 p75")

我得到的结果如下：

------------------------------------------------------------------------------------------
                      (1)                                                                 
                                                                                          
                   cumpct         mean           sd          p25          p50          p75
------------------------------------------------------------------------------------------
1                             104.6667     37.22007           70          100          144
2                                  185     7.071068          180          185          190
3                                257.5     272.2361           65        257.5          450
4                                  454      602.455           28          454          880
5                                   75     49.49747           40           75          110
Total                         205.1818     252.3192           65          110          190
------------------------------------------------------------------------------------------
N                      11                                                                 
------------------------------------------------------------------------------------------

. 

---

在运行后的示例中：

estpost tabstat wage, ///
        statistics(mean sd p25 p50 p75) ///
        columns(statistics) by(A)

e（）中存储的内容是：

所以当你跑步的时候

esttab ., replace  ///
        cells("cumpct mean sd p25 p50 p75")

未找到cumpct，因此将丢失

可以使用一个小的辅助程序手动将累积矩阵添加到e（）

clear
input float A wage
1 100
3 450
2 180
2 190
1  70
4 880
3  65
5  40
1  144
4  28
5  110
end

// Helper program
cap program drop add_e
program add_e, eclass
    args name matrix
    ereturn matrix `name' = `matrix'
end

* tabulation
estpost tabulate A
matrix cumpct=e(cumpct)

* Summary Stats
estpost tabstat wage, ///
statistics(mean sd p25 p50 p75) ///
columns(statistics) by(A) 

add_e "cumpct" cumpct

* Esttab
esttab ., replace  ///
cells("cumpct mean sd p25 p50 p75")

结果:

------------------------------------------------------------------------------------------
                      (1)                                                                 
                                                                                          
                   cumpct         mean           sd          p25          p50          p75
------------------------------------------------------------------------------------------
1                27.27273     104.6667     37.22007           70          100          144
2                45.45455          185     7.071068          180          185          190
3                63.63636        257.5     272.2361           65        257.5          450
4                81.81818          454      602.455           28          454          880
5                     100           75     49.49747           40           75          110
Total                         205.1818     252.3192           65          110          190
------------------------------------------------------------------------------------------
N                      11                                                                 
------------------------------------------------------------------------------------------

---

2月27日，您承诺“从现在起，我将添加一个示例数据集和我尝试的代码！”是的，我表示歉意。我编辑了我的问题，并在上面添加了一个示例数据。我不使用这套命令，但您已经让您的问题更适合使用这些命令的人。

------------------------------------------------------------------------------------------
                      (1)                                                                 
                                                                                          
                   cumpct         mean           sd          p25          p50          p75
------------------------------------------------------------------------------------------
1                27.27273     104.6667     37.22007           70          100          144
2                45.45455          185     7.071068          180          185          190
3                63.63636        257.5     272.2361           65        257.5          450
4                81.81818          454      602.455           28          454          880
5                     100           75     49.49747           40           75          110
Total                         205.1818     252.3192           65          110          190
------------------------------------------------------------------------------------------
N                      11                                                                 
------------------------------------------------------------------------------------------