Gnuplot 是否可以偏移单个xtic/X的位置？

是否可以偏移gnuplot中单个xtic/Y的位置

在我的情况下，我有一个（传统风格的）x/y轴，xtic/y“0”结束在各自的轴上。我希望只有一个位于原点西南（左下）的“0”，而不是两个“0”（一个代表x，一个代表y），这样它就不会干扰轴

我使用的代码是：

reset
set xrange [-5:5];
set yrange [-5:5];

set size ratio 1
set xzeroaxis
set yzeroaxis
set border 0

set grid x2tics y2tics noxtics noytics
set x2tics 0.5 format "" scale 0
set y2tics 0.5 format "" scale 0
set xtics axis 1 
set ytics axis 1 

set arrow 1 from 0,-5.3 to 0,5.3 lt -1 filled head
set arrow 2 from -5.3,0 to 5.3,0 lt -1 filled head

plot 1/0

这个怎么样

代码：

### xtics, ytics only one zero
reset session
set xrange [-5:5]
set yrange [-5:5]

set size ratio 1
set xzeroaxis
set yzeroaxis
set border 0

set grid x2tics y2tics noxtics noytics
set x2tics 0.5 format "" scale 0
set y2tics 0.5 format "" scale 0
set xtics axis 1 
set ytics axis 1 
set xtics add ("" 0)
set ytics add ("" 0)
set label 1 "0" at 0,0 offset -1.5,-0.5

set arrow 1 from 0,-5.3 to 0,5.3 lt -1 filled head
set arrow 2 from -5.3,0 to 5.3,0 lt -1 filled head

plot 1/0
### end of code

结果：

### xtics, ytics only one zero
reset session
set xrange [-5:5]
set yrange [-5:5]

set size ratio 1
set xzeroaxis
set yzeroaxis
set border 0

set grid x2tics y2tics noxtics noytics
set x2tics 0.5 format "" scale 0
set y2tics 0.5 format "" scale 0
set xtics axis 1 
set ytics axis 1 
set xtics add ("" 0)
set ytics add ("" 0)
set label 1 "0" at 0,0 offset -1.5,-0.5

set arrow 1 from 0,-5.3 to 0,5.3 lt -1 filled head
set arrow 2 from -5.3,0 to 5.3,0 lt -1 filled head

plot 1/0
### end of code