Sql dbms_xmldom-从oracle数据库创建xml
我正在尝试从oracle数据库创建一个xml文件 我无法获得正确的格式,不知道是否可以获得一些帮助 这是脚本的一部分:Sql dbms_xmldom-从oracle数据库创建xml,sql,xml,oracle,plsql,Sql,Xml,Oracle,Plsql,我正在尝试从oracle数据库创建一个xml文件 我无法获得正确的格式,不知道是否可以获得一些帮助 这是脚本的一部分: l_record_element := dbms_xmldom.createElement(l_domdoc, 'record_type'); dbms_xmldom.setAttribute(l_record_element,'desc', r_dept.public1); l_record_node := dbms_xmldom.appendChild(l_dept_nod
l_record_element := dbms_xmldom.createElement(l_domdoc, 'record_type');
dbms_xmldom.setAttribute(l_record_element,'desc', r_dept.public1);
l_record_node := dbms_xmldom.appendChild(l_dept_node,dbms_xmldom.makeNode(l_record_element));
我的输出:
<record_type desc="Public"/>
我需要的输出:
<record_type desc="Public">PUBLIC</record_type>
谢谢 您需要创建并附加一个带有PUBIC值的文本节点 演示显示来自提供记录类型的同一游标:
set serveroutput on
declare
l_domdoc dbms_xmldom.domdocument;
l_dept_node dbms_xmldom.domnode;
l_record_node dbms_xmldom.domnode;
l_record_element dbms_xmldom.domelement;
l_record_text dbms_xmldom.domtext;
l_tmp_node dbms_xmldom.domnode;
l_xmltype xmltype;
l_buffer varchar2(32767);
begin
l_domdoc := dbms_xmldom.newDOMDocument; --(xmltype('<data />'));
for r_dept in (select 'Public' as public1, 'PUBLIC' as public2 from dual) loop
l_dept_node := dbms_xmldom.makeNode(l_domdoc);
-- code you showed
l_record_element := dbms_xmldom.createElement(l_domdoc, 'record_type');
dbms_xmldom.setAttribute(l_record_element,'desc', r_dept.public1);
l_record_node := dbms_xmldom.appendChild(l_dept_node, dbms_xmldom.makeNode(l_record_element));
-- add a text node
l_record_text := dbms_xmldom.createTextNode(l_domdoc, r_dept.public2);
l_tmp_node := dbms_xmldom.appendChild(l_record_node, dbms_xmldom.makeNode(l_record_text));
-- display the node for demo
l_xmltype := dbms_xmldom.getXmlType(l_domdoc);
dbms_xmldom.freeDocument(l_domdoc);
dbms_output.put_line(l_xmltype.getClobVal);
end loop;
end;
/
<record_type desc="Public">PUBLIC</record_type>
PL/SQL procedure successfully completed.