Batch file 是否通过.bat文件更改文件夹图标？

如何制作一个.bat文件，自动将文件夹的图标更改为当前目录中的图标，即“transprent.ico”

您可以通过更改

Desktop.ini

文件来执行此操作

@echo off
set /p "fld=Folder: "
set /p "ico=Icon file: "
md "%fld%\icons" 2>nul
if exist %ico% copy "%ico%" "%fld%\icons\icon.ico" /y 1>nul
attrib -h -s "%fld%\desktop.ini" 2>nul
(
echo/[.ShellClassInfo]
echo/IconResource=icons\icon.ico,0
) > "%fld%\Desktop.ini"
attrib +h +s -a "%fld%\Desktop.ini"
attrib +r "%fld%"
attrib +h "%fld%\icons"
taskkill -im explorer.exe /f >nul&start explorer

---

我创建了这个批处理文件。将其放入要搜索的所有文件夹的父文件夹中。此版本将查找与ICO文件具有匹配名称的PNG，但如果愿意，可以编辑该部分，使其仅执行找到的ICO文件。它还将复制旧的desktop.ini文件，但您也可以选择编辑该文件

@echo off
set O=desktop.old
set F=desktop.ini
FOR /R %%I IN (*.ico) DO @(
cd%%~pI 
if exist %%~dpnI.png (
echo %%~dpnI.png
attrib -h -s %F% 
copy /Y %F% %O%
echo [.ShellClassInfo] > %F%
echo IconResource=%%~nxI,0 >> %F%
echo [ViewState] >> %F%
echo Mode= >> %F%
echo Vid= >> %F%
echo FolderType=Videos >> %F%
echo Logo=%%~nI.png >> %F%
attrib +h +s %F% 
)
)
cd ..

---

我知道这不是你想要的确切解决方案 但是，这仍然是一个解决办法

1.安装InPoint/FolderIco

2.将FolderIco.exe的路径添加到环境路径

3.按如下方式创建批处理文件：

FolderIco -f "[path to your directory]" --icon "path to your .ico file"