Oracle dbms_xmldom如何创建blob节点？

我有CR_元素程序，可以添加一个节点。 我现在必须创建一个blob节点，我想知道如何使用像CR_blob_元素这样的过程来创建它

有人能告诉我怎么做吗

问候,

皮埃尔

PS：我正在使用Oracle Database 11g 11.2.0.4.0版

 CR_BLOB_ELEMENT(l_domdoc in out dbms_xmldom.DOMDocument,
                               ref_node in dbms_xmldom.DOMNode,
                               nomel    in varchar2,
                               blobtobeadded   in blob)


   procedure CR_ELEMENT(l_domdoc in out dbms_xmldom.DOMDocument,
                           ref_node in dbms_xmldom.DOMNode,
                           nomel    in varchar2,
                           vnomel   in varchar2) as

        element  dbms_xmldom.DOMElement;
        node     dbms_xmldom.DOMNode;
        text     dbms_xmldom.DOMText;
        textnode dbms_xmldom.DOMNode;
      begin
        element  := dbms_xmldom.createElement(l_domdoc, nomel);
        node     := dbms_xmldom.appendChild(ref_node,
                                            dbms_xmldom.makeNode(element));
        text     := dbms_xmldom.createTextNode(l_domdoc, vnomel);
        textnode := dbms_xmldom.appendChild(node, dbms_xmldom.makeNode(text));

      end;

如果对某人有用。 请在community.oracle.com上找到odie_63给出的以下答案。 这是完美的工作。 当做 皮埃尔

---

所以您需要将二进制数据转换为XML文档？如果是这样的话，那么一个选项就是将二进制数据编码为Base64格式。Tks Jokke。我确实将base64编码的blob写入了数据库，但在将其写入xml时，我遇到了麻烦。由于varchar2的限制，它的内容恐怕会被截断。我说的对吗？Base64是基于文本的格式。如果可以将blob转换为clob/varchar2，那么就不会有任何问题。如果大小有限制，只需将数据分割成更小的部分。关于它还有很多其他问题/文章。对不起，我错了，DOM节点大小可能有限制…我已经找到了很多关于这个主题的文章，但实际上我还不清楚。谢谢你抽出时间。

SQL> create table images (  
  2    id       integer  
  3  , name     varchar2(256)  
  4  , content  blob  
  5  );  

Table created  

SQL>  
SQL> declare  
  2   
  3    bf          bfile := bfilename('XML_DIR','base64.bin');  
  4    lob_ptr     blob;  
  5    dest_offs   integer := 1;  
  6    src_offs    integer := 1;  
  7   
  8  begin  
  9   
10    insert into images (id, name, content)  
11    values (1, 'Koala.jpg', empty_blob())  
12    returning content into lob_ptr;  
13   
14    dbms_lob.open(bf, dbms_lob.lob_readonly);  
15    dbms_lob.loadblobfromfile(lob_ptr, bf, dbms_lob.getlength(bf), dest_offs, src_offs);  
16    dbms_lob.close(bf);  
17   
18  end;  
19  /  

PL/SQL procedure successfully completed  

SQL> commit;  

Commit complete  

SQL>  
SQL> select id  
  2       , name  
  3       , utl_raw.cast_to_varchar2(dbms_lob.substr(content, 30)) as first_bytes  
  4       , dbms_lob.getlength(content) as lob_size  
  5  from images  
  6  /  

   ID NAME         FIRST_BYTES                      LOB_SIZE  
----- ------------ -------------------------------- ----------  
    1 Koala.jpg    /9j/4AAQSkZJRgABAgEAYABgAAD/7g      1068504  

SQL>  
SQL> declare  
  2   
  3    x_doc       xmltype;  
  4    domdoc      dbms_xmldom.DOMDocument;  
  5    domnode     dbms_xmldom.DOMNode;  
  6    domtext     dbms_xmldom.DOMText;  
  7    ostream     sys.utl_BinaryOutputStream;  
  8    chunksize   pls_integer;  
  9    offset      pls_integer := 1;  
10    buf         raw(32767);  
11    image       blob;  
12   
13  begin  
14   
15    select xmlelement("image",  
16             xmlelement("id", t.id)  
17           , xmlelement("name", t.name)  
18           , xmlelement("content")  
19           )  
20         , t.content  
21    into x_doc  
22       , image  
23    from images t  
24    where t.id = 1 ;  
25   
26    domdoc := dbms_xmldom.newDOMDocument(x_doc);  
27   
28    -- get /image/content node so that we can append a text node and stream the BLOB to it :  
29    domnode := dbms_xslprocessor.selectSingleNode(dbms_xmldom.makeNode(domdoc), '/image/content');  
30    domtext := dbms_xmldom.createTextNode(domdoc, null);  
31    domnode := dbms_xmldom.appendChild(domnode, dbms_xmldom.makeNode(domtext));  
32   
33    ostream := DBMS_XMLDOM.setNodeValueAsBinaryStream(domnode);  
34    chunksize := dbms_lob.getchunksize(image);  
35   
36    loop  
37      begin  
38        -- read BLOB in chunk of <chunksize> :  
39        dbms_lob.read(image, chunksize, offset, buf);  
40      exception  
41        when no_data_found then  
42          exit;  
43      end;  
44      -- write chunk to DOM node :  
45      ostream.write(buf, chunksize);  
46      offset := offset + chunksize;  
47    end loop;  
48   
49    ostream.flush();  
50    ostream.close();  
51   
52    dbms_xmldom.writeToFile(domdoc, 'XML_DIR/image.xml');  
53    dbms_xmldom.freeDocument(domdoc);  
54   
55  end;  
56  /  

PL/SQL procedure successfully completed  

Output in image.xml :

<image>  
  <id>1</id>  
  <name>Koala.jpg</name>  
  <content>/9j/4AAQSkZJRgABAgEAYABgAAD/7gAOQWRvYmUAZAAAAAAB/+EUI0V4aWYAAE1NACoAAAAIAAcB  
MgACAAAAFAAAAGIBOwACAAAABwAAAHZHRgADAAAAAQAEAABHSQADAAAAAQA/AACcnQABAAAADgAA  
AADqHAAHAAAH9AAAAACHaQAEAAAAAQAAAH0AAADnMjAwOTowMzoxMiAxMzo0ODoyOABDb3JiaXMA  
...  
aWpkRY6dqaJY42qFjs8ZZ5nlkjZpmJUiJ1+ijn3dVeTtb4B1R5NJVaEkn/V8+u4Xijpp6SFlimp6  
qNHgjlVIgrtLCyxll1NpaT6An6W92mA8HwkyadMeEZJjEDmvE/t/1f5uv//Z</content>  
</image>