在sas中编写vba代码

我想将我的VBA代码实现到SAS代码中，这样一次运行就可以完成整个过程。我的SAS代码读取一个大SAS表，进行一些转换，最后导出到Excel文件（代码如下）。我还在Excel文件中编写了一些VBA代码（例如，对某些变量进行自动筛选，您可以看到下面的代码）

该表如下所示：

A B C Var1 Var2 Var3
--------------------
1 1 1 10 15 20
1 1 2 15 20 30
1 2 1 20 30 40
1 2 2 30 40 50
2 1 1 40 50 60
2 1 2 50 60 70
2 2 1 60 70 80
..............
..............

但是，我想将我的VBA代码实现到SAS代码中，这样我只需运行一次即可完成整个过程。我知道如何在SAS中打开并运行Excel文件（代码如下），但我不知道如何在SAS中实现VBA代码

如果您想知道为什么我要在SAS中实现我的宏代码，我将在将来多次使用类似的SAS表，因此将整个代码放在一个地方会更实用

我刚刚意识到我不能以启用宏的Excel格式XLSM导出SAS中的表。我想这也是一个挑战。此外，从Excel文件保存宏代码也不太实际，因为它必须保存在“添加项”菜单中。因此，最好在一个地方处理整个过程，比如在SAS编辑器中

SAS中将最终表格导出到Excel文件的代码：

PROC EXPORT DATA=File1
        OUTFILE= "&server\&env\test1.xlsx" 
        DBMS=EXCEL REPLACE; 
   SHEET="sheet1"; 
RUN;

Sub Macro1()
    Dim N As Long, r As Range
With Sheets("sheet1")
    N = .Cells(Rows.Count, "B").End(xlUp).Row
    ReDim ary(1 To N)
    For i = 1 To N
        ary(i) = .Cells(i, 1)
    Next i
End With

Range("A1:F20").AutoFilter
ActiveSheet.Range("$A$1:$F$20").AutoFilter Field:=1, Criteria1:=ary, Operator:=xlFilterValues
End Sub

Excel文件中用于为Excel文件中的变量创建自动筛选的VBA代码示例：

PROC EXPORT DATA=File1
        OUTFILE= "&server\&env\test1.xlsx" 
        DBMS=EXCEL REPLACE; 
   SHEET="sheet1"; 
RUN;

Sub Macro1()
    Dim N As Long, r As Range
With Sheets("sheet1")
    N = .Cells(Rows.Count, "B").End(xlUp).Row
    ReDim ary(1 To N)
    For i = 1 To N
        ary(i) = .Cells(i, 1)
    Next i
End With

Range("A1:F20").AutoFilter
ActiveSheet.Range("$A$1:$F$20").AutoFilter Field:=1, Criteria1:=ary, Operator:=xlFilterValues
End Sub

SAS中启动和运行SAS中Excel文件的代码：

OPTIONS NOXWAIT NOXSYNC;
   DATA _NULL_;
   RC=SYSTEM('START EXCEL');
   RC=SLEEP(0.5);
RUN;
FILENAME CMDS DDE 'EXCEL|SYSTEM';
DATA _NULL_;
   FILE CMDS;
   PUT "[OPEN(""&server\&env\test1.XLS"")]";
   PUT '[RUN("Macro1")]';
   PUT '[SAVE.AS("&server\&env\FORMATTED_FILE.XLSM")';
   PUT "[QUIT()]";
RUN;
QUIT;

---

通常的方法是使用模板文件。您保存了模板，其中保存了excel宏（可能还对其进行了一些格式化；使用DDE，您不必从空白工作表开始）

您可以使用DDE填充模板工作簿/工作表，然后“另存为”另一个文件，也可以使用DDE创建新工作簿和工作表，打开模板工作簿，运行宏，关闭模板。这可能取决于是否要将宏与结果一起分发

这允许您运行所有内容，而无需以任何方式与之交互-您不必向其中添加新宏或任何内容，因为模板宏已经存在。通过这种方式，一切都可以一次完成

---

例如，本文以及其他几篇关于该主题的论文中都显示了这一点。

使用DDE，您可以在SAS中设置过滤器：

data _null_;
    FILE CMDS;
    /* select your worksheet */
    put '[workbook.select("your_sheet")]';
    /* select the column range you want to set the filter */
    put '[select("r1c2:r1c5")]';
    /* set filter */
    put '[filter]';
run;

---

我总是发现DDE有点笨重，如果你在excel工作簿运行时触摸它，它会感到不安。本例将VBscript写入sas工作区，然后执行iut。基本上，您可以让put语句为您希望程序执行的任何操作编写代码，并且它可以由SAS数据集中的内容驱动。此示例向现有excel电子表格添加标题和文件夹

%macro xlHeadFoot(WorkBookPath=,Header=FileName,Footer=SheetName,onlySheet=);

  %local _shortpath WorkBook;

  data _null_;
    length header footer $200;
    header=ifc(lowcase("&header.")='filename' or lowcase("&header.")='sheetname',tranwrd(tranwrd(lowcase("&header."),'filename','&F'),'sheetname','&A'),"&header.");
    footer=ifc(lowcase("&footer.")='filename' or lowcase("&footer.")='sheetname',tranwrd(tranwrd(lowcase("&footer."),'filename','&F'),'sheetname','&A'),"&footer.");
    call symput("header",trim(header));
    call symput("footer",trim(footer));
  run;

  %let WorkBook=%scan(&WorkBookPath.,%sysfunc(countw(&WorkBookPath.,\)),\);

    %* ***********************************************;
    %* get the short DOS name for the workspace folder;

    data _null_;
      rc=filename("inpipe",catx('"','for %I in (',"%sysfunc(pathname(work))",') do echo %~sI'),"pipe");
    run;

    data _null_;
      infile inpipe truncover end=last;
      input @1 data $256. ;
      rc=filename("inpipe","");
      if last then call symput('_shortpath',trim(data));
    run;

    %* *******************************;
    %* tidy up any previous executions;

    data _null_;
      if fileexist("&_shortpath\testx.vbs") then do;
        rc=filename("dump","&_shortpath\testx.vbs");
        rc=fdelete('dump');
        msg=sysmsg();
        if msg ne '' then put msg=;
      end;
      if fileexist("&_shortpath\xmlFile.xml") then do;
        rc=filename("dump","");
        rc=filename("dump","&_shortpath\xmlFile.xml");
        rc=fdelete('dump');
        msg=sysmsg();
        if msg ne '' then put msg=;
        rc=filename("dump","");
      end;
    run;


  %if %sysfunc(fileexist("&WorkBookPath."))=1 %then %do;


    data null;
      file "%sysfunc(pathname(work))\testx.vbs";
      put @1 'Set objExcel = CreateObject("Excel.Application")';
      put @1 'objExcel.Application.Visible = True';
      put @1 'objExcel.Workbooks.open  "' "&WorkBookPath." '"' ;
      %if %str(&onlySheet.) ne %str() %then %do;
        put @1 'onlySheetExisits=False';
        put @1 'for each sheet in objExcel.Workbooks("' "&WorkBook." '").sheets';  
        put @1 'if strcomp(sheet.name,"' "&onlySheet." '",1)=0 then onlySheetExisits=True';
        put @1 'if strcomp(sheet.name,"' "&onlySheet." '",1)=0 then sheet.PageSetup.CenterHeader = "' "%str(&Header.)" '"';
        put @1 'if strcomp(sheet.name,"' "&onlySheet." '",1)=0 then sheet.PageSetup.CenterFooter = "' "%str(&Footer.)" '"';
        put @1 'Next';
      %end;
      %else %do;
        put @1 'for each sheet in objExcel.Workbooks("' "&WorkBook." '").sheets';  
        put @1 'sheet.PageSetup.CenterHeader = "' "%str(&Header.)" '"';
        put @1 'sheet.PageSetup.CenterFooter = "' "%str(&Footer.)" '"';
        put @1 'Next'; 
      %end;

      put @1 'objExcel.Workbooks("' "&WorkBook." '").save';
      put @1 'objExcel.Workbooks("' "&WorkBook." '").Close';
      put @1 'objExcel.Application.Quit';
      %if %str(&onlySheet.) ne %str() %then %do;
        put @1 'if onlySheetExisits=False then msgbox "Error! Could not find Worksheet: '"&onlySheet."' in Workbook: "' ' & vbcr & ' '" '"&WorkBookPath." '",16,"SAS: '"&SYSMACRONAME"'"';
      %end;

    run;


    x %sysfunc(quote("&_shortpath.\testx.vbs")); 

  %end;
  %else %put %str(ERR)OR: [&SYSMACRONAME.] Unable to open: &WorkBookPath.  - check it exists!;


%mend;

---

您的意思是希望能够通过DDE创建一个新的Excel文件，然后通过SAS以编程方式在其中创建一个新的VBA宏？基本上是的。我希望我的SAS代码将读取SAS表，将结果导出到Excel文件（如果可能，XLSM），并且我的SAS代码还将运行一些VBA代码以使Excel文件更漂亮。我希望所有这些进程都只在一个代码中运行一次…您运行的excel宏是否总是相同的？使用excel模板的方法有效吗？我认为这是做这件事的标准方法；您将excel宏存储在一个静态的“模板”工作簿中，然后从那里执行它（在写入其他工作簿时，或者您可以写入模板工作簿，然后另存为其他工作簿名称）。我计划在SAS中使用VBA来处理相同的表变量，但要更改每个excel文件中的数据。我只会使用%let var1=&var更改SAS文件开头的“宏变量”。您是说将Excel宏保存为静态模板工作簿，还是说XLSB格式？你的意思是我只是简单地把我的宏代码保存在任何填充板中，然后在需要的时候复制粘贴它吗？如果你的例子是autofilter，我会说标记集已经提供了一个很好的机制来实现这一点。此外，您还可以导出到XLSM，我已经多次这样做了。你们有什么版本的SAS？