Rest 在open.mapquestapi.com上处理4GL GET请求

我有一个严重的问题，正确的GET方法调用获取一些地理位置数据。 我的代码相当标准，大部分来自ProgressKB和其他网站

DEFINE VARIABLE vcHost   AS CHARACTER INITIAL "open.mapquestapi.com" NO-UNDO.
DEFINE VARIABLE vcPort   AS CHARACTER INITIAL "80" NO-UNDO.
DEFINE VARIABLE vhSocket AS HANDLE    NO-UNDO.

CREATE SOCKET vhSocket.
vhSocket:CONNECT('-H ' + vcHost + ' -S 80')NO-ERROR.

IF vhSocket:CONNECTED() = FALSE THEN
DO:
    MESSAGE "Connection failure" VIEW-AS ALERT-BOX.

    MESSAGE ERROR-STATUS:GET-MESSAGE(1) VIEW-AS ALERT-BOX.
    RETURN.
END.
ELSE
    MESSAGE "Connect"
        VIEW-AS ALERT-BOX.

这部分代码返回消息“Connect”，因此我相信我已正确连接。 下一部分：

vhSocket:SET-READ-RESPONSE-PROCEDURE('getResponse').
RUN GetRequest.

WAIT-FOR READ-RESPONSE OF vhSocket.
vhSocket:DISCONNECT() NO-ERROR.
DELETE OBJECT vhSocket.
QUIT.

PROCEDURE GetRequest:
    DEFINE VARIABLE vcRequest AS CHARACTER.
    DEFINE VARIABLE mRequest  AS MEMPTR.

vcRequest = 'GET ' +
    '/nominatim/v1' +
    '/search.php?key=WLrMQcGao56Cb5m4ulmwZZDOegO3BkZn&format=xml&q=warszawa chałubińskiego 8&addressdetails=1&limit=50' +
    " ~r~n HTTP/1.1 ~r~n" +
    "~r~nConnection: close~r~n~r~n".

    MESSAGE vcREquest
        VIEW-AS ALERT-BOX.

    SET-SIZE(mRequest)            = 0.
    SET-SIZE(mRequest)            = LENGTH(vcRequest) + 1.
    SET-BYTE-ORDER(mRequest)      = BIG-ENDIAN.
    PUT-STRING(mRequest,1)        = vcRequest .

    vhSocket:WRITE(mRequest, 1, LENGTH(vcRequest)).
END PROCEDURE.

PROCEDURE getResponse:
    DEFINE VARIABLE vcWebResp AS CHARACTER NO-UNDO.
    DEFINE VARIABLE lSucess   AS LOGICAL   NO-UNDO.
    DEFINE VARIABLE mResponse AS MEMPTR    NO-UNDO.

    IF vhSocket:CONNECTED() = FALSE THEN 
    do:
        MESSAGE 'Not Connected' VIEW-AS ALERT-BOX.
        RETURN.
    END.
    lSucess = TRUE.

    DO WHILE vhSocket:GET-BYTES-AVAILABLE() > 0:

        SET-SIZE(mResponse) = vhSocket:GET-BYTES-AVAILABLE() + 1.
        SET-BYTE-ORDER(mResponse) = BIG-ENDIAN.
        vhSocket:READ(mResponse,1,1,vhSocket:GET-BYTES-AVAILABLE()).
        vcWebResp = vcWebResp + GET-STRING(mResponse,1).
    END.

    message vcWebResp view-as alert-box.       
END.

来自Web服务器的响应是： HTTP/1.1 400错误的\u请求 内容长度：0 连接：关闭

正如你们所看到的，大部分代码都取自互联网上的进度文档和示例。我试图以各种方式修改GET请求，但没有成功。我还尝试了一些不同的代码，但我认为其中一个是正确解决方案的指南。预期结果应与此网站上的类似：。可以找到一些关于此API的简短文档。 此代码将在UNIX服务器上运行，因此我无法使用.NET库。 任何帮助都将不胜感激

编辑：

---

请记住，键参数中显示的哈希值将很快被删除！您应该在business.mapquest.com上免费生成自己的密钥。

假设您使用的是最新版本的Progress OpenEdge（11.5+）您可以使用OpenEdge.Net.pl（在Unix上也可用）创建请求，以下（在Linux上运行）可以让您开始：

---

OpenEdge.Net.pl也只是使用ABL代码和套接字进行通信。

假设您使用的是最新版本的Progress OpenEdge（11.5+）您可以使用OpenEdge.Net.pl（在Unix上也可用）创建请求，以下（在Linux上运行）可以帮助您开始：

---

OpenEdge.Net.pl也只是使用ABL代码和套接字进行通信。

的工作原理与charm类似。非常感谢Stefan！对于具有相同问题的其他人：如果您从.sh脚本运行某个.p文件，请记住在PROPATH参数中添加到OpenEdge.Net.pl的正确路径，例如：

$DLC/tty/netlib/OpenEdge.Net.pl

。效果很好。非常感谢Stefan！对于具有相同问题的其他人：如果从.sh脚本运行某个.p文件，请记住在PROPATH参数中为OpenEdge.Net.pl添加正确的路径，例如：

$DLC/tty/netlib/OpenEdge.Net.pl

。

USING OpenEdge.Net.HTTP.RequestBuilder.
USING OpenEdge.Net.HTTP.ClientBuilder.
USING OpenEdge.Net.HTTP.IHttpRequest.
USING OpenEdge.Net.HTTP.IHttpResponse.
USING Progress.Json.ObjectModel.JsonArray.

define variable oRequest  as IHttpRequest no-undo.
define variable oResponse as IHttpResponse no-undo.
define variable oEntity   as Progress.Lang.Object no-undo.

oRequest    =   RequestBuilder
                    :Get(
                        "http://open.mapquestapi.com"
                        + "/nominatim/v1/search.php"
                        + "?key=WLrMQcGao56Cb5m4ulmwZZDOegO3BkZn"
                        + "&q=warszawa chałubińskiego 8"
                        + "&addressdetails=1"
                        + "&limit=50"
                        + "&format=json"
                    )
                    :Request
                    .
oResponse = ClientBuilder:Build():Client:Execute( oRequest ).

oEntity = oResponse:Entity.

def var lcc as longchar no-undo.

cast( oEntity, JsonArray ):Write( lcc, true ).

message string( lcc ).