根据NSIS中的CurrentUser/AllUsers安装模式定制INSTDIR

根据

MultiUser.nsh

的宏，将基于

$MultiUser.InstallMode

的值将

$INSTDIR

设置为以下路径之一：

• 当前用户：

  “$LOCALAPPDATA\${MULTIUSER\u INSTALLMODE\u INSTDIR}”

• 用户：

  “$PROGRAMFILES\${MULTIUSER\u INSTALLMODE\u INSTDIR}”

基本上，宏将

$MULTIUSER\u INSTALLMODE\u INSTDIR

附加到

$LOCALAPPDATA

或

$PROGRAMFILES

中，并将其用作默认安装路径

我需要的只是CurrentUser安装模式的一个稍微不同的路径，即：

“$LOCALAPPDATA\Programs\${MULTIUSER\u INSTALLMODE\u INSTDIR}”

我怎样才能做到这一点

---

如果用户有机会选择installMode，则在做出此选择后，必须设置默认的

$INSTDIR

值。

您可以使用多用户安装模式函数回调函数define进行更改：

Name "MultiUser test"
!define MULTIUSER_INSTALLMODE_INSTDIR "$(^Name)"
!define MULTIUSER_EXECUTIONLEVEL Highest
!define MULTIUSER_INSTALLMODE_FUNCTION onMultiUserModeChanged
!define MULTIUSER_MUI
!include MultiUser.nsh
!include MUI2.nsh
!include LogicLib.nsh

!insertmacro MULTIUSER_PAGE_INSTALLMODE
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES 
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES 
!insertmacro MUI_LANGUAGE English

Function .onInit
    !insertmacro MULTIUSER_INIT
FunctionEnd
Function un.onInit
    !insertmacro MULTIUSER_UNINIT
FunctionEnd

Function onMultiUserModeChanged
${If} $MultiUser.InstallMode == "CurrentUser"
    StrCpy $InstDir "$LocalAppdata\Programs\${MULTIUSER_INSTALLMODE_INSTDIR}"
${EndIf}
FunctionEnd

Section
MessageBox MB_OK $InstDir
Quit ; This is just a demo

SetOutPath $InstDir
WriteUninstaller "$InstDir\Uninst.exe"
SectionEnd

Section Uninstall
Delete "$InstDir\Uninst.exe"
RMDir $InstDir
SectionEnd

或者更好地使用UserProgramFiles已知文件夹（如果可用）：

!macro GetUserProgramFiles outvar
!define /IfNDef KF_FLAG_CREATE 0x00008000
!define /IfNDef FOLDERID_UserProgramFiles {5CD7AEE2-2219-4A67-B85D-6C9CE15660CB}
System::Store S
System::Call 'SHELL32::SHGetKnownFolderPath(g "${FOLDERID_UserProgramFiles}", i ${KF_FLAG_CREATE}, p 0, *p .r2)i.r1' ; This will only work on Win7+
${If} $1 == 0
    System::Call '*$2(&w${NSIS_MAX_STRLEN} .s)'
    System::Call 'OLE32::CoTaskMemFree(p r2)'
${Else}
    Push "$LocalAppData\Programs"
${EndIf}
System::Store L
Pop ${outvar}
!macroend

Function onMultiUserModeChanged
${If} $MultiUser.InstallMode == "CurrentUser"
    !insertmacro GetUserProgramFiles $InstDir
    StrCpy $InstDir "$InstDir\${MULTIUSER_INSTALLMODE_INSTDIR}"
${EndIf}
FunctionEnd

---

非常感谢，在找到你的答案之前，我做了完全相同的事情。