Windows installer 如何通过NSIS在MUI_页面_组件中实现工具提示效果？

目前，我正在通过NSIS为我们的产品开发一个安装包，但是，我们的产品经理不喜欢MUI_PAGE_组件的默认样式，因此我想知道如何通过NSIS实现组件页面，同时删除说明框，当鼠标悬停在组件项上时，工具提示将给出说明

!define MUI_COMPONENTSPAGE_NODESC 

---

将从组件页面中删除描述

太好了，这就是我需要的，我想我必须编写一个自定义dll并从脚本中调用，非常感谢！

!define MUI_COMPONENTSPAGE_NODESC
!include MUI2.nsh
!include LogicLib.nsh

!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE English

Section Foo SID_FOO
SectionEnd
Section Bar SID_BAR
SectionEnd
Section Baz SID_BAZ
SectionEnd

var ttip

!define WS_POPUP 0x80000000
!define TTF_SUBCLASS    0x010
!define /math TTM_ACTIVATE ${WM_USER} + 1
!define /math TTM_ADDTOOL ${WM_USER} + 4
!define /math TTM_SETTOOLINFO ${WM_USER} + 9
!define /math TTM_TRACKACTIVATE ${WM_USER} + 17
!define /math TTM_TRACKPOSITION ${WM_USER} + 18
!define /math TTM_POP ${WM_USER} + 28
!define /math TTM_POPUP ${WM_USER} + 34

Function .onMouseOverSection
${If} $0 = -1
killtip:
    SendMessage $ttip ${TTM_ACTIVATE} 0 0
    Return
${EndIf}
StrCpy $2 ""
${If} $ttip = 0
    System::Call 'USER32::CreateWindowEx(i${WS_EX_TOPMOST},t"tooltips_class32",i,i${WS_POPUP},i,i,i,i,i0,i,i,i)i.r2'
    StrCpy $ttip $2
${EndIf}
StrCpy $1 ""
${Select} $0
${Case} ${SID_FOO}
    StrCpy $1 "Foo?"
${Case} ${SID_BAR}
    StrCpy $1 "BarBarBar"
${Case} ${SID_BAZ}
    StrCpy $1 "Baaaaaaaaaaaaaaaaaz!!!"
${EndSelect}
FindWindow $3 "#32770" "" $HWNDPARENT
System::Call '*(i40,i${TTF_SUBCLASS},i$3,i0x408,i,i,i,i,i0,tr1)i.r1'
SendMessage $2 ${TTM_ADDTOOL} 0 $1
SendMessage $ttip ${TTM_SETTOOLINFO} 0 $1
SendMessage $ttip ${TTM_ACTIVATE} 1 0
SendMessage $ttip ${TTM_TRACKACTIVATE} 1 $1
System::Free $1
${If} $2 <> 0
    ;BUGFIX: Sometimes we get an initial onMouseOverSection call with no place to show a tip
    System::Call 'USER32::IsWindowVisible(ir3)i.r0'
    ${IfThen} $0 = 0 ${|} goto killtip ${|}
${EndIf}
FunctionEnd