在excel中计算时差

我在excel中有两个日期“1/2/2016 01:56:05”和“8/3/2016 06:21:46”。如何以天和小时的形式计算它们之间的时差

---

谢谢

假设日期在单元格

A1

和

A2

中，这将生成一个带有分钟的答案，以及d:hh:mm格式的答案

=INT(A2-A1) & ":" & TEXT(A2-A1,"hh:mm")

如果不需要几分钟，请放下

：mm

如果您想要文本：

=INT(A2-A1) & " days, " & TEXT(A2-A1,"h") & " hours"

如果您希望文本包含分钟：

=INT(A2-A1) & " days, " & TEXT(A2-A1,"h"" hours, ""m"" minutes""")

---

使用双引号相互并排“转义”引号本身，并允许额外的文本出现在字符串中。正如Ron在回答中所述，同一格式字符串中的

h

后面的

m

表示分钟，因此您可以通过将两种格式都放在一种格式中来保存额外的A2-A1计算。

尝试将拼写的小时和分钟包括在内：

=INT(A2-A1) & " days, " & TEXT(A2-A1,"h "" hours, ""m "" minutes""")

---

请注意，由于

m

紧跟在

h

之后（忽略引号中的分隔符文本），因此它将被解释为分钟，而不是月份

我更喜欢使用小数形式的日期。它看起来很笨重，但我更高兴知道它在做什么

我通常会做的是将A1-A2放在单元格A3中，然后分别计算出组成部分：

Days: =INT(A3)
Hours: =INT((A3-INT(A3))*24)
Minutes: =INT(((A3*24)-INT(A3*24))*60)

或者，如果您想在一个公式中完成这一切：

=INT(A3)&" days, "&INT((A3-INT(A3))*24)&" hours, "&INT(((A3*24)-INT(A3*24))*60)&" min"

或者不使用A3

=INT(A1-A2)&" days, "&INT(((A1-A2)-INT(A1-A2))*24)&" hours, "&INT((((A1-A2)*24)-INT((A1-A2)*24))*60)&" min"

---

这不是最漂亮或最有效的方法，但你可以看到这种方法是如何计算时间的。

谢谢！但是我如何包括文本部分的会议记录呢？我尝试了下面的方法，但似乎不起作用：=INT（A2-A1）和“days”，TEXT（A2-A1，“h”）和“hours”，TEXT（A2-A1，“m”）和“min”