使用XSL将稀疏填充的XML列表转换为HTML表

我正在尝试使用XSL将XML文件转换成一个漂亮的HTML表，但我一辈子都不知道如何正确排列所有列。我发现了一个类似的问题（），这是一个信息丰富的问题（我对XSL非常陌生，所以每一点都有帮助），但我的XML的结构要复杂一些。。。不定期地：

<?xml version="1.0"?>
<root>
    <Group>
        <Type>Type1</Type>
        <Desc>Desc1</Desc>
        <Name>Name1</Name>
    </Group>
    <Group>
        <Type>Type2</Type>
        <Name>Name2</Name>
        <State>State2</State>
    </Group>
    <Group>
        <Type>Type3</Type>
        <State>State3</State>
        <Country>Country4</Country>
    </Group>
</root>

类型1
描述1
名称1
类型2
姓名2
状态2
类型3
状态3
国家4

有没有一种好方法可以将其转换为格式良好的表？我更希望它能像这样在XML上工作，就像我们曾经向一个组元素添加过一个新字段一样，我不希望它们必须向每个其他元素添加相同的标记（如果有一种很好的方法可以自动将所有缺少的子元素添加到其他组元素中的组元素中，那也很好，可以使用可以首先运行的第二个XSLT）。此XML没有支持模式，但如果有帮助，可以创建一个支持模式

---

很抱歉，如果之前已经回答过这个问题，那么除了上述问题之外，我找不到更接近的问题，也找不到关于如何将缺少的子元素添加到元素的任何内容。

首先，这并不简单。如果您是XSLT新手，那么这可能不是您从事的最佳项目

为了理解下面的解决方案，您需要熟悉使用以及技术

XSLT1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:key name="col-by-name" match="/root/Group/*" use="name()" />
<xsl:key name="cell-by-rowXcol" match="/root/Group/*" use="concat(generate-id(..), '|', name())" />

<xsl:template match="/root">
    <xsl:variable name="distinct-columns" select="Group/*[count(. | key('col-by-name', name())[1]) = 1]"/>
    <table border="1">
        <thead>
            <tr>
                <xsl:for-each select="$distinct-columns">
                    <th><xsl:value-of select="name()"/></th>
                </xsl:for-each>
            </tr>
        </thead>
        <tbody>
            <xsl:for-each select="Group">
            <xsl:variable name="row" select="generate-id()" />
                <tr>
                    <xsl:for-each select="$distinct-columns">
                        <td>
                            <xsl:value-of select="key('cell-by-rowXcol', concat($row, '|', name()))" />
                        </td>
                    </xsl:for-each>
                </tr>
            </xsl:for-each>
        </tbody>
    </table>
</xsl:template>

</xsl:stylesheet>

结果（渲染）：

---

在XSLT 2.0中，您可以使用

distinct-values（）

函数而不是Muenchian分组。

以下是我对XSLT 2.0解决方案的尝试：

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="html" version="5.0" encoding="UTF-8" indent="yes" />

    <xsl:variable name="col-names" select="distinct-values(root/Group/*/node-name(.))"/>

    <xsl:template match="root">
        <table>
            <thead>
                <tr>
                    <xsl:for-each select="$col-names">
                        <th>
                            <xsl:value-of select="."/>
                        </th>
                    </xsl:for-each>
                </tr>
            </thead>
            <tbody>
                <xsl:apply-templates select="Group"/>                
            </tbody>
        </table>
    </xsl:template>

    <xsl:template match="Group">
        <tr>
            <xsl:variable name="this" select="."/>
            <xsl:for-each select="$col-names">
                <td>
                    <xsl:value-of select="$this/*[node-name(.) eq current()]"/>
                </td>
            </xsl:for-each>
        </tr>
    </xsl:template>
</xsl:transform>

请注明XSLT 1.0或2.0。我更喜欢1.0以保证与Eclipse的兼容性，但我相信我可以让2.0在我们现有的东西中工作。当我找到一个喜欢它的处理器时，这一个就很有魅力（XML Spy有，我们在Eclipse中使用的WAS运行时内置的那个没有）。这两个不同的值功能是我所缺少的最重要的东西，这正是我所需要的。谢谢你和迈克尔的帮助。