Salesforce 尝试创建自定义'；收入日期'；销售人员领域

我正在尝试创建一个“收入日期””字段，该字段遵循以下逻辑。。 我希望收入日期字段根据CS团队编辑的日期字段进行计算。 字段（可编辑日期字段）为 -超期 -电子邮件开始日期 -直播日期 -预计电子邮件开始日期 -估计G L日期

第五个自动计算日期字段（预计生效日期），该字段始终具有日期值（仅当上述字段为空时使用）

所以，我想用的逻辑是

（i） 是否有超期驾驶日期？如果是，那么拿着这个，停下来如果否，则转至（ii）

（ii）是否至少存在“电子邮件开始日期”或“实时日期”中的一个？如果是，请选择其中较早的一个并停止如果否，则转至（iii）

（iii）是否至少有一个“预计电子邮件开始日期”和“预计G L日期””？如果是，请选择其中较早的一个并停止如果否，则转至（iv）

（iv）如果上述所有字段均为空，则采用预计上线日期

我知道这看起来令人困惑，但这只是因为我们计算收入的方式取决于我们的CS团队输入的日期，即我们在客户网站上的时间（与交易结束日期不同）

似乎在下面这个公式的某个地方出错了

空白值（超过行驶日期）， 如果（非（电子邮件开始日期c）和非（电子邮件开始日期c）），如果（电子邮件开始日期c<电子邮件开始日期c，电子邮件开始日期c，现场日期c）），如果（电子邮件开始日期c）和非（电子邮件开始日期c）），如果（电子邮件开始日期c和现场日期c））， 如果（不是（ISBLANK（估计的电子邮件开始日期））和&NOT（ISBLANK（估计的电子邮件开始日期））， 如果（估计的电子邮件开始日期c<估计的电子邮件开始日期c，估计的电子邮件开始日期c，估计的日期c）），

---

如果（ISBLANK（估计的电子邮件开始日期）和&ISBLANK（估计的开始日期），BLANKVALUE（估计的开始日期，估计的开始日期））

我会试着引导你完成我的设计过程；）

公式的基本形状可以是这样的：

BLANKVALUE(Over_ride_Date__c,
    IF(ISBLANK(Email_Start_Date__c) && ISBLANK(Live_Date__c),
        IF(ISBLANK(Estimated_Email_Start_Date__c) && ISBLANK(Estimated_G_L_Date__c),
            Estimated_Go_Live_Date__c,
            /* need to use Estimated_Email_Start_Date__c or Estimated_G_L_Date__c */
        ),
        /* need to use Email_Start_Date__c or Live_Date__c */
    )
)

现在应该很容易了。如果未设置“覆盖”，且“电子邮件开始日期”和“活动日期”均为空，则转到下一个变量。如果至少设置了其中一个，我们将尝试使用它们。与最后一对日期相似

---

那么现在应该是什么呢：

电子邮件和Live均已填写-以较小的数字为准

填写电子邮件，实时空-接收电子邮件

电子邮件为空，实时填写-采取实时

有几种方法可以做到这一点。位长但可读：

IF(ISBLANK(Email_Start_Date__c),
    Live_Date__c,
    IF(ISBLANK(Live_Date__c),
        Email_Start_Date__c,
        IF(Email_Start_Date__c < Live_Date__c, Email_Start_Date__c, Live_Date__c)
    )
)

---

我可以说很明显，你是一个销售天才！它工作得很好，你解释得很好。非常感谢你的努力和帮助。我必须向你学习科幻小说：）很高兴你喜欢它，而且它工作正常；）这肯定胜过了我们在上一篇文章中所做的大量评论…@eyescream我对你高质量的回答感到惊讶。我是你的粉丝：）嗨@MartinBorthiry！非常感谢你说的这些好话，但我承认这是一项很好的投资。Priyanka的问题对我来说有点像复仇女神（），我决定最好多花点时间来记录这个答案&“教”与在接下来的2个月内弹出“新评论”通知：P

IF(ISBLANK(Live_Date__c) || BLANKVALUE(Email_Start_Date__c, Live_Date__c) < Live_Date__c,
    BLANKVALUE(Email_Start_Date__c, Live_Date__c),
    Live_Date__c
)

BLANKVALUE(Over_ride_Date__c,
    IF(ISBLANK(Email_Start_Date__c) && ISBLANK(Live_Date__c),
        IF(ISBLANK(Estimated_Email_Start_Date__c) && ISBLANK(Estimated_G_L_Date__c),
            Estimated_Go_Live_Date__c,
            IF(ISBLANK(Estimated_G_L_Date__c) || BLANKVALUE(Estimated_Email_Start_Date__c, Estimated_G_L_Date__c) < Estimated_G_L_Date__c,
                BLANKVALUE(Estimated_Email_Start_Date__c, Estimated_G_L_Date__c),
                Estimated_G_L_Date__c
            )
        ),
        IF(ISBLANK(Live_Date__c) || BLANKVALUE(Email_Start_Date__c, Live_Date__c) < Live_Date__c,
            BLANKVALUE(Email_Start_Date__c, Live_Date__c),
            Live_Date__c
        )
    )
)