Xml XSLT1.0将分隔字符串转换为节点

我有一个XML文件，我想格式化，但我需要一些帮助

我的意见是：

<X>
    <Y>
        <id>2047866</id>
        <email_address>abc@gmail.com</email_address>
        <senddate>2017-02-02 15:13:27.0941121</senddate>
        <product_id>5000231;5000233;5000237;5000240;5000240;5000241;</product_id>
    </Y>
</X>

2047866
abc@gmail.com
2017-02-02 15:13:27.0941121
5000231;5000233;5000237;5000240;5000240;5000241;

我需要构建一个XSL，将我的输入转换为：

<X>
    <Y>
        <id>2047866</id>
        <email_address>abc@gmail.com</email_address>
        <senddate>2017-02-02 15:13:27.0941121</senddate>
        <product_id>5000231</product_id>
    </Y>
    <Y>
        <id>2047866</id>
        <email_address>abc@gmail.com</email_address>
        <senddate>2017-02-02 15:13:27.0941121</senddate>
        <product_id>5000233</product_id>
    </Y>
    etc
    .
    .
</X>

2047866
abc@gmail.com
2017-02-02 15:13:27.0941121
5000231
2047866
abc@gmail.com
2017-02-02 15:13:27.0941121
5000233
等
.
.

我找到了一个脚本，可以帮助我从product_ID中获取每个ID，但我还需要复制每个product_ID上面的ID、电子邮件、发送日期，并将它们放入Y parent标记中

<?xml version="1.0" encoding="UTF-8"?>

;

你能给我一些关于如何进行的提示吗

谢谢大家!

以以下方式尝试：

XSLT1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Y">
    <xsl:call-template name="tokenize">
        <xsl:with-param name="text" select="product_id"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="';'"/>
        <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" />
        <xsl:if test="$token">
            <xsl:copy>
                <xsl:apply-templates select="id | email_address | senddate"/>
                <product_id>
                    <xsl:value-of select="$token"/>
                </product_id>
            </xsl:copy>
        </xsl:if>
        <xsl:if test="contains($text, $delimiter)">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>

</xsl:stylesheet>

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Y">
    <xsl:call-template name="tokenize">
        <xsl:with-param name="text" select="product_id"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="';'"/>
        <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" />
        <xsl:if test="$token">
            <xsl:copy>
                <xsl:apply-templates select="id | email_address | senddate"/>
                <product_id>
                    <xsl:value-of select="$token"/>
                </product_id>
            </xsl:copy>
        </xsl:if>
        <xsl:if test="contains($text, $delimiter)">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>

</xsl:stylesheet>