Maple 如何在特殊点绘制实验数据？

我有一组实验数据p，我想得到实验和预测的曲线图。为了做到这一点，我使用另一组依赖于pq的数据，绘制散点图，使用适当的拟合，然后获得回归线，并在适当的微分方程中使用其系数。P的曲线看起来不错，但我需要添加实验数据。为了简单起见，我使用了区间t=0..150

如何绘制实验数据，使P0=Pvals[1]，P10=Pvals[2]等。？此外，我如何分配数据，比如说，我有t=0..800，并且想要绘制Pvals，以便P0=Pvals[1]和P800=Pvals[16]

---

我不确定我是否完全遵循你的方法。但这是你想要实现的吗

restart;
with(Statistics):

Pvals := [3.929, 5.308, 7.24, 9.638, 12.866, 17.069, 23.192, 31.433,
          38.558, 50.156, 62.948, 75.996, 91.972, 105.711, 122.775, 131.669]:

for i to 15 do Qval[i] := .1*(Pvals[i+1]/Pvals[i]-1); end do:
Qvals := [seq(Qval[i], i = 1 .. 15), 0.144513895e-1]:

form := a*v^2+b*v+c:

CF := CurveFitting:-LeastSquares(Pvals, Qvals, v, curve = form);

       CF := 0.0370152282598477 - 0.000272504103112702 v

                               -7  2
              + 5.60958249026713 10   v

现在我在DE中使用CF，因为我不明白您为什么放弃v^2术语

#de := diff(P(t), t) = (0.370152282598477e-1-0.272504103112702e-3*P(t))*P(t);
de := diff(P(t), t) = eval(CF, v=P(t))*P(t);

           d         /                                              
    de := --- P(t) = \0.0370152282598477 - 0.000272504103112702 P(t)
           dt                                                       

                            -7     2\     
       + 5.60958249026713 10   P(t) / P(t)

我将使用dsolve命令的numeric选项，并获取一个为数值t值计算Pt的过程

现在再做一些调整，这也是我对你目标的猜测

endpt := fsolve(Pfunc(t)-Pvals[16]);

                  endpt := 135.2246055

Pfunc(endpt), Pvals[16];

               131.669000003321, 131.669

plot(Pfunc(t), t=0 .. endpt, size=[500,200]);

现在显示针对0的Pdata。。也是800,

---

这正是我一直想做的。我无意中放弃了v^2术语，很高兴你纠正了我。再次感谢你！

sol := dsolve({de, P(0) = 3.929}, P(t), numeric, output=listprocedure ):

Pfunc := eval(P(t), sol);

              Pfunc := proc(t)  ...  end;

Pfunc(0.0), Pvals[1];

                3.92900000000000, 3.929

endpt := fsolve(Pfunc(t)-Pvals[16]);

                  endpt := 135.2246055

Pfunc(endpt), Pvals[16];

               131.669000003321, 131.669

plot(Pfunc(t), t=0 .. endpt, size=[500,200]);

a,b,N := 0.0, 800.0, nops(Pvals);

                a, b, N := 0., 800.0, 16

Pfuncscaled := proc(t) 
                 if not t::numeric then
                   return 'procname'(args);
                 end if;
                 Pfunc(t*endpt/b);
               end proc:

Pfuncscaled(0), Pvals[1];

                3.92900000000000, 3.929

Pfuncscaled(800), Pvals[N];

               131.669000003321, 131.669

PLscaled := plot( Pfuncscaled(t), t=a .. b,
                  color=red, size=[500,200] );

V := Vector(N, (i)->a+(i-1)*(b-a)/(N-1)):

V[1], V[-1];

                    0., 800.0000000

Pdatascaled := plot( < V | Vector(Pvals) >,
                     color=blue, size=[500,200],
                     style=pointline, symbol=solidcircle );

plots:-display( PLscaled, Pdatascaled, size=[500,500] );