Delphi编译器何时创建隐式接口变量？

我在这里测试了一段代码，寻找StackOverflow上的注释，我遇到了一个隐式接口变量抬头的情况。我看不出是什么导致了这种情况。我有一个小工厂，它为一个新创建的对象返回一个接口。如果我在过程块中调用该方法，那么我只得到1的引用计数。如果我从主程序块调用它，那么我得到的引用计数是2

我用Delphi10西雅图进行了测试。是否有包含隐式接口创建规则的资源，工厂返回接口的模式是否不是可靠的模式

program TestRefCount;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  Vcl.Dialogs;

type
  IMyInterface = interface(IInterface)
    ['{62EB2C46-9B8A-47CE-A881-DB96E6F6437D}']
    procedure DoSomething;
    function GetRefCount: Integer;
  end;

  TMyObject = class(TInterfacedObject, IMyInterface)
  strict private
    FMyValue: Integer;
  public
    procedure Init;
    procedure DoSomething;
    function GetRefCount: Integer;
  end;

  TMyFactory = class(TObject)
  private
    function CreateMyInt: IMyInterface;
  end;

procedure TMyObject.DoSomething;
begin
  MessageDlg(IntToStr(FMyValue), mtInformation, [mbok], 0);
end;

function TMyObject.GetRefCount: Integer;
begin
  Result := FRefCount;
end;

procedure TMyObject.Init;
begin
  FMyValue := 100;
end;

function TMyFactory.CreateMyInt: IMyInterface;
var
  myObject: TMyObject;
begin
  myObject := TMyObject.Create;
  Assert(myObject.GetRefCount = 0);
  myObject.Init;
  Assert(myObject.GetRefCount = 0);
  Result := myObject;
  Assert(myObject.GetRefCount = 1);
  Assert(Result.GetRefCount = 1);
end;

procedure WorkWithIntf;
var
  myFactory: TMyFactory;
  myInt: IMyInterface;
begin
  myFactory := TMyFactory.Create;
  try
    myInt := myFactory.CreateMyInt;
    Assert(myInt.GetRefCount = 1);
    myInt.DoSomething;
    Assert(myInt.GetRefCount = 1);
  finally
    myFactory.Free;
  end;
end;

var
  myFactory: TMyFactory;
  myInt: IMyInterface;
begin
  try
    // This case doesn't have an implicit interface variable
    WorkWithIntf;
    // This case does have an implicit interface variable
    myFactory := TMyFactory.Create;
    try
      myInt := myFactory.CreateMyInt;
      Assert(myInt.GetRefCount = 1); // This fails because the refcount is 2
      myInt.DoSomething;
      Assert(myInt.GetRefCount = 1);
    finally
      myFactory.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

以下是没有IMPLIT接口变量的第一个块：

TestRefCount.dpr.67: myInt := myFactory.CreateMyInt;
005C6A5A 8D55F8           lea edx,[ebp-$08]
005C6A5D 8B45FC           mov eax,[ebp-$04]
005C6A60 E83BFEFFFF       call TMyFactory.CreateMyInt
TestRefCount.dpr.68: Assert(myInt.GetRefCount = 1);
005C6A65 8B45F8           mov eax,[ebp-$08]

TestRefCount.dpr.86: myInt := myFactory.CreateMyInt;
005CF513 8D55EC           lea edx,[ebp-$14]
005CF516 A19CB75D00       mov eax,[$005db79c]
005CF51B E88073FFFF       call TMyFactory.CreateMyInt
005CF520 8B55EC           mov edx,[ebp-$14]
005CF523 B8A0B75D00       mov eax,$005db7a0
005CF528 E8C7E3E3FF       call @IntfCopy
TestRefCount.dpr.87: Assert(myInt.GetRefCount = 1); // This fails because the refcount is 2
005CF52D A1A0B75D00       mov eax,[$005db7a0]

这里是第二个块，我们可以看到隐式接口变量：

TestRefCount.dpr.67: myInt := myFactory.CreateMyInt;
005C6A5A 8D55F8           lea edx,[ebp-$08]
005C6A5D 8B45FC           mov eax,[ebp-$04]
005C6A60 E83BFEFFFF       call TMyFactory.CreateMyInt
TestRefCount.dpr.68: Assert(myInt.GetRefCount = 1);
005C6A65 8B45F8           mov eax,[ebp-$08]

TestRefCount.dpr.86: myInt := myFactory.CreateMyInt;
005CF513 8D55EC           lea edx,[ebp-$14]
005CF516 A19CB75D00       mov eax,[$005db79c]
005CF51B E88073FFFF       call TMyFactory.CreateMyInt
005CF520 8B55EC           mov edx,[ebp-$14]
005CF523 B8A0B75D00       mov eax,$005db7a0
005CF528 E8C7E3E3FF       call @IntfCopy
TestRefCount.dpr.87: Assert(myInt.GetRefCount = 1); // This fails because the refcount is 2
005CF52D A1A0B75D00       mov eax,[$005db7a0]

---

据我所知，并且没有在任何文档中记录，编译器以不同的方式处理局部变量和全局变量。对于本地用户，它相信分配给本地用户的任务会成功。因此，不需要隐式局部搜索。这是你的第一个病例

对于全局变量，编译器更为谨慎。它以怀疑的眼光看待全局变量。如果变量赋值失败，它会发出防御代码。编译器首先分配给一个隐式局部变量，这个赋值肯定会成功。因此，接口的引用计数将增加。然后分配给全局。如果失败，那么至少隐式局部有一个引用，并且能够减少它并正确地释放接口

您可能想知道为什么编译器对分配给全局变量感到紧张。你知道它是安全的，不能失败，编译器害怕什么？其全局变量的概念更为广泛。它会考虑一个指向接口引用的指针，例如，它是全局的。编译器试图防止指针无效、赋值失败以及没有人引用接口。编译器只考虑两种情况：局部和全局。它信任对局部变量的赋值，而其他一切都与潜在风险的全局变量相结合。包括你完全安全的全球服务

在我看来，编译器过于谨慎了。如果程序员说变量可以赋值，我不认为编译器应该怀疑它。如果程序员犯了错误，那么程序员当然应该准备好接受后果。它们可能是泄漏，也可能是运行时内存访问失败。但设计师们采取了一种不同的、更保守的方法

看到隐式局部变量的另一种情况是在函数返回值上使用

as

运算符。例如：

Foo := GetBar as IFoo;

更多信息请点击此处：

不过，这种情况是明确的。隐式局部变量非常重要，因为

as

引发异常是完全合理的