Assembly 使用8位寄存器添加两个32位数字

这里的目标是两个加上两个32位的数字，这些数字存储在小端符号中。这些数字存储在以下存储单元中：

• 第一个号码：0x3000-0x3003
• 秒数：0x4000-0x4003
• 结果应进入：0x5000-0x5003

以下是我的实施，从干燥原则来看，这不是很有效：

ARG1 EQU 3000H
ARG2 EQU 4000H
RESULT EQU 5000H

ORG 0000H
    
MOV DPTR, #ARG1 + 0
MOV A, #12H
MOVX @DPTR, A
MOV DPTR, #ARG1 + 1
MOV A, #34H
MOVX @DPTR, A
MOV DPTR, #ARG1 + 2
MOV A, #00H
MOVX @DPTR, A
MOV DPTR, #ARG1 + 3
MOV A, #00H
MOVX @DPTR, A

MOV DPTR, #ARG2 + 0
MOV A, #00H
MOVX @DPTR, A
MOV DPTR, #ARG2 + 1
MOV A, #00H
MOVX @DPTR, A
MOV DPTR, #ARG2 + 2
MOV A, #56H
MOVX @DPTR, A
MOV DPTR, #ARG2 + 3
MOV A, #78H
MOVX @DPTR, A

MOV DPTR, #ARG1 + 0
MOVX A, @DPTR
MOV R0, A
MOV DPTR, #ARG2 + 0
MOVX A, @DPTR
ADDC A, R0
MOV DPTR, #RESULT + 0
MOVX @DPTR, A

MOV DPTR, #ARG1 + 1
MOVX A, @DPTR
MOV R0, A
MOV DPTR, #ARG2 + 1
MOVX A, @DPTR
ADDC A, R0
MOV DPTR, #RESULT + 1
MOVX @DPTR, A

MOV DPTR, #ARG1 + 2
MOVX A, @DPTR
MOV R0, A
MOV DPTR, #ARG2 + 2
MOVX A, @DPTR
ADDC A, R0
MOV DPTR, #RESULT + 2
MOVX @DPTR, A

MOV DPTR, #ARG1 + 3
MOVX A, @DPTR
MOV R0, A
MOV DPTR, #ARG2 + 3
MOVX A, @DPTR
ADDC A, R0
MOV DPTR, #RESULT + 3
MOVX @DPTR, A

JNC EXIT
INC A
MOVX @DPTR, A

EXIT:
  NOP
  SJMP $

END

问题：我想知道是否有一种方法可以使用循环实现此功能并减少重复指令

例如，此示例在直接寻址模式下使用8位内存地址时使用寄存器组：

ORG 0H

MOV 30H, #12H
MOV 31H, #34H
MOV 32H, #00H
MOV 33H, #00H

MOV 40H, #00H
MOV 41H, #00H
MOV 42H, #56H
MOV 43H, #78H

MOV R0, #30H    ;pointer of bank 0
MOV R1, #50H    ;result storage bank 0
MOV R2, #4      ;counter
SETB RS0
MOV R1, #40H    ;pointer bank 1
CLR RS0
CLR C 

LOOP:
  MOV A, @R0
  SETB RS0
  ADDC A, @R1
  INC R1
  CLR RS0
  MOV @R1, A
  INC R0
  INC R1
  DJNZ R2, LOOP

  JNC EXIT
  INC @R1

EXIT:
  NOP
  SJMP $

END

---

（我使用的是µVision IDE）

知道外部内存地址的低位字节是相同的（00h），可以简化代码。这意味着我们可以在循环的整个迭代过程中保持数据指针DPTR（地址82h处的特殊功能寄存器

DPL

的低位字节不变。
要在3个外部DWORD之间切换，我们只需更改DPTR的高位字节（地址83h处的特殊功能寄存器

DPH

）

为了在所有涉及的DWORD中转到下一个更高的字节，我在循环的底部使用了

INC 82h

指令。使用

INC

（而不是

ADD

）非常重要，因为

INC

不会更改我们希望在循环中传播的进位标志C

  MOV  82h, #00h   ; DPL = 00h
  MOV  R1, #4      ; Each dword has 4 bytes
  CLR  C           ; Clear carry so 1st ADDC works fine
LOOP:
  MOV  83h, #30h   ; DPH = 30h --> DPTR == [3000h,3003h]
  MOVX A, @DPTR    ; Load byte from 1st dword
  MOV  R0, A       ; Free the accumulator (MOVX needs A)
  MOV  83h, #40h   ; DPH = 40h --> DPTR == [4000h,4003h]
  MOVX A, @DPTR    ; Load byte from 2nd dword
  ADDC A, R0       ; Addition defines carry
  MOV  83h, #50h   ; DPH = 50h --> DPTR == [5000h,5003h]
  MOVX @DPTR, A    ; Store byte in 3rd dword
  INC  82h         ; DPL++
  DJNZ R1, LOOP    ; Decrement counter and loop back if not zero

  ; Process the final carry as needed

---

是的，使用循环是绝对可能的，并且应该使用它来完成。查看您的代码，哪些指令相似或相等，并查看指令集哪些指令可能有用。@thebusybee您能更具体一点吗？如何使用8位寄存器引用2字节内存地址？一个接一个。。。或者，如果你指的是如何访问

DPTR

：在

DPH

和

DPL

@thebusybee-hmm中有两半，我不确定你的意思。为了使用循环，我必须将内存地址存储在寄存器中，以提取单个字节，增加它们，等等。但我不能在8位寄存器（R0，R1…）中存储像

0x3000

这样的2字节内存地址。同样，请阅读文档

DPTR

是一个16位寄存器。