如何使用VBA查找某个范围是否包含在另一个范围中？

我在比较两个范围时遇到问题。为了简单起见，我将选取两个简单的范围

M6:M10

和

M6:M8

，我想知道第二个范围是否包含在第一个范围内，我想做的第一件事是编写

    Sub example()
    Dim range1, range2, inte As range
        Set range1 = range("M6:M10")
        Set range2 = range("M6:M8")
        Set intersec = Intersect(range1, range2)
        If intersec = range2 Then
            [if statement]
        End If
    End Sub

但此过程返回以下错误：

PRB:Error 13（类型不匹配）和Error 3061 w/SQL查询

所以也许我不能用这种方式使用“intersect”方法……关于如何测试范围的包含性有什么提示吗？

---

多谢各位

我使用它的方式如下：

If Application.Intersect(rng1, rng2) Is Nothing Then 
    'herecomesthecode
Else
    'herecomesthecode
End if

您可以删除else或不写任何内容，这取决于您想要实现的目标。

这里有一种方法：

Sub ProperSubSet()
    Dim range1 As Range, range2 As Range, inte As Range
    Dim r As Range

    Set range1 = Range("M6:M10")
    Set range2 = Range("M6:M8")

    For Each r In range2
        If Intersect(r, range1) Is Nothing Then
            MsgBox "range2 is not a proper subset of range1"
        Exit Sub
        End If
    Next r
    MsgBox "range2 is a proper subset of range1"
End Sub

---

首先，将range1和range2变量声明为范围

然后，在比较intersec变量和range2变量时，使用range方法的address属性来比较内容

比如：

Sub example()
Dim range1 As Range, range2 As Range, intersec As Range
    Set range1 = Range("M6:M10")
    Set range2 = Range("M11:M12")
    Set intersec = Intersect(range1, range2)
    If Not intersec Is Nothing Then
        If intersec.Address = range2.Address Then
            '[CODE GOES HERE]
        End If
    End If
End Sub

---

以下是一些你可以尝试的东西：

Sub Test()
    Dim R1 As Range, R2 As Range, R3 As Range

    Set R1 = Application.InputBox("Select first range", , , , , , , 8)
    Set R2 = Application.InputBox("Select second range", , , , , , , 8)

    Set R3 = Intersect(R1, R2)
    If Not R3 Is Nothing Then
        If R3.Address = R1.Address Then
            MsgBox "First Range is subset of second"
        ElseIf R3.Address = R2.Address Then
            MsgBox "Second Range is subset of first"
        Else
            MsgBox "Neither range contained in the other"
        End If
    Else
        MsgBox "Ranges are disjoint"
    End If

End Sub

---

另一个变体：

Sub ProperSubSet2()
    Dim range1 As Range, range2 As Range
    Set range1 = [M6:M10]
    Set range2 = [M6:M8]
    Set rComp = Intersect(range2, range1)

    If Not rComp Is Nothing Then
        If rComp.Cells.Count = range2.Cells.Count Then
            MsgBox "range2 is a proper subset of range1"
        Else
            MsgBox "range2 is not a proper subset of range1"
        End If
    Else
        MsgBox "Both ranges aren't intersected at all!"
    End If

End Sub

---

可以将相交点与范围进行比较，以确定一个范围是否包含在另一个范围内。一些代码来显示这个

Sub TestExample()
    Dim Range1 As Range: Set Range1 = Range("M6:M10")
    Dim Range2 As Range: Set Range2 = Range("M6:M8")
    MsgBox Example(Range1, Range2)
End Sub

Function Example(Range1 As Range, Range2 As Range) As Integer
    Dim Overlay As Range: Set Overlay = Application.Intersect(Range1, Range2)
    If Not Overlay Is Nothing Then
        If Overlay.Address = Range1.Address Then Example = Example + 1
        If Overlay.Address = Range2.Address Then Example = Example + 2
    End If
End Function

---

如果没有范围完全包含在另一个范围内，则函数将返回0；如果第一个范围包含在第二个范围内，则函数将返回1；如果第二个范围包含在第一个范围内，则函数将返回2；如果范围相等，则函数将返回3，单元格数量非常大的区域（so.CountLarge，而不是.Count），那么这将起作用：

Function RangeContainsRange(BigRange As Range, SmallRange As Range) As Boolean
    If BigRange.Parent Is SmallRange.Parent Then
        RangeContainsRange = Application.Union(BigRange, SmallRange).Cells.CountLarge = BigRange.Cells.CountLarge
    Else
        RangeContainsRange = False
    End If
End Function

---

Dim range1、range2、inte As range

将

range1

和

range2

声明为变体（这不是问题所在）——您提到的错误似乎与您显示的代码无关，但可能隐藏在方括号中。如果不相交，则intersect方法也不会返回任何结果，可能是个问题。你应该先检查intersect是否为空。你能确认哪一行产生了错误吗？如果intersec=range2，则怀疑它是

，然后

。如果您试图确认intersec和range2完全重叠，请尝试：

如果intersec.Address=range2.Address，则

。