Excel 使用输入规范生成SAS代码

我们有一套在SAS中开发的预定义宏，用于使用SAS数据集生成表、列表和图形。我的要求是专门为表自动生成SAS代码。对于要生成的表，有一些固定数量的模板可用。此外，还可以使用SAS程序生成每个表的输出。每当需要从这些模板生成表时，都需要修改相关的SAS程序以生成所需的输出

为了避免每次单独编写SAS程序以生成固定类型的输出的冗余，我想创建一个工具来生成SAS代码。此代码将用作生成表的源代码

我准备了一份excel工作簿，其中包含构建程序所需的所有详细信息，如各种参数及其值，例如标题、脚注、源数据集、按行/列分组。Excel中创建的简单用户表单用于显示和配置这些参数

现在的问题是-如何使用Excel VBA生成SAS语句？以及如何使用Excel VBA连接SAS以执行SAS程序

如果你以前做过类似的事情，或者你对这类问题陈述有什么想法，请在这里分享。任何帮助都是值得感激的

---

谢谢。

我不会涉及VBA。我会编写一个SAS程序来读取需求，生成表格，并将它们推回到一个新的Excel程序中。如果您想完全从Excel程序中驱动它，我建议使用SAS Excel加载项而不是VBA代码，尽管您可以通过VBA触发它。Chris Hemidinger是SAS在这类问题上的专家，他确实在communities.SAS.com上发布，因为另一位用户表示您应该在评论中发布

创建空表是一个简单的过程，但是报表表通常有一个非常特定的布局，因此您可以进一步概括这个过程。例如，我有一个宏，它为一个数据集创建我的标准表1特征表，我只需要按类型continuous、Category、binary指定输入变量，然后生成输出，并通过ODS excel将其推送到excel。我还使用PROC REPORT来格式化它，因为我将为不同的变量交替着色行，这样更易于读取/显示

/*
This macro creates a table of charateristics for the variables listed.  
It handles categorical, binary and continuous variables and produces and output dataset that can be further customized. No statistical information is
included in this analysis
*/

/*Parameters to be set:
dsetin - name of dataset to be analyzed
cont = macro variable list of variable names, ie cont=age weight height
cat=list of categorical variables ie cat=sex grade
bin=binary variables, such as smoking now, smoking ever
dsetout=name of output dataset
Run example at the end for a sample output dataset call sample_table_char in the work directory
*/


*options mprint symbolgen;
%macro table_char(dsetin, cont, cat, bin, dsetout);


*delete old dataset;

proc datasets nodetails nolist;
    delete &dsetout;
quit;

/****************************************************************
Handle Categorical Variables
****************************************************************/

*loop through variable list;
%let i=1;
%do %while (%scan(&cat, &i, " ") ^=%str());
%let var=%scan(&cat, &i, " ");  

*Get format for variable;
data _null_;
 set &dsetin;
 call symput("var_fmt", vformat(&var));
run;



proc freq data=&dsetin noprint;
    table &var/missing out=tab_var;
run;



data temp1;
    length categorical $200.; format categorical $200.;
    length value $200.; format value $200.;

    set tab_var;
    percent=percent/100;
    categorical=put(&var., &var_fmt.);
    if _n_=1 then do;
        value=put(count, 8.)||"("||compress(put(percent, percent8.1))||")";
        order=2;
        output;
        order=1;
        value='';
        categorical=propcase(vlabel(&var.));
        output;
    end;
    else do;
        order=2;
        value=put(count, 8.)||"("||compress(put(percent, percent8.1))||")";
        output;

    end;

    keep categorical value order;
run;

proc sort data=temp1 out=temp2 (drop=order); by order categorical; run;


proc append base=&dsetout data=temp2;
run;

*clean up;

proc datasets nodetails nolist;
    delete tab_var temp1 temp2;
run; quit;

*Increment counter;
%let i=%eval(&i+1);
%end; *Categorical;

/****************************************************************
Handle Continuous Variables
****************************************************************/

%let i=1;
%do %while (%scan(&cont, &i, " ") ^=%str());
%let var=%scan(&cont, &i, " "); 



proc means data=&dsetin (rename=&var=vn) noprint;
var vn;
output out=table_var n= nmiss= mean= min= max= std= median= p25= p75= p90=/autoname;
run;

*get label of variable for clean reporting;
data _null_;
 set &dsetin;
 call symput("var_label", vlabel(&var));
run;




data temp1;
    length categorical $200.; format categorical $200.;
    format value $200.; length value $200.;

    set table_var;

    categorical="&var_label.";
    value=.;
    output;

    categorical='Count(Missing)';
    value=put(vn_n, 5.)||"("||compress(put(vn_nmiss, 5.))||")";
    output;

    categorical='Mean (SD)';
    value=put(vn_mean, 8.1)||"("||compress(put(vn_stddev, 8.1))||")";
    output;

    categorical='Median (IQR)';
    value=put(vn_median, 8.1)||"("||compress(put(vn_p25, 8.1))||" - "||compress(put(vn_p75, 8.1))||")";
    output;

    categorical='Range';
    value=put(vn_min, 8.1)||" - "||compress(put(vn_max, 8.1));
    output;

    categorical='90th Percentile';
    value=put(vn_p90, 8.1);
    output;



    keep categorical value;
run;


proc append base=&dsetout data=temp1;
run;

*clean up;

proc datasets nodetails nolist;
    delete table_var temp1;
run; quit;

*Increment counter;
%let i=%eval(&i+1);
%end; *Continuous;

/*****************************************************************
Handle Binary Variables (only report 1s)
*****************************************************************/

%let i=1;
%do %while (%scan(&bin, &i, " ") ^=%str());
%let var=%scan(&bin, &i, " ");  



proc freq data=&dsetin noprint;
    table &var/missing out=tab_var;
run;

data tab_var;
    set tab_var;
    where &var=1;
run;

data temp1;
    length categorical $200.; format categorical $200.;
    length value $200.; format value $200.;

    set tab_var;
    percent=percent/100;
    if _n_=1 then do;
        value=put(count, 8.)||"("||compress(put(percent, percent8.1))||")";
        order=1;
        categorical=propcase(vlabel(&var.));
        output;
    end;
    keep categorical value;
run;




proc append base=&dsetout data=temp1;
run;

*clean up;

proc datasets nodetails nolist;
    delete tab_var temp1;
run; quit;

*Increment counter;
%let i=%eval(&i+1);
%end;*Binary;


%mend table_char;


/* *Example of macro usage; */
/* data sample; */
/*  set sashelp.class; */
/*  female=ifn( sex='F',1,0); */
/* run; */
/*  */
/*  */
/* %table_char(sample, height weight age, sex, female, sample_table_char); */

---

我建议尝试SAS institute excel论坛。另一个建议是查看VBA中的SAS加载项对象库。我管理的唯一VBA集成是更新SAS表：-我不确定您在这里问什么。您是否不确定如何从VBA生成文本文件？如果您知道如何做到这一点，那么生成SAS代码应该不会有问题。然而，我过去曾在这样的系统上工作过，我也会在SAS中生成SAS代码；这似乎是系统内更好的职责分离。编写一个SAS程序，读取Excel工作表，生成合适的SAS代码来创建表，然后运行SAS代码。感谢您的评论。为了进一步澄清我的问题，我正在寻找通过VBA生成SAS代码的解决方案。我很想知道是否有人已经用更合乎逻辑的方式做了这类事情。到目前为止，我的做法非常简单，编写自己的逻辑规则来生成预期的代码。感谢Reeza提供了寻找可能的解决方案的指针。