Graph 如何使用gnuplot将两个长方体晶须图合并为一个

我有两个框须图，一个显示时间，另一个显示内存使用情况。请参阅下文：

显示时间使用情况的框须图：

显示内存使用情况的框须图：

gnuplot中是否有将这两个图形合并为一个图形的方法？理想情况下，我希望每个“X”条目并排绘制两个框须图。将有两个Y轴-y1显示时间，y2显示不同范围的内存

---

提前感谢。

由于您没有提供任何示例数据，我使用了gnuplot的candlestick.dem演示中的数据，并假设您在第一列中有JDK编号：

2.1 1 1.5 2   2.4 4   6.
2.2 2 1.5 3   3.5 4   5.5
3.0 3 4.5 5   5.5 6   6.5
3.1 4 3.7 4.5 5.0 5.5 6.1
4.0 5 3.1 3.5 4.2 5   6.1
5.0 6 1   4   5.0 6   9
6.0 7 4   4   4.8 6   6.1
7.0 8 4   5   5.1 6   6.1

打印操作如下所示：

使用线型-3打印空打印，线型-3不绘制任何内容，并使用xticlabels生成自定义XTIC

绘制相对于xtic向左移动一点的时间使用情况的框须

绘制相对于xtic向右移动一点的内存使用情况的框须

为简单起见，这里我对时间和内存使用相同的数据，但您当然可以使用不同的数据文件以及不同的y2range和yrange：

这使得：

---

内存绘图的链接已断开。如果你更新它，我可以包括图片。更新后，链接现在应该可以工作了。忘记启用“视图”。非常感谢@Christoph！成功了。只是想澄清一下，‘lt’表示‘线型’，‘t’表示‘标题’，对吗？@IshtiaqueHussain是的，我习惯于只使用速记。我更新了示例以使用更详细的选项。

set boxwidth 0.2 absolute
set offset 0.5,0.5,0,0

set yrange[0:10]
set y2range[0:10]
set ytics nomirror
set y2tics
set ylabel 'time usage'
set y2label 'memory usage'
set xlabel 'JDKs'

set key left

plot 'data.txt' using 2:4:xticlabels(1) linetype -3 notitle,\
     '' using ($2-0.15):4:3:7:6 with candlesticks linetype 1 title 'Quartiles, time' whiskerbars,\
     '' using ($2-0.15):5:5:5:5 with candlesticks linetype -1 linewidth 2 notitle,\
     'data.txt' using ($2+0.15):4:3:7:6 with candlesticks linetype 2 axes x1y2 title 'Quartiles, memory' whiskerbars,\
     '' using ($2+0.15):5:5:5:5 with candlesticks linetype -1 linewidth 2 axes x1y2 notitle