触发器在oracle sql中不起作用

我有一个名为Reading的表，有一个列调用ReaderID来指定谁读取读取。现在我想添加一个触发器，以便在表读取中添加新行时，始终检查读取器是否已经读取了5次。如果是，请不要进行插入。确保一个读者的阅读次数不能超过5次。这是我的代码，它不起作用，行仍然可以插入而无需检查

CREATE OR REPLACE TRIGGER TRIGGER1 
BEFORE INSERT ON READING 
FOR EACH ROW
DECLARE
      varReaderCount   Int;
      varRID           Int;
BEGIN
    varRID := :new.ReaderID;

    SELECT COUNT(*) INTO varReaderCount
    FROM Reading
    WHERE ReaderID = varRID;

    IF (varReaderCount >= 5) THEN
      BEGIN
        DBMS_OUTPUT.PUT_LINE('*************************************************');
        DBMS_OUTPUT.PUT_LINE('The reader has reach the limitation of reading.');
        DBMS_OUTPUT.PUT_LINE('**************************************************');
      RETURN;
      END;
    END IF;
END;

---

我不知道为什么。

要阻止插入完成，您需要在触发器中引发异常。顺便说一句，那些DBMS_OUTPUT.PUT_LINE调用没有任何意义-触发器在Oracle内部运行，没有地方显示该输出。

您需要替换这些行：

IF (varReaderCount >= 5) THEN
    BEGIN
      DBMS_OUTPUT.PUT_LINE('*************************************************');
      DBMS_OUTPUT.PUT_LINE('The reader has reach the limitation of reading.');
      DBMS_OUTPUT.PUT_LINE('**************************************************');
      RETURN;
    END;
END IF;

按顺序：

IF (varReaderCount >= 5) THEN  
    RAISE_APPLICATION_ERROR(-20101,'limitation of reading');  
END IF;

在需要捕获异常以避免插入期间出错后：

 DECLARE
    readingException EXCEPTION;
    PRAGMA EXCEPTION_INIT(readingException, -20101);
 BEGIN 
    INSERT into READING VALUES (...);
 EXCEPTION
    WHEN readingException 
      THEN NULL;
 END;

---

我假设您已经发现，您不能从定义行级触发器的同一个表中进行选择；它会导致表突变异常

为了使用触发器正确创建此验证，应创建一个过程以获取用户指定的锁，以便在多用户环境中正确序列化验证

PROCEDURE request_lock
  (p_lockname                     IN     VARCHAR2
  ,p_lockmode                     IN     INTEGER  DEFAULT dbms_lock.x_mode
  ,p_timeout                      IN     INTEGER  DEFAULT 60
  ,p_release_on_commit            IN     BOOLEAN  DEFAULT TRUE
  ,p_expiration_secs              IN     INTEGER  DEFAULT 600)
IS
  -- dbms_lock.allocate_unique issues implicit commit, so place in its own
  -- transaction so it does not affect the caller
  PRAGMA AUTONOMOUS_TRANSACTION;
  l_lockhandle                   VARCHAR2(128);
  l_return                       NUMBER;
BEGIN
  dbms_lock.allocate_unique
    (lockname                       => p_lockname
    ,lockhandle                     => p_lockhandle
    ,expiration_secs                => p_expiration_secs);
  l_return := dbms_lock.request
    (lockhandle                     => l_lockhandle
    ,lockmode                       => p_lockmode
    ,timeout                        => p_timeout
    ,release_on_commit              => p_release_on_commit);
  IF    (l_return = 1) THEN
    raise_application_error(-20001, 'dbms_lock.request Timeout');
  ELSIF (l_return = 2) THEN
    raise_application_error(-20001, 'dbms_lock.request Deadlock');
  ELSIF (l_return = 3) THEN
    raise_application_error(-20001, 'dbms_lock.request Parameter Error');
  ELSIF (l_return = 5) THEN
    raise_application_error(-20001, 'dbms_lock.request Illegal Lock Handle');
  ELSIF (l_return not in (0,4)) THEN
    raise_application_error(-20001, 'dbms_lock.request Unknown Return Value ' || l_return);
  END IF;
  -- Must COMMIT an autonomous transaction
  COMMIT;
END request_lock;

然后，此过程可以用于复合触发器（假设至少是Oracle 11），在早期版本中，需要将其拆分为单个触发器

CREATE OR REPLACE TRIGGER too_many_readings
  FOR INSERT OR UPDATE ON reading
  COMPOUND TRIGGER

  -- Table to hold identifiers of inserted/updated readers
  g_readerIDs sys.odcinumberlist;

BEFORE STATEMENT 
IS
BEGIN
-- Reset the internal reader table
 g_readerIDs := g_readerIDs();
END BEFORE STATEMENT; 

AFTER EACH ROW
IS
BEGIN
  -- Store the inserted/updated readers
  IF (  INSERTING
     OR (   UPDATING
        AND :new.readerID <> :old.readerID))
  THEN           
    g_readerIDs.EXTEND;
    g_readerIDs(g_readerIDs.LAST) := :new.readerID;
  END IF;
END AFTER EACH ROW;

AFTER STATEMENT
IS
  CURSOR csr_readers
  IS
    SELECT DISTINCT
           rid.column_value readerID
    FROM TABLE(g_readerIDs) rid
    ORDER BY rid.column_value;
  CURSOR csr_constraint_violations
    (p_readerID reading.readerID%TYPE)
  IS
    SELECT count(*) readings
    FROM reading rdg
    WHERE rdg.readerID = p_readerID
    HAVING count(*) > 5;
  r_constraint_violation csr_constraint_violations%ROWTYPE;
BEGIN
  -- Check if for any inserted/updated reading there exists more than 5 readings
  -- for the same reader. Serialise the constraint for each readerID so
  -- concurrent transactions do not affect each other
  FOR r_reader IN csr_readers LOOP
    request_lock('TOO_MANY_READINGS_' || r_reader.readerID);
    OPEN csr_constraint_violations(r_reader.readerID);
    FETCH csr_constraint_violations INTO r_constraint_violation;
    IF csr_constraint_violations%FOUND THEN
      CLOSE csr_constraint_violations;
      raise_application_error(-20001, 'Reader ' || r_reader.readerID || ' has ' || r_constraint_violation.readings || ' readings');
    ELSE
      CLOSE csr_constraint_violations;
    END IF;
  END LOOP;
END AFTER STATEMENT;

END;

---

这样的触发器不会停止超过5个会话插入行-每个会话只看到提交的数据，因此查询将只返回已提交的行。您可以有100个会话，所有插入行都不会触发触发器。除了已经指出的dbms_输出之外，触发器不做任何事情