Android Play Store（也是SHA1 Key Viewer）的简易编译、签名和zipalign APK方法

您如何轻松地将APK软件包编译并部署到Google Play Store？我一直在搜索最简单的安装方法，最后完成了以下操作？你能建议一个更好的方法吗

“您能在Android Studio中使用GUI而不是终端对APK文件进行签名和zip对齐吗？”

两个批处理文件，用于协助部署过程 我创建了以下批处理文件，以加快在各种设备上测试我的APK文件，同时我还开发了几个Android到Arudino通信的人。。因此，我可能需要在代码/语法发生一次更改后准备好APK。无论如何他们是干什么的

编译、签名、ZipAlign（Android Studio版本）

• 使用Gradle（包含在Android Studio中）将项目编译为发布版本
• 将发布APK从项目文件夹复制到您自己的发布文件夹
• 使用jarsigner使用密钥库文件对APK文件进行签名
• 使用ZipAlign创建APK的新副本，以供google Play商店使用
• 删除ZipAlign留下的原始文件

complile_release.bat

---

查看APK SHA1值 下面的批处理文件仅允许您根据需要查看SHA1密钥或其他详细信息

视图_sha1.bat

---

我希望这两个人能对人们有所帮助/帮助

StackOverflow是用来提问的。你的问题是什么？问题是，这是否是一种正确的或首选的方式来编译你的项目，同时也提供代码供人们使用。编辑时使用最上面的注释/问题。当阅读有关在StackExchange上发布问题的文章时，建议您提问并回答自己的问题，因为这是分享知识的好方法。。。所以我做了。。。您可能希望阅读StackOverflow文档并按照正确操作说明进行操作：您提供的链接应该可以从中轻松访问，因为我看不到ask页面上的直接链接。

@echo off
REM Modify the variables between the lines to match your installation and project
REM ----------------------------------------------------
set sKeyAlias=MyProjectNameAlias
set sStorePass=MyPassword
set sPathKeyStore=C:\Projects\Android\Key_Stores.keystore
set sFileTmp=igetdeleted.apk
set sFileOutput=MyProjectName.apk
set sPathOrigAPK=C:\Projects\MyProjectFolder\MyProjectName\build\apk\MyProjectName-release-unsigned.apk
set sPathOutput=C:\Projects\Releases
set sPathJavaBin=C:\Program Files\Java\jdk1.7.0_10\bin
set sPathAnTools=C:\Program Files\Android\android-studio\sdk\tools
set sPathGradle=C:\Projects\MyProjectFolder\
set sDriveGradle=%sPathGradle:~0,2% 
REM ----------------------------------------------------


REM -- Navigate to gradlew.bat folder and execute with "aR" for a release version
%sDriveGradle%
cd %sPathGradle%
call "gradlew.bat" aR

REM -- Copy the compiled APK to our output/release folder
copy "%sPathOrigAPK%" "%sPathOutput%\%sFileTmp%" /Y >nul

REM -- Sign the APK package
"%sPathJavaBin%\jarsigner.exe" -verbose -sigalg SHA1withRSA -digestalg SHA1 -keystore "%sPathKeyStore%" -storepass "%sStorePass%" "%sPathOutput%\%sFileTmp%" %sKeyAlias%

REM -- Zipalign the APK package (This creates a copy)
"%sPathAnTools%\zipalign.exe" -f -v 4 "%sPathOutput%\%sFileTmp%" "%sPathOutput%\%sFileOutput%"

REM -- Delete the original from the zipalign output the APK package
del "%sPathOutput%\%sFileTmp%"

REM -- Awaiting user input before closing the window
pause

@echo off

REM Modify the variables between the lines to match your installation and project
REM ----------------------------------------------------
set sKeyAlias=MyProjectNameAlias
set sStorePass=MyPassword
set sPathJavaBin=C:\Program Files\Java\jdk1.7.0_10\bin
set sPathKeyStore=C:\Projects\Android\Key_Stores.keystore
REM ----------------------------------------------------

REM -- This will use the Java keytool to display the some information about the APK including the SHA1 key as required for google
"%sPathJavaBin%\keytool" -list -v -keystore "%sPathKeyStore%" -storepass "%sStorePass%" -alias "%sKeyAlias%"

REM -- Awaiting user input before closing the window
pause