模式搜索的awk等价物

我有以下文件：

Schedule Name:       Today

  Schedule Type:       Standard
  Active:              yes
  Effective date:      01/24/2014 11:17:05
  Client Encrypt:      no
  LC/CY/Custmr:  EU         NY  Cindy
                 BU         CA  Victor
                 GU         MI  Bob
  Include:
Schedule Name:       Tomorrow

  Schedule Type:       Standard
  Active:              yes
  Effective date:      01/26/2014 11:17:05
  Client Encrypt:      no
  LC/CY/Custmr:  MU         LA  Martha
                 EU         CA  Sam
  Include:
Schedule Name:       Yesterday

  Schedule Type:       Standard
  Active:              no
  Effective date:      01/21/2014 11:17:05
  Client Encrypt:      no
  LC/CY/Custmr:  NV         IL  Joe

  Include:

期望输出

Cindy    Today
Victor   Today
Bob      Today
Martha   Tomorrow
Sam      Tomorrow

现在，我想获得日程名称，即今天、明天以及客户名称，如果活动为是，这是第四个字段。因此，输出应为：

cat billing | 
    awk '/Schedule Name/ || /Active:/ || /LC/,/^$/' | 
    grep -v '^$'

在包含之前的LC之后是一个空行，所以我尝试获取所有数据，直到您找到一个空行，然后是grep-v空行，如果我尝试在不显示计划名称和活动的情况下工作，效果很好，但不适用于这两种模式的搜索

我使用下面的代码，这是相当缓慢

for pol in `cat /tmp/Active_Policies`
do
        count=`sudo /usr/openv/admin/pollist $pol -U | awk '/LC\/CY\/Custmr:/,/Include:/' | grep -v "Include:" | wc -l`
        if [ $count -gt 0 ]
        then
                first=`sudo /usr/openv/admin/pollist $pol -U | awk '/LC\/CY\/Custmr:/,/Include:/' | grep -v "Include:" | awk '{print $4}' | head -1`
                echo "$first    $pol" >> /tmp/Policies_$(date +%m-%d-%Y)
                counter=1
                for client in `sudo /usr/openv/admin/pollist $pol -U | awk '/LC\/CY\/Custmr:/,/Include:/' | grep -v "Include:" | awk '{print $3}' | sed '1d;$d'`
                do
                        ((counter = counter + 1))
                        if [ $counter -le $count ]
                        then
                                echo "$client   $pol" >> /tmp/Policies_$(date +%m-%d-%Y)
                        fi
                done
        fi
done

---

以下是解决问题的正确方法：

$ cat tst.awk
BEGIN { OFS="\t" }
/^[^[:space:]]/ { prt() }
NF {
    if ( /:/ ) {
        name = $0
        sub(/:.*/,"",name)
        gsub(/^[[:space:]]+|[[:space:]]+$/,"",name)
    }
    value = $0
    sub(/^[^:]+:/,"",value)
    gsub(/^[[:space:]]+|[[:space:]]+$/,"",value)

    n2v[name,++numVals[name]] = value
}
END { prt() }

function prt() {
    custFldName = "LC/CY/Custmr"
    if ( n2v["Active",1] == "yes" ) {
        sched = n2v["Schedule Name",1]
        for (valNr=1; valNr<=numVals[custFldName]; valNr++) {
            cust = n2v[custFldName,valNr]
            sub(/.*[[:space:]]/,"",cust)
            print cust, sched
        }
    }
    delete n2v
    delete numVals
}

关键是在上面创建一个数组n2v[]，将名称映射到值，其中名称是每行第一个：之前的文本，关联的值是其后的任何内容：。然后，每次点击日程表行或输入文件末尾时，只需打印n2v数组中您关心的值

$ awk -f tst.awk file
Cindy   Today
Victor  Today
Bob     Today
Martha  Tomorrow
Sam     Tomorrow