“我如何停止？”；锁不可用于<；数据集>&引用；SAS中的错误？

在运行SAS程序时，我始终会出现“锁定不可用”错误。如果我在一个程序中多次对同一数据集执行操作，通常会发生这种情况。在研究了这个错误之后，我的理解是这意味着两个程序试图访问同一个数据集。换句话说，这类似于试图打开别人或你自己已经在使用的文档。下面是给出此错误的代码示例：

data TSTONE.map;
    infile <PATH> delimiter = ',' truncover firstobs=2 dsd TERMSTR=cr LRECL=32760;

    format assessment_edition $45.;
    format ...

    input
    assessment_edition :$45.
    ...
    ;
run;

data tstone.map;
    set tstone.map;
    drop DistrictName ...;
run;

data TSTONE.map；
填充分隔符='，'truncover firstobs=2 dsd TERMSTR=cr LRECL=32760；
格式评估版45美元。；
格式。。。
输入
评估版：45美元。
...
;
跑
数据tstone.map；
设置tstone.map；
删除地区名称。。。；
跑

---

我在一些地方输入了“…”，在那里我有很长的字段列表要导入或删除。因此，首先我导入了一个CSV文件，然后执行一个数据步骤来覆盖文件，删除一些我不需要的字段。我应该注意，有时当我运行这样的程序时，我不会得到任何锁错误。没有其他用户访问这些数据集，它们是我机器的本地用户。此外，如果我突出显示并按顺序运行这两个数据步骤，则不会出现任何问题。

首先，锁定错误可能只是时间问题。服务器可能尚未从早期导入解锁文件。解决方法是不重用数据集名称；如果需要执行一些临时工作，则将文件导入临时（

work.

）数据集，然后将该数据集设置为

tstone.

数据集。我发现锁错误更可能发生在服务器上（特别是使用NAS），因为那里可能有更多的延迟；在本地磁盘上，文件锁定延迟通常很短，以至于不会发生（但并非不可能）

第二，删除（如保留和重命名）可以在数据集选项中完成，几乎可以在OUT=或set或任何类似的地方进行。例如，你可以

proc import file=<whatever> out=tstone.map(drop=... list of drops...);
run;

proc import file=out=tstone.map（drop=…drop列表…）；
跑

---

没有理由强迫SAS重新处理整个数据集，只是为了删除一些变量。

编辑2015年8月10日：此答案中的宏已于2015年8月10日更新。通常更好的调试信息，添加了选项，可以很好地终止SAS，无论是以批处理模式还是交互模式运行

2014年8月12日编辑：此答案中的宏已于2014年8月12日更新。如果您有之前的版本，那么如果您的libname包含数百或数千个数据集，您会注意到锁定时间很慢。下面的更新版本已修复此问题

回答：我们的数据集每隔这么多分钟更新一次，同时我们需要临时报告和计划报告来访问这些数据集。为了克服锁定问题，我们创建了宏来锁定和解锁表，然后再使用它们。它已经运行了将近一年，没有任何错误报告（我们已经解决了所有遇到的bug）

用法：

会话A中的程序：

%lock(iDs=sashelp.class);
** READ TABLE;
%unlock(iDs=sashelp.class);

会话B中的程序：

%lock(iDs=sashelp.class);
** UPDATE TABLE;
%unlock(iDs=sashelp.class);

它是如何工作的。。。。假设会话B首先启动。它将在执行更新之前锁定数据集。会话A希望使用相同的表（而B仍在更新）它。在会话A尝试对其执行任何操作之前，它将检查它是否已锁定。如果被锁定，会话A将等待一段时间（默认值为5分钟），然后决定放弃。如果会话B在5分钟内完成，它将释放锁，会话A将锁定并继续。会话A将在完成后解锁它。您还可以根据需要传入一系列其他选项，以自定义在无法获得锁时如何处理

%lock

宏：

/******************************************************************************
** PROGRAM:  MACRO.LOCK.SAS
**             
** DESCRIPTION: LOCKS A SAS TABLE SO THAT YOU CAN DO WHAT IT IS YOU NEED TO DO.
** 
** PARAMETERS: iDS     :             THE TABLE TO TRY AND LOCK.
**             iTIMEOUT:             THE MAXIMUM # OF SECONDS TO WAIT TRYING TO GET THE LOCK.
**             iRETRY  :             HOW OFTEN TO RETRY GETTING THE LOCK (IN SECONDS)
**             iVERBOSE:             WHETHER TO PRINT OUT DEBUGGING INFO
**             iEndQuietlyOnTimeout: EXIT SAS IF THE LOCK FAILS
**             iIgnoreError:         IGNORE ERRORS IF DATASET DOESNT EXIST AND CANT BE LOCKED
**
*******************************************************************************
** VERSION:
** 2.0 ON: 13-NOV-14 BY: RP
**     CHANGED METHOD OF CHECKING WHETHER FILE EXISTS TO USE THE FILEEXIST 
**     FUNCTION.  MUCH BETTERER.
** 2.1 ON: 14-SEP-15 BY: MS
**     ADDED OPTIONAL FLAG TO IGNORE ERRORS WHILE ATTEMPTING A LOCK. MUCH BETTERERER.
** 2.2 ON: 25-SEP-15 BY: RP
**     HANDLED FAILS BETTERERER.  MADE WORDS IN LOG MORE BETTERERER TOO.
******************************************************************************/

%macro lock(iDs=, iTimeOut=600, iRetry=3, iVerbose=1, iEndSasQuietlyOnTimeout=0, iIgnoreError=0);

  %global lock_lock_failed ;
  %local starttime lib mbr physical_filename;

  %let starttime = %sysfunc(datetime());
  %let lock_lock_failed = 1;

  /*
  ** MAKE SURE THE REQUIRED DS IS NOT A VIEW.
  ** TODO. CHANGE THIS TO ACCEPT 1 WORD DATA SET REFERENCES
  */
  %let lib               = %sysfunc(pathname(%sysfunc(scan(&iDs,1))));
  %let mbr               = %sysfunc(scan(&iDs,2));
  %let physical_filename = &lib\&mbr..sas7bdat;  


  %if not %sysfunc(fileexist(&physical_filename)) %then %do;
    %if not &iIgnoreError %then %do;
      %put &err: (MACRO.LOCK.SAS) THE DATASET YOU TRIED TO LOCK DOES NOT EXIST (OR YOU TRIED TO LOCK A VIEW WHICH IS NOT POSSIBLE). ;
      %put &err: (MACRO.LOCK.SAS) THE DATASET NAME WAS &iDs .  EXITING SAS.;
      %stop_sas;
    %end;
    %else %do;
      %put NOTE: (MACRO.LOCK.SAS) THE DATASET YOU TRIED TO LOCK DOES NOT EXIST (OR YOU TRIED TO LOCK A VIEW WHICH IS NOT POSSIBLE). ;
      %put NOTE: (MACRO.LOCK.SAS) CONTINUUING DESPITE FAILURE TO LOCK AS iIgnoreError=&iIgnoreError ;      
    %end;
  %end;
  %else %do;

    %do %until(&lock_lock_failed eq 0 or %sysevalf(%sysfunc(datetime()) gt (&starttime + &iTimeOut)));

      %if &iVerbose %then %do;
        %put trying open ...;
      %end;

      data _null_;
        dsid = 0;
        do until (dsid gt 0 or datetime() gt (&starttime + &iTimeOut));
          dsid = open("&iDs");
          if (dsid eq 0) then do;
            rc = sleep(&iRetry);
          end;
        end;
        if (dsid gt 0) then do;
          rc = close(dsid);
        end;
      run;

      %if &iVerbose %then %do;
        %put trying lock ...;
      %end;

      lock &iDs;

      %if &syslckrc eq 0 %then %do;
        %let lock_lock_failed = 0;
      %end;
      %else %do;
        /*
        ** THIS WILL ONLY HAPPEN WHEN THE DATASET IS BEING VIEWED IN AN INTERACTIVE SESSION.
        ** THE OPEN FUNCTION WILL SAY ITS ABLE TO OPEN THE DATASET BUT THEN THE LOCK FUNCTION
        ** WILL FAIL.  WHEN THIS HAPPENS SLEEP HERE AS WELL SO THAT WE DONT GET THOUSANDS OF LOCK 
        ** ATTEMPTS IN THE LOG FILE.
        */
        %let rc = %sysfunc(sleep(%eval(&iRetry * 5)));
      %end;

      %if &iVerbose %then %do;
        %put syslckrc=&syslckrc;
      %end;

    %end;

    %if &lock_lock_failed %then %do;
      %if &iEndSasQuietlyOnTimeout %then %do;
        %stop_sas;
      %end;
      %put &err: (MACRO.LOCK.SAS) COULD NOT LOCK DATASET BEFORE TIMEOUT (&iTimeOut) OCCURRED.;
    %end;

  %end;

%mend;

解锁宏：

/******************************************************************************
** PROGRAM:  MACRO.UNLOCK.SAS
**             
** DESCRIPTION: UNLOCKS A SAS TABLE LOCKED WITH MACROS.LOCK.SAS.
** 
** PARAMETERS: iDS     : THE TABLE TO TRY AND UNLOCK.
**
*******************************************************************************
** VERSION:
** 1.0 ON: 07-OCT-11 BY: RP
**     CREATED.
******************************************************************************/

%macro unlock(iDs=);
  /* 
  ** ONLY UNLOCK IF THE LOCK WAS SUCCESSFUL
  */
  %if %symexist(lock_lock_failed) %then %do;
    %if &lock_lock_failed eq 0 %then %do;
      lock &iDs clear;
    %end;
    %else %do;
      %put ATTEMPT TO UNLOCK WAS IGNORED AS ATTEMPT TO LOCK FAILED.;
    %end;
  %end;
  %else %do;
    %put ATTEMPT TO UNLOCK WAS IGNORED AS NO ATTEMPT TO LOCK WAS MADE.;
  %end;
%mend;

这些程序还需要存在一些其他实用程序宏

IsDir宏：

/******************************************************************************
** PROGRAM:  CMN_MAC.ISDIR.SAS
**
** DESCRIPTION: DETERMINES IF THE SPECIFIED PATH EXISTS OR NOT.
**              RETURNS: 0 IF THE PATH DOES NOT EXIST OR COULD NOT BE OPENED.
**                       1 IF THE PATH EXISTS AND CAN BE OPENED.
**
** PARAMETERS: iPath: THE FULL PATH TO EXAMINE.  NOTE THAT / AND \ ARE TREATED
**                    THE SAME SO &SASDIR/COMMON/MACROS IS THE SAME AS
**                    &SASDIR\COMMON\MACROS.
**
*******************************************************************************
** VERSION:
** 1.0 ON: 13-JUL-07 BY: RP
**     CREATED.  
** 1.1 ON: 29-APR-10 BY: RP
**     ADDED CLEANUP CODE SO FILES WOULD NOT REMAIN LOCKED.
** 1.2 ON: 15-APR-14 BY: JG
**     ADDED MORE DEBUGGING INFO.
** 1.3 ON: 12-DEC-14 BY: RP
**     CLEANED UP DEBUGGING INFO TO A SINGLE LINE
******************************************************************************/

%macro isDir(iPath=,iQuiet=1);
  %local result dname did rc;

  %let result = 0;
  %let check_file_assign =  %sysfunc(filename(dname,&iPath));

  %put ASSIGNED FILEREF (0=yes, 1=no)? &check_file_assign &iPath;


  %if not &check_file_assign %then %do;

    %let did = %sysfunc(dopen(&dname));

    %if &did %then %do;
      %let result = 1;
    %end;
    %else %if not &iQuiet %then %do;
      %put &err: (ISDIR MACRO).;
      %put %sysfunc(sysmsg());
    %end;

    %let rc = %sysfunc(dclose(&did));

  %end;
  %else %if not &iQuiet %then %do;
    %put &err: (ISDIR MACRO).;
    %put %sysfunc(sysmsg());
  %end;

  &result

%mend;
/*%put %isDir(iPath=&sasdir\commonn\macros);*/
/*%put %isDir(iPath=&sasdir/kxjfdkebnefe);*/
/*%put %isDir(iPath=&sasdir/kxjfdkebnefe, iQuiet=0);*/
/*%put %isDir(iPath=c:\temp);*/

文件列表宏：

/******************************************************************************
** PROGRAM:  MACRO.FILE_LIST.SAS
**
** DESCRIPTION: RETURNS THE LIST OF FILES IN A DIRECTORY SEPERATED BY THE
**              SPECIFIED DELIMITER. RETURNS AN EMPTY STRING IF THE THE 
**              DIRECTORY CAN'T BE READ OR DOES NOT EXIST.
**
** PARAMETERS: iPath: THE FULL PATH TO EXAMINE.  NOTE THAT / AND \ ARE TREATED
**                    THE SAME SO &SASDIR/COMMON/MACROS IS THE SAME AS
**                    &SASDIR\COMMON\MACROS. WORKS WITH BOTH UNIX AND WINDOWS.
**
*******************************************************************************
** VERSION:
** 1.0 ON: 17-JUL-07 BY: RP
**     CREATED.  
** 1.1 ON: 29-APR-10 BY: RP
**     ADDED CLEANUP CODE SO FILES WOULD NOT REMAIN LOCKED.
**     FIXED ERROR OCCURRING WHEN IPATH DID NOT EXIST.
** 1.2 ON: 18-AUG-10 BY: RP
**     CATERED FOR MACRO CHARS IN FILENAMES
** 1.3 ON: 14-APR-14 BY: RP&JG
**     ADDED MORE DEBUGGING INFO TO CHECK PATH
** 1.4 ON: 13-NOV-14 BY: RP
**     CHANGED PROGRAM FLOW TO MAKE IT BOTH EASIER TO READ AND TO 
**     REDUCE UNNECESSARY CHECKS / IMPROVE PERFORMANCE.
******************************************************************************/
/*
** TODO. THERES ABOUT 100 WAYS THIS COULD BE IMPROVED.  DO IT SOMETIME.
** SIMPLY IF STATEMENTS FOR FILTERS.
*/
%macro file_list(iPath=, iFilter=, iFiles_only=0, iDelimiter=|);
  %local result did dname cnt num_members filename rc check_dir_exist check_file_assign;

  %let result=;

  %let check_dir_exist = %isDir(iPath=&iPath);
  %let check_file_assign = %sysfunc(filename(dname,&iPath));

  %put The desired path:  &iPath;
  %if &check_dir_exist and not &check_file_assign %then %do;

    %let did = %sysfunc(dopen(&dname));
    %let num_members = %sysfunc(dnum(&did));

    %do cnt=1 %to &num_members;

      %let filename = %qsysfunc(dread(&did,&cnt));
      %if "&filename" ne "" %then %do;

        %if "&iFilter" ne "" %then %do;
          %if %index(%lowcase(&filename),%lowcase(&iFilter)) eq 0 %then %do;
            %goto next;
          %end;
        %end;

        %if &iFiles_only %then %do;
          %if %isDir(iPath=%nrbquote(&iPath/&filename)) %then %do;
            %goto next;
          %end;
        %end;

        %let result = &result%str(&iDelimiter)&filename;

        %next:

      %end;
      %else %do;
        %put ERROR: (CMN_MAC.FILE_LIST) FILE CANNOT BE READ.;
        %put %sysfunc(sysmsg());
      %end;
    %end;

    %let rc = %sysfunc(dclose(&did));

  %end;
  %else %do;

    %put ERROR: (CMN_MAC.FILE_LIST) PATH DOES NOT EXIST OR CANNOT BE OPENED.;
    %put %sysfunc(sysmsg());

    %put DIRECTORY EXISTS (1-yes, 0-no)?  &check_dir_exist;
    %put ASSIGN FILEREF SUCCESSFUL (0-yes, 1-no)?  &check_file_assign;

  %end;

  /*
  ** RETURN THE RESULT.  TRIM THE LEADING DELIMITER OFF THE FRONT OF THE RESULTS.
  */
  %if "&result" ne "" %then %do;
    %qsubstr(%nrbquote(&result),2)
  %end;

%mend; 
/*%put %file_list(iPath=e:\blah\);*/
/*%put %file_list(iPath=e:\SASDev);*/
/*%put %file_list(iPath=e:\SASDev\,iFiles_only=1);*/
/*%put %file_list(iPath=e:\sasdev\,iFiles_only=1,iFilter=auto);*/

停止sas宏：

/******************************************************************************
** PROGRAM:  MACRO.STOP_SAS.SAS
**             
** DESCRIPTION: SIMPLE MACRO TO UNCONDITIONALLY END THE CURRENTLY RUNNING SAS CODE
** 
** PARAMETERS: NONEE
**
*******************************************************************************
** VERSION:
** 1.0 ON: 25-SEP-15 BY: RP
**     CREATED
** 1.1 ON: 05-OCT-15 BY: RP
**     FIXED TYPO TO AVOID WARNING MESSAGE
******************************************************************************/

%macro stop_sas;
  %if "&sysenv" eq "FORE" %then %do;
    %abort cancel;
  %end;
  %else %do;
    endsas;
  %end;
%mend;

---

在%do循环中运行proc append时，我遇到了相同的问题，如下所示：

%do i=1996 %to 2013;
proc append base=inscat.pc_all data = pc&i. force;
run; quit;
%end;

这是在我的本地机器上，因此没有其他人试图访问数据集。发生的事情是，循环运行得如此之快，以至于基本文件在开始写入循环的下一部分之前没有关闭。在做了大量工作并尝试了许多复杂的解决方案之后，事实证明，您可以延长SAS在声明失败的锁之前等待的时间。您可以在创建库时执行以下操作：

libname inscat 'C:\Users\...\insurercat\data' filelockwait=5;

---

这只会将等待时间延长到5秒，然后SAS就会确定这是一个锁定错误（我相信默认值为0）。这个简单的选项修复了我遇到的所有锁问题。

其他观察：我通常运行Enterprise Guide程序，因为我更喜欢UI，即使我仍然从头开始编写代码。当我通过基本SAS运行这段代码时，它不会出错，这可能是EG特定的。不，它不是EG特定的。我可以确认，当从基本SAS运行时，也会出现错误。是的，我怀疑是时间问题。如果我在数据步骤之间运行此命令：%let slp=%sysfunc（sleep（1））；它可以工作，但是它会不断延长运行程序所需的时间，这使得这个解决方案非常糟糕。数据集重命名解决方案似乎是最好的选择，但我不喜欢它使代码看起来多么混乱。当同事们不得不运行我的代码时，我会感到困惑。关于代码，这只是一个示例。我的意思是，无论在这两个连续的数据集中发生了什么，这种情况都会发生。我确实考虑过这一点，并认为人们搜索这个消息可能会遇到这个问题，这对他们可能有用。也许这不是最好的方法，但至少在某个地方有记录。很高兴它帮助了某人。我还应该提到，这样做的正确方法是许可SAS/SHARE模块。但对于那些预算运营的公司，上述wi