Colors Gnuplot-在0处显示不同的勾号颜色

我想在0处显示不同的勾号颜色。 例如，下面的图像我想将y轴0处的勾号颜色设置为

蓝色

。可能吗？谢谢

---

我不知道有一个直接的Gnuplot特性可以做到这一点，但是可以使用一些变通方法

例如，可以在位置0处取消设置tic，并在那里放置自定义标签：

set terminal pngcairo enhanced font ",14"
set output 'fig.png'

set multiplot

xMin = 0
xMax = 2*pi

set xr [xMin:xMax]
set yr [-1:1]

set xtics out nomirror
set ytics out nomirror 
set ytics add ("" 0)

set label "0" at xMin,0 offset char -1.5,0 right textcolor rgb "blue"

plot sin(x) w l t 'sin(x)'

或者，可以使用基于

multiplot

的技术，其中策略基本上是首先绘制感兴趣的功能/数据，而不在tic位于零的位置，然后用一个空的图覆盖该功能/数据，但对于自定义tic位于零的位置：

set terminal pngcairo enhanced font ",14"
set output 'fig.png'

set xr [0:2*pi]
set yr [-1:1]

set xtics out nomirror
set ytics out nomirror 
set ytics add ("" 0)

plot sin(x) w l t 'sin(x)'

set lmargin at screen GPVAL_TERM_SCALE * GPVAL_TERM_XMIN / (1.*GPVAL_TERM_XSIZE)
set rmargin at screen GPVAL_TERM_SCALE * GPVAL_TERM_XMAX / (1.*GPVAL_TERM_XSIZE)
set bmargin at screen GPVAL_TERM_SCALE * GPVAL_TERM_YMIN / (1.*GPVAL_TERM_YSIZE)
set tmargin at screen GPVAL_TERM_SCALE * GPVAL_TERM_YMAX / (1.*GPVAL_TERM_YSIZE)

unset border
unset key
unset xtics
unset ytics

set ytics ("0" 0) out nomirror textcolor rgb 'blue'

plot 1/0

两种方法的结果几乎相同：