Apache flex 如何在flex中创建瓷砖墙纸？

我正在尝试用flex制作瓷砖墙纸。我做了拉伸或正常使用的背景尺寸为100%和“自动”。但我不知道如何创建瓷砖

有人可以帮我的源代码，指令或最好的将是一个源代码

问候

---

Zeeshan

使用CSS样式或属性样式无法在Flex 3中创建平铺背景

但是，只需为组件指定自定义编程外观即可，该外观通过使用原始位图数据处理平铺图像的绘制

让我用一些代码进一步说明我的观点

<mx:Canvas borderSkin="{TiledBackgroundSkin}"
    width="100%" height="100%">
</mx:Canvas>

构造函数创建用于平铺的位图图像

然后updateDisplayList方法（在初始创建和后续调整组件大小后调用）使用平铺背景填充整个组件

如果希望调整平铺图像的偏移位置，可以使用updateDisplayList方法进行调整

public class TiledBackgroundSkin extends RectangularBorder
{
    [Bindable]      
    [Embed(source='tile.jpg')]
    private var tileImageClass  :Class;
    private var tileBitmapData  :BitmapData;

    public function TiledBackgroundSkin()
    {
        super(); 
        createBitmap()
    }

    /** A private method that handles the drawing of the bitmap **/
    private function createBitmap():void
    {
        var backgroundImage:Bitmap = new tileImageClass();
        tileBitmapData = new BitmapData(backgroundImage.width,backgroundImage.height);
        tileBitmapData.draw( backgroundImage );
    }

    /** Override updateDisplayList to draw the Tiled Background **/
    override protected function updateDisplayList(  unscaledWidth:Number,unscaledHeight:Number ):void 
    {
        super.updateDisplayList(unscaledWidth,unscaledHeight );
        graphics.clear();
        graphics.beginBitmapFill( tileBitmapData );
        graphics.drawRect(0,0,unscaledWidth,unscaledHeight);
        graphics.endFill();
    }       
}