Vbscript 遍历文件夹并查找特定文件

我编写了这段代码来遍历文件夹，并在找到“.c”文件时退出函数。理想情况下，它应该返回“.c”文件的路径。但它返回的是空字符串

tval = 1
Function findStlcode(objFSO,fFolder,folderName)
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set Folder = objFSO.GetFolder(fFolder)
    Set colfiles = Folder.Files
    For Each objFile In colfiles
        strFilename = objFile.name
        If strcomp(strFilename,folderName & ".c",vbTextCompare) = 0 Then
            findStlcode = fFolder & "\" & folderName & ".c"
            tval = tval + 1
            Exit Function
        End If
    Next
    For Each Subfolder In Folder.SubFolders
        If tval = 1 Then
            xx = findStlcode(objFSO, Subfolder.Path, folderName)
        End If
    Next
End Function

---

将FOR循环内容更改为以下，将xx更改为findStlcode，它应该可以工作

strFilename = objFile.name
If Right(strFilename, 2) = ".c" Then
    findStlcode = fFolder & "\" & strFilename
    tval = tval + 1
    Exit Function
End If

---

完成下面的代码

tval = 1
Function findStlcode(objFSO,fFolder)
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set Folder = objFSO.GetFolder(fFolder)
    Set colfiles = Folder.Files
    For Each objFile In colfiles
        strFilename = objFile.name
        If Right(strFilename, 2) = ".c" Then
            findStlcode = fFolder & "\" & strFilename
            tval = tval + 1
            Exit Function
        End If
    Next
    For Each Subfolder In Folder.SubFolders
        If tval = 1 Then
            findStlcode = findStlcode(objFSO, Subfolder.Path)
        End If
    Next
End Function

---

调用函数

Set objFSO = CreateObject("Scripting.FileSystemObject")
Wscript.Echo findStlcode(objFSO, "C:\")

---

问题的根本原因是函数实际上没有返回路径（通过将路径指定给函数名），其他人已经指出了这一点

但是，您的实现中还有一些其他问题需要解决：

• 您不应该使用全局变量来跟踪是否找到匹配的文件。递归函数调用的返回值也可以用于相同的效果
• 如果要在每次函数调用中重新创建它，那么传递

  objFSO

  是没有意义的。实际上，在任何情况下，最好创建一个

  FileSystemObject

  实例作为全局（单例）对象，并在脚本中的任何地方使用它
• 传递文件夹对象而不是路径字符串，这样您就不必在下一个递归步骤中将字符串转换回文件夹对象
• 如果要检查扩展名，请使用适当的方法从文件名（）中提取扩展名

这样就足够了：

Set fso = CreateObject("Scripting.FileSystemObject")

Function findStlcode(fldr)
  Dim f, sf, path

  For Each f In fldr.Files
    If LCase(fso.GetExtensionName(f)) = "c" Then
      path = f.Path
      Exit For
    End If
  Next

  For Each sf In fldr.SubFolders
    If IsEmpty(path) Then path = findStlcode(sf)
  Next

  findStlcode = path
End Function

startFolder = "C:\some\folder"
cfile = findStlCode(fso.GetFolder(startFolder))

---

我看不出你是如何返回结果的。什么类型的“findStlcode”？@Zam返回不正确，因为OP在递归中将其分配给xx