如何使gnuplot图表看起来更具视觉吸引力？

我已经在gnuplot工作了一段时间了。最近开始使用它创建要发送给客户的报告。我试着用我的绘图脚本进行试验，但效果不太好

我的问题很简单，如何让Gnuplot的图表看起来真的很棒？考虑D3/chartjs输出以进行比较

---

我理解“很棒”是主观的。但在这方面的一般指针会有很大帮助

在网上寻找你喜欢的调色板。一个很好的来源是

尝试边框样式、网格样式等。 一旦您对它感到满意，就将样式项放在

gnuplotrc

中

这是我的gnuplotrc：

set encoding utf8

# See https://github.com/Gnuplotting/gnuplot-palettes
# Line styles (colorbrewer Set1)
set style line 1 lc rgb '#E41A1C' pt 1 ps 1 lt 1 lw 2 # red
set style line 2 lc rgb '#377EB8' pt 6 ps 1 lt 1 lw 2 # blue
set style line 3 lc rgb '#4DAF4A' pt 2 ps 1 lt 1 lw 2 # green
set style line 4 lc rgb '#984EA3' pt 3 ps 1 lt 1 lw 2 # purple
set style line 5 lc rgb '#FF7F00' pt 4 ps 1 lt 1 lw 2 # orange
set style line 6 lc rgb '#FFFF33' pt 5 ps 1 lt 1 lw 2 # yellow
set style line 7 lc rgb '#A65628' pt 7 ps 1 lt 1 lw 2 # brown
set style line 8 lc rgb '#F781BF' pt 8 ps 1 lt 1 lw 2 # pink
# Palette
set palette maxcolors 8
set palette defined ( 0 '#E41A1C', 1 '#377EB8', 2 '#4DAF4A', 3 '#984EA3',\
4 '#FF7F00', 5 '#FFFF33', 6 '#A65628', 7 '#F781BF' )

# Standard border
set style line 11 lc rgb '#808080' lt 1 lw 3
set border 0 back ls 11
set tics out nomirror

# Standard grid
set style line 12 lc rgb '#808080' lt 0 lw 1
set grid back ls 12
unset grid

这是我的gnuplot文件模板：

set terminal pdfcairo enhanced color dashed font "Alegreya, 14" \
rounded size 16 cm, 9.6 cm

# Default encoding, line styles, pallette, border and grid are set in
# /usr/local/share/gnuplot/x.y/gnuplotrc.

set xlabel "x"
set ylabel "f(x)"
set grid
set key right top
set xrange[0:6.28]
set yrange[-1:1]
set output 'sinx.pdf'

plot sin(x) w l ls 1, cos(x) w l ls 2

（您应该将字体更改为可用的字体。）

看起来是这样的：

这很棒吗？嗯，我喜欢这样想！但严肃地说，这种布局是有原因的

• 我希望数据是最重要的。这就是为什么边框没有被放大，也没有背景色
• 尽管如此，我还是希望查看者看到图形与标签上显示的值的交叉位置，从而看到可见的记号和（不显眼的）网格

为了使图表“适合”文档的样式，我倾向于做以下几件事：

使用与文档正文相同的字体

对文档中的所有图形使用相同的大小、线条样式、边框等

将图形大小与列或文本块的宽度匹配

---

这不仅是主观的，而且取决于许多方面：输出意图、数据类型、目标受众等等。关于许多好的例子，我听到了。虽然gnuplotting有很多很好的例子，但它们往往属于“看看你能用gnuplot做什么”类型，而不是“如何让你枯燥的饼图/条形图看起来更好”。我想我应该提到我的数据和图表是相当基本的，我只是想知道是否有简单的方法可以让它们看起来比花几个小时进行gnuplot设置更好这太棒了！并且真正遵守“墨水越少越好”的规则（现在想不起书名）。祝大家好运。这太棒了。非常感谢你在这方面给我一个开头：）