AppleScript将拖动的文档传递给另一个应用程序

多亏了，我的Mac有一个小AppleScript来打开Adobe Distiller的新会话

do shell script "open -n -a " & quoted form of "Acrobat Distiller"

新问题，要求对此进行一点改进。如果将一个.ps拖到（或者确实拖了几个）由该.scpt生成的.app，蒸馏器的新会话是否会与该文档（或这几个文档）一起打开

---

多谢各位

将以下脚本另存为应用程序。如果您运行该应用程序，它将允许您选择要在新实例中打开的文件；如果您将文件放在其上，它将在新实例中打开所有文件：

on run
    set filesToOpen to choose file with multiple selections allowed
    set fileListString to createUnixFileString(filesToOpen)
    makeNewInstanceWithFiles(fileListString)
end run

on open droppedFiles
    set fileListString to createUnixFileString(droppedFiles)
    makeNewInstanceWithFiles(fileListString)
end open

on createUnixFileString(aList)
    set fileString to ""
    repeat with thisItem in aList
        set fileString to fileString & " " & quoted form of (POSIX path of thisItem)
    end repeat
    return fileString
end createUnixFileString

on makeNewInstanceWithFiles(f)
    do shell script "open -n -a " & quoted form of "Acrobat Distiller" & f
end makeNewInstanceWithFiles

---

如果希望在单独的实例中打开每个文件，请为每个文件调用

makeNewInstanceWithFiles

（确保获取posix路径并包含空格作为分隔符），而不是调用

createUnixFileString

处理程序。

谢谢。太棒了。