Xml 如何在XSLT遗留代码库中查找死代码

我从一个帮助我分析XSLT遗留代码库的脚本开始。有大约100个XSLV1.0文件，多年来有点混乱

代码需要清理。第一步是查找未使用的代码（模板、变量等）

我的问题是如何查找不再使用的匹配模板：

 <xsl:template match="blabla">...</xsl:template>

。。。

---

一般来说，找到永远不会执行的匹配模板（带或不带模式属性）的最佳方法是什么？

模板规则可能永远不会执行的原因有两个：或者总是优先选择另一个模板规则，或者，没有一个节点与其模式匹配的源文档。通过对样式表的静态分析来检测这两种情况都是不实际的。您最好的选择是使用源文档的代表性示例（以及样式表参数值等其他输入条件）动态地进行一些代码覆盖率分析

谷歌搜索“代码覆盖率XSLT”是值得的，尽管它会给你更多的问题而不是答案。XSpec不会覆盖代码，但前提是您有一套全面的XSpec测试，这似乎不太可能。Saxon有一个工具（-TP:profile.html），用于输出每个模板规则执行的频率，但遗憾的是，它忽略了计数为零的那些模板规则。将这些数据与一些源代码分析相结合，以找到列表中没有出现的模板规则（以及将多个运行的输出与不同的源文档相结合），并不难

对许多源文档实际执行样式表的另一种方法是将匹配模式提取到一个合成样式表中，该样式表根据每个匹配模式测试每个输入节点。您可以为每个匹配输出一个元素，然后对输出进行后期处理，以查找输出中缺少的模式：

第一:

<xsl:template match="... a sample pattern... ">
  <match id="654321"/>
  <xsl:apply-templates select="@*|node()"/>
</xsl:template>
(repeated for each pattern in the original stylesheet)

（对原始样式表中的每个模式重复）

然后进行分析：

<xsl:variable name="data" select="."/>
<xsl:key name="k" match="match" use="@id"/>
<xsl:for-each select="1 to max(//match/@id)[not(key('k', ., $data))]">
  No matches for pattern id="{.}"
</xsl:for-each>

模式id=“{.}”没有匹配项

但是，对于可以由

xsl:apply imports

或

xsl:next match

指令触发的模板规则，或者对于匹配多个模板规则的节点（可能在不同模式下），这将为您提供错误的“不匹配”结果。我相信这个想法是可以改进的

代码需要清理。第一步是查找未使用的代码 （模板、变量等）

我的问题是如何查找不再使用的匹配模板：

 <xsl:template match="blabla">...</xsl:template>

好消息是事情并不像我在另一个答案中看到的那样理论化（几乎没有希望）。仅通过静态分析就可以获得许多有用的信息

最近我做了类似的事情。这个简单的转换发现，在530.xsl或.xslt文件中，有180个是“Main”（未导入或包含在任何其他样式表中）

然后逐个查看“Main”样式表并确定是否曾经将其用作主（独立）转换，这样就可以排除大量此类XSLT文件

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:variable name="vBaseFileUrl" select="'file:///C:/TheDirectoryPathToTheXSLTCode'"/>

 <xsl:variable name="vStyleSheets" select=
 "collection(concat($vBaseFileUrl, '?select=*.xsl;recurse=yes'))
 |
  collection(concat($vBaseFileUrl, '?select=*.xslt;recurse=yes'))"/>


  <xsl:template match="/">
    Number of *.xsl | *.xslt stylesheets: <xsl:value-of select="count($vStyleSheets)"/>

    Document URIs:
    <xsl:variable name="vdocURIs" select="$vStyleSheets/document-uri(.)"/>
    <xsl:value-of select="$vdocURIs" separator="&#xA;"/>

    <xsl:variable name="vDistinctFilenames" select=
    "distinct-values($vStyleSheets/tokenize(document-uri(.), '/')[last()])"/>

    <xsl:value-of select="'&#xA;','&#xA;',
                          'Distinctly named stylesheets: ', count($vDistinctFilenames)"/>

<xsl:variable name="vMainFilenames" select=
"$vDistinctFilenames
    [not(. = $vStyleSheets/*/(xsl:import | xsl:include)/tokenize(@href, '/')[last()])]"/>

<xsl:value-of select="'&#xA;','&#xA;','Main filenames: ', count($vMainFilenames)"/>

<xsl:variable name="vMainStylesheets" select=
"$vStyleSheets[tokenize(document-uri(.), '/')[last()] = $vMainFilenames]
"/>

  <xsl:value-of select="'&#xA;','&#xA;','Main stylesheets: ', count($vMainStylesheets)"/>

==========================================
    Document URIs grouped by name: <xsl:text/>
    <xsl:for-each-group select="$vdocURIs" group-by="tokenize(., '/')[last()]">
      <xsl:sort select="current-grouping-key()"/>
      <xsl:variable name="vStylesheetFilename" select="current-grouping-key()"/>
      <xsl:variable name="vImportedOrIncluded" select=
      "$vStyleSheets[/*/(xsl:import | xsl:include)[tokenize(@href, '/')[last()] 
                     eq $vStylesheetFilename]][1]"/>

      <xsl:value-of select="'&#xA;', '&#xA;', 
                            $vStylesheetFilename, 
                            if(empty($vImportedOrIncluded)) then ' Main ' else (), ':'"/>
==========================================
<xsl:text/>

      <xsl:variable name="vUrisInGroup" as="xs:string*">
        <xsl:perform-sort select="current-group()">
          <xsl:sort select="."/>
        </xsl:perform-sort>
      </xsl:variable>

      <xsl:for-each select="$vUrisInGroup">
        <xsl:value-of select=
           "substring-after(., substring-before(., 'nameOfRootDir')), '&#xA;'"/>
      </xsl:for-each>
    </xsl:for-each-group>
  </xsl:template>
</xsl:stylesheet> 

*.xsl |*.xslt样式表的数量：
文档URI：
==========================================
按名称分组的文档URI：
==========================================

---

在匹配模板的级别上：

让我们有：

<xsl:template match="possiblySomepath/someName[PossiblySomePredicate]/possibleTailPath">

我们分析了一组可能的源XML文档，并确定这些文档从不包含名为“someName”的元素——或者在更好的情况下，我们提供了源XML模式，从中我们可以看到文档中不包含名为“someName”的元素。然后我们可以安全地删除该模板

至于“Main”样式表，在我们排除了这些明显的样式表之后，我们可以以类似的方式调查并找到没有匹配的

指令的命名的模板，然后去掉所有这些

代码如下所示：

==========================================
    <xsl:variable name="vTemplateNamesDistinct" 
      select="distinct-values($vStyleSheets/*/xsl:template/@name)"/>
    <xsl:value-of select=
    "'&#xA;','&#xA;','Distinct template names: ', count($vTemplateNamesDistinct)"/>

    <xsl:variable name="vnamedTemplatesNeverCalled" select=
   "distinct-values($vStyleSheets/*/xsl:template/@name
                     [not(. = $vStyleSheets//xsl:call-template/@name)])"/>
    <xsl:value-of select=
       "'&#xA;','&#xA;','Template names never called: ', count($vnamedTemplatesNeverCalled)"/>

    <xsl:value-of select="$vnamedTemplatesNeverCalled" separator="&#xA;"/>
==========================================

==========================================
==========================================

---

在我的例子中，大约有400个命名模板。其中有40多个命名模板未被调用。

没有“最佳”模板但是可以执行一些转换来分析代码库并找到排除的候选项。有一些有用的静态分析示例，这些示例易于编码和执行，可以提供帮助我们找到并消除死XSLT代码的结果。可能有一些这样的示例，但我怀疑大多数死模板规则都会出现仅仅是因为它们匹配的XML结构已经不再使用了。@MichaelKay对我来说，对许多源文档（在我们的例子中，源代码很少但很大）执行样式表是一种很好的概率方法。它有助于找到不再使用的规则的候选规则。我可以编写一个脚本来检测代码，并使分析变得简单。不需要其他工具支持。将匹配模式提取到合成样式表中更为复杂，因为在本例中，经常使用具有未知模式的临时xml树[…]，要找出规则所针对的节点类型是很困难的。让我们警告读者，如果正在研究的样式表集实现了多过程处理，那么第二种方法将不会给出具有代表性的结果。更准确地说，与中间处理过程中的某个节点匹配的模板（而不是原始输入中的任何节点）将被错误地标记为“不匹配”。谢谢分享想法和代码。我想你的代码做了一些类似于我链接的XQuery脚本的事情。但我正在理解：）并将稍后返回。@MarkusSchmid the be