Erlang 备份/恢复mnesia数据库的正确方法是什么？

警告：背景信息很长。如果您认为需要在背景信息之前回答问题，请跳到底部。感谢你花这么多时间

我浏览了所有的网页（阅读谷歌），但我没有找到一个好的答案。是的，在erlang.org网站上有很多关于Mnesia文档的链接和参考，但即使是这些链接也存在版本问题

因此，在最简单的情况下，如果当前连接到的节点（）与表集的所有者相同，则备份/恢复将正常工作。例如：

$ erl -sname mydatabase

> mnesia:start().
> mnesia:create_schema(...).
> mnesia:create_table(...).
> mnesia:backup("/tmp/backup.bup").
> mnesia:restore("/tmp/backup.bup", [{default_op, recreate_tables}]).

嘿，这太棒了

但是，如果数据库实际运行在远程节点（）或远程节点（）上，则必须通过以下方式启动备份：

$ erl -sname mydbadmin

> rpc:call(mydatabase@host, mnesia, backup, ["/tmp/backup.bup"]).
> rpc:call(mydatabase@host, mnesia, restore, ["/tmp/backup.bup", [{default_op, recreate_tables}]]).

当然，这也很简单。现在有一些棘手的事情

• 假设您正在进行每日备份。你的mnesia数据库服务器死了，你不得不更换硬件。如果要按原样恢复数据库，则需要使用与以前相同的名称命名新硬件，并且还需要使用相同的名称命名节点
• 如果要更改硬件和/或节点（）的名称。。。或者，如果要在另一台计算机上进行恢复，则需要执行节点更改过程。（在mnesia文件中描述和说明）

但这就是事情变得复杂的地方。虽然我的熟人，erlang和mnesia专家建议，mnesia的复制存在严重缺陷，您不应该使用它（据我所知，目前没有替代方案，您实施更好版本的可能性有多大；不太可能）

因此，您有两个节点（）用于复制ram和基于磁盘的表。您一直在维护使用默认BackupMod定期使用标准备份备份数据库的策略。有一天，一位经理要求您验证备份。仅当您尝试还原您获得的数据库时：

{atomic,[]}

根据文件，这意味着没有错误。。。但没有恢复任何桌子

如果不想运行change_node过程，请记住node（）和hostname必须匹配，因此可以更改hostname和-sname参数以匹配备份数据的计算机。但是，这一次您会遇到一个奇怪的错误：

{aborted,{'EXIT',{aborted,{bad_commit,{missing_lock,mydatabase@otherhost}}}}}

仍然不想运行change_node过程，我快速克隆并恢复我的服务器，这样我就有了两台类似的机器。然后，我适当地命名以匹配生产服务器。我开始恢复过程。尤里卡！我现在在恢复服务器上有了真实的工作数据

我想说这是路的尽头。。。但我还没有问一个问题，所以。。。。就在这里

问题：如果要恢复从已复制mnesia节点群中获取的备份，如何修改该文件（类似于更改节点过程），以便忽略或从备份中删除其他节点

---

问题略有不同：如何在单个节点（）上恢复复制的多节点（）mnesia数据库？

我认为这个问题属于与简单问题相关的更广泛的mnesia问题范畴：

如何重命名Mnesia节点

如果数据库不是很大，第一个也是最简单的解决方案是使用mnesia:traverse\u备份功能（请参阅）。 以下是《Mnesia用户指南》中的一个示例：

change_node_name(Mod, From, To, Source, Target) ->
    Switch =
        fun(Node) when Node == From -> To;
           (Node) when Node == To -> throw({error, already_exists});
           (Node) -> Node
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, lists:map(Switch,Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, lists:map(Switch, Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Mod, Target, Mod, Convert, switched).

view(Source, Mod) ->
    View = fun(Item, Acc) ->
                   io:format("~p.~n",[Item]),
                   {[Item], Acc + 1}
           end,
    mnesia:traverse_backup(Source, Mod, dummy, read_only, View, 0).

这里最重要的部分是

{schema，db_nodes，nodes}

元组的操作，它允许您重命名或替换db节点

顺便说一句，我在过去使用过这个函数，我注意到备份术语的格式在mnesia版本之间发生了变化，但可能只是因为我写了不好的代码。只要打印一个小型mnesia数据库的备份日志，检查备份术语格式，如果您想确定的话

---

希望这有帮助

我很难做到这一点，所以我将分享我所经历的步骤

首先备份分布式系统中要恢复的节点（到单个节点）：

确保要还原到的节点上有以下

change\u node\u name

自适应：

-module(move_backup).
-export([set_node_name/4]).                                                                                                    

set_node_name(From, To, Source, Target) ->
    Switch =
        fun (Nodes) ->
                case lists:member(From, Nodes) of
                    true -> [To];
                    false -> []
                end
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, Switch(Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, Switch(Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Target, Convert, switched).

转换备份：

> move_backup:set_node_name('before@host', 'after@host', "/path/to/backup", "/path_to_backup_converted").

我将假设新节点完全为空（如果不是这种情况，您可能需要更改

default\u op

参数）。有两个选项，一个用于实时恢复：

> mnesia:restore("/path/to/backup_converted", [{default_op, recreate_tables}]).

这很好，但如果您有一个大型数据库，可能会占用大量内存（我的数据库容量约为10GB，因此导致内存不足异常）。另一种方法是安装回退，然后重新启动shell：

> mnesia:install_fallback("/path/to/backup_converted").
> q().

---

然后，当您重新启动shell时（假设您使用的是正确的节点名称），它将导入完整的数据库。

我有文本，它没有说明任何关于备份或恢复mnesia服务器集群的内容。您在问题中提到，您知道change node示例，这也包含在我指出的文档中。如果我正确理解了你的问题，在同一个例子中，你可以看到元组{schema，db_nodes，nodes}被检查：这个元组包含为Mnesia数据库注册的节点。啊！我在变更节点代码中遗漏了这一点。（您的答案没有提到这一点，但是，change_node（）应该是正确的答案。）谢谢。我也应该看看。

> mnesia:install_fallback("/path/to/backup_converted").
> q().