Actionscript 3 如何将MOIVELIP连接到as3isolib网格？

我是使用AS3和as3isolib的初学者。我试图将fla库中的一些MC添加到isoGrid对象中。我试图使用IsoGrid类的addChild（）方法，但它给了我一个错误：1067：将[MovieClip Name]类型的值隐式强制到不相关的类型as3isolib.data:INode。我想这需要我使用node类

你知道怎么做这样的事吗

---

提前感谢。

as3isolib使用自己的

显示列表

像渲染树一样，在此树中添加所有节点必须实现

as3isolib。数据：INode

。有两种可能将flash本机显示对象添加到

IsoScene

：

看看这个小教程：

    //create IsoView, IsoScene and IsoGrid - default from as3isolib
    var view:IsoView = new IsoView();
    view.setSize(stage.stageWidth, stage.stageHeight);
    addChild(view);

    var scene:IsoScene = new IsoScene();
    view.addScene(scene);

    var grid:IsoGrid = new IsoGrid({cellSize:32});
    grid.setGridSize(800, 600);
    grid.stroke = new Stroke(0, 0x576F33);
    grid.render();

    //create iso box, just for demo
    var obj:IsoBox = new IsoBox();
    obj.setSize(32, 32, 64);
    obj.moveTo(5*32, 5*32, 1);

    //first possiblity to add flash.display.Shape to the iso scene - using IsoSprite.sprites
    var isoSprite:IsoSprite = new IsoSprite();
    isoSprite.moveTo(5*32, 7*32, 1);

    var shape1:Shape = new Shape();
    shape1.graphics.beginFill(0xFF0000, 1);
    shape1.graphics.drawRect(0, 0, 32, 32);
    isoSprite.sprites = [shape1];

    //second possiblity to add flash.display.Shape to the iso scene - using IsoDisplayObject.container
    var isoObj:IsoDisplayObject = new IsoDisplayObject();
    isoObj.moveTo(7*32, 7*32, 1);

    var shape2:Shape = new Shape();
    shape2.graphics.beginFill(0x0000FF, 1);
    shape2.graphics.drawRect(0, 0, 32, 32);
    isoObj.container.addChild(shape2);

    //add all objects to the scene and render all
    scene.addChild(grid);
    scene.addChild(obj);
    scene.addChild(isoSprite);
    scene.addChild(isoObj);
    scene.render();

---

这就是我想要的答案。非常感谢你，我的朋友。