Ada约束错误:鉴别检查失败。这是什么意思?
我试图搜索文档和代码,但我无法找到这是什么,因此无法找到如何更正它 情景: 我正在使用Ada SPARK vectors库,我有以下代码:Ada约束错误:鉴别检查失败。这是什么意思?,ada,spark-ada,Ada,Spark Ada,我试图搜索文档和代码,但我无法找到这是什么,因此无法找到如何更正它 情景: 我正在使用Ada SPARK vectors库,我有以下代码: package MyPackage with SPARK_Mode => On is package New_Vectors is new Formal_Vectors (Index_Type => test, Element_Type => My_Element.Object); type Object is private; p
package MyPackage
with SPARK_Mode => On
is
package New_Vectors is new Formal_Vectors (Index_Type => test, Element_Type => My_Element.Object);
type Object is private;
private
type Object is
record
Data : New_Vectors.Vector (Block_Vectors.Last_Count);
Identifier : Identifier_Range;
end record;
我在代码调用时收到错误:
function Make (Identifier : Identifier_Range) return Object is
begin
return (
Data => New_Vectors.Empty_Vector,
Identifier => Identifier);
end Make;
指向空向量
。困难在于Empty_Vector
将容量定义为0
,这似乎是导致问题的原因。现在我不知道该如何处理,因为容量
似乎在类型定义中(查看了a-cofove.ads
)
所以基本上我被困在如何解决这个问题上;或者说如何在将来发现这种情况。你的分析是正确的。出现此错误的原因是,您试图将空向量(即容量为0的向量)分配给容量为块向量的向量。最后一个\u计数
(看起来非零)
实际上,您不需要显式初始化向量就可以使用它。默认初始化(使用
,例如,请参阅)就足够了,如下例所示
但是,为了证明没有运行时错误,确实需要使用clear
明确清除向量。然后可以使用Empty_Vector
函数在断言中检查向量是否为空,如下例所示。使用gnatprove
可以显示该示例没有运行时错误。例如,在GNAT Studio中通过菜单SPARK>prove打开验证设置,在“常规”部分(左上)选择“报告检查已移动”,然后通过选择“执行”(右下)运行分析
main.adb
with Ada.Text_IO; use Ada.Text_IO;
with Ada.Containers.Formal_Vectors;
procedure Main with SPARK_Mode is
package My_Vectors is new Ada.Containers.Formal_Vectors
(Index_Type => Natural,
Element_Type => Integer);
use My_Vectors;
type Object is record
Data : Vector (Capacity => 10); -- Max. # of elements: 10
Value : Integer;
end record;
-- Initialize with default value (i.e. <>), no explicit initialization needed.
Obj : Object :=
(Data => <>,
Value => 42);
begin
-- Clear the vector, required for the assertions to be proven.
Clear (Obj.Data);
-- Assert that the vector is not empty.
pragma Assert (Obj.Data = Empty_Vector);
-- Populate the vector with some elements.
Append (Obj.Data, 4);
Append (Obj.Data, 5);
Append (Obj.Data, 6);
-- Assert that the vector is populated.
pragma Assert (Obj.Data /= Empty_Vector);
-- Show the contents of Obj.Data.
Put_Line ("Contents of Obj.Data:");
for I in Natural range 0 .. Natural (Length (Obj.Data)) - 1 loop
Put_Line ("[" & I'Image & "]" & Element (Obj.Data, I)'Image);
end loop;
New_Line;
-- or, alternatively using an iterator ...
declare
I : Extended_Index := Iter_First (Obj.Data);
begin
while Iter_Has_Element (Obj.Data, I) loop
Put_Line ("[" & I'Image & "]" & Element (Obj.Data, I)'Image);
I := Iter_Next (Obj.Data, I);
end loop;
end;
New_Line;
-- Show the contents of Obj.Value.
Put_Line ("Contents of Obj.Value:");
Put_Line (Obj.Value'Image);
New_Line;
end Main;
Contents of Obj.Data:
[ 0] 4
[ 1] 5
[ 2] 6
[ 0] 4
[ 1] 5
[ 2] 6
Contents of Obj.Value:
42