Delphi 记录构造函数和字段初始化错误

Delphi 10.2.3中的以下代码：

uses
  System.SysUtils;

type
  TRec = record
  strict private
    FName: String;
    FValue: Integer;
  public
    property Name: String read FName;
    property Value: Integer read FValue;

    constructor Create(const AName: String);
    function WithValue(const AValue: Integer): TRec;
  end;

constructor TRec.Create(const AName: String);
begin
  FName := AName;
end;

function TRec.WithValue(const AValue: Integer): TRec;
begin
  Result := Self;
  Result.FValue := AValue;
end;

procedure Main;
var
  x: TRec;
begin
  x := TRec.Create('First').WithValue(666);
  x := TRec.Create('Second');
  Writeln('In stack: ', x.Value);
end;

var
  x: TRec;
begin
  x := TRec.Create('First').WithValue(666);
  x := TRec.Create('Second');
  Writeln('In global: ', x.Value);

  Main;
  Readln;
end.

生成以下输出：

In global: 0
In stack: 666

是否打算这样做？当对数据段中的全局变量赋值时，编译器生成“call@CopyRecord”行，但当使用堆栈中的局部变量时，编译器不会添加这一行

对于全球：

Project17.dpr.47: x := TRec.Create('First').WithValue(666);
0041D56B 8D45E0           lea eax,[ebp-$20]
0041D56E BA44D64100       mov edx,$0041d644
0041D573 E87CDAFFFF       call TRec.Create
0041D578 8D55E0           lea edx,[ebp-$20]
0041D57B B8C0584200       mov eax,$004258c0
0041D580 8B0D64AF4100     mov ecx,[$0041af64]
0041D586 E865B2FEFF       call @CopyRecord
0041D58B B8C0584200       mov eax,$004258c0
0041D590 8D4DE8           lea ecx,[ebp-$18]
0041D593 BA9A020000       mov edx,$0000029a
0041D598 E877DAFFFF       call TRec.WithValue
0041D59D 8D55E8           lea edx,[ebp-$18]
0041D5A0 B8B8584200       mov eax,$004258b8
0041D5A5 8B0D64AF4100     mov ecx,[$0041af64]
0041D5AB E840B2FEFF       call @CopyRecord
Project17.dpr.48: x := TRec.Create('Second');
0041D5B0 8D45D8           lea eax,[ebp-$28]
0041D5B3 BA5CD64100       mov edx,$0041d65c
0041D5B8 E837DAFFFF       call TRec.Create
0041D5BD 8D55D8           lea edx,[ebp-$28]
0041D5C0 B8B8584200       mov eax,$004258b8
0041D5C5 8B0D64AF4100     mov ecx,[$0041af64]
0041D5CB E820B2FEFF       call @CopyRecord

本地：

Project17.dpr.39: x := TRec.Create('First').WithValue(666);
0041B074 8D45F0           lea eax,[ebp-$10]
0041B077 BAF8B04100       mov edx,$0041b0f8
0041B07C E873FFFFFF       call TRec.Create
0041B081 8D45F0           lea eax,[ebp-$10]
0041B084 8D4DF8           lea ecx,[ebp-$08]
0041B087 BA9A020000       mov edx,$0000029a
0041B08C E883FFFFFF       call TRec.WithValue
Project17.dpr.40: x := TRec.Create('Second');
0041B091 8D45F8           lea eax,[ebp-$08]
0041B094 BA10B14100       mov edx,$0041b110
0041B099 E856FFFFFF       call TRec.Create
Project17.dpr.41: Writeln('In stack: ', x.Value);
0041B09E A1ACF54100       mov eax,[$0041f5ac]
0041B0A3 BA2CB14100       mov edx,$0041b12c
0041B0A8 E87BA8FEFF       call @Write0UString

我应该在记录的每个构造函数中都使用这样的行吗

Self := Default(TRec);

Self := Default(TRec);

因为如果我添加这一行，那么输出是直观的，两种情况下都返回0

是否打算这样做

记录是值类型。分配此类类型的局部变量时，它们不是默认初始化的。所以，是的，这是设计好的

对以下对象执行默认初始化：

• 全局变量
• 类实例
• 托管类型的所有变量

我应该在记录的每个构造函数中都使用这样的行吗

Self := Default(TRec);

Self := Default(TRec);

是，如果您希望构造函数初始化记录的每个字段

---

就个人而言，就可读性而言，我不太喜欢记录构造函数。当我看到：

foo := TBar.Create(...);

我希望

foo

是一个类的实例，因此我还希望在实例的生命周期结束时看到对

foo.Free

的调用

我自己倾向于使用静态类方法，总是命名为

New

，来构造新创建的值类型实例

我也不太喜欢你的

WithValue

实例方法。我认为强制类的使用者使用名称填充一个实例，然后在该实例上调用

WithValue

，通过提供值来完成任务，这感觉有点笨拙。我会这样写：

type
  TRec = record
  strict private
    FName: String;
    FValue: Integer;
  public
    property Name: String read FName;
    property Value: Integer read FValue;
  public
    class function New(const Name: String; const Value: Integer): TRec; static;
  end;

class function TRec.New(const Name: String; const Value: Integer): TRec;
begin
  Result.FName := Name;
  Result.FValue := Value;
end;

---

关于带值是一个ValueObject模式。记录是不可变的，这就是一个例子。但通常构造函数的名称类似于CreateForPerson（APerson…）等，用于描述参数意图。但是我认为实际上使用静态方法构造新实例有点错误，并开始将构造函数作为更“标准”的方式来使用。但是我发现这并不是最好的方法，我以前使用的静态方法（你说你也使用它们）更好。当静态方法看到结果类型时，我们已经明确知道它未初始化，我们需要编写result:=Default（txx）；然后设置所需的字段。感谢您对记录和构造函数的输入。我认为我回答的第二部分很大程度上取决于个人偏好。我不认为任何一种方法在绝对意义上更好。