Xml 对不同同级节点的引用

如何在xsl中实现这一点？我曾尝试将其用于

应用模板

，但运气不佳

test.xml

<row>
    <table name="Person">
        <tuple>
            <val>BOB</val>
            <val>BILL</val>
        </tuple>
    </table>
    <table name="Age">
        <tuple>
            <val>18</val>
            <val>21</val>
        </tuple>
    </table>
</row>

上下快速移动
账单
18
21

期望输出

<row>
    <data>
        <name>BOB</name>
        <age>18</age>
    </data>
    <data>
        <name>BILL</name>
        <age>21</age>
    </data>
</row>

上下快速移动
18
账单
21

我不知道用XSL进行解构绑定的任何方法；我很想知道是否有一个当地的成语

无论如何：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/row">
  <row>
  <xsl:for-each select="table[@name='Person']/tuple/val">
    <xsl:variable name="i" select="position()" />
    <data>
      <name><xsl:value-of select="." /></name>
      <age><xsl:value-of select="../../../table[@name='Age']/tuple/val[position()=$i]" /></age>
    </data>
  </xsl:for-each>
  </row>
</xsl:template>

</xsl:stylesheet>

诚然，这不是最漂亮的XSL样式表，但它确实做到了这一点

---

当然，这里假设每个姓名条目都有一个匹配的年龄条目。如果您的姓名和年龄条目在原始XML文档中由id交叉引用，这将非常有用。

另一种方法是使用

xsl:key

根据元素的位置查找

val

元素

 <xsl:key name="values" match="val" use="count(preceding-sibling::val)" />

然后，您可以使用键获取构成

数据
元素的所有
val
元素

<xsl:apply-templates select="key('values', position() - 1)" />

除了凌乱的
xsl:choose
之外，这个解决方案也是相当通用的

<xsl:apply-templates select="key('values', position() - 1)" />

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes" />

    <xsl:key name="values" match="val" use="count(preceding-sibling::val)" />

    <xsl:template match="/row">
        <row>
            <xsl:for-each select="table[1]/tuple/val">
                <data>
                    <xsl:apply-templates select="key('values', position() - 1)" />
                </data>
            </xsl:for-each>
        </row>
    </xsl:template>

    <xsl:template match="val">
        <xsl:variable name="name">
            <xsl:choose>
                <xsl:when test="../../@name = 'Person'">name</xsl:when>
                <xsl:otherwise><xsl:value-of select="translate(../../@name, 'ABCDEFGHIJKLMNOPQRSTUVWXYZ', 'abcdefghijklmnopqrstuvwxyz')" /></xsl:otherwise>
            </xsl:choose>
        </xsl:variable>
        <xsl:element name="{$name}">
            <xsl:value-of select="." />
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>