Sql Oracle-发送带有excel附件的电子邮件

我想用PLSQL发送excel文件和电子邮件

我使用XLSX_BUILDER_PKG创建excel文件，效果很好。它可以正确创建excel文件

然后我想将excel文件作为附件发送，我使用xlsx_builder_pkg.finish函数得到BLOB，当我发送电子邮件时，我得到了带有附件的文件，但excel文件已损坏

CREATE OR REPLACE PROCEDURE test_send_mail (p_to          IN VARCHAR2,
                                       p_from        IN VARCHAR2,
                                       p_subject     IN VARCHAR2,
                                       p_text_msg    IN VARCHAR2 DEFAULT NULL,
                                       p_attach_name IN VARCHAR2 DEFAULT NULL,
                                       p_attach_mime IN VARCHAR2 DEFAULT NULL,
                                       p_attach_blob IN BLOB DEFAULT NULL,
                                       p_smtp_host   IN VARCHAR2,
                                       p_smtp_port   IN NUMBER DEFAULT 25)
AS
  l_mail_conn   UTL_SMTP.connection;
  l_boundary    VARCHAR2(50) := '----=*#abc1234321cba#*=';
  l_step        PLS_INTEGER  := 12000; -- make sure you set a multiple of 3 not higher than 24573
BEGIN
  l_mail_conn := UTL_SMTP.open_connection(p_smtp_host, p_smtp_port);
  UTL_SMTP.helo(l_mail_conn, p_smtp_host);
  UTL_SMTP.mail(l_mail_conn, p_from);
  UTL_SMTP.rcpt(l_mail_conn, p_to);

  UTL_SMTP.open_data(l_mail_conn);

  UTL_SMTP.write_data(l_mail_conn, 'Date: ' || TO_CHAR(SYSDATE, 'DD-MON-YYYY HH24:MI:SS') || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'To: ' || p_to || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'From: ' || p_from || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'Subject: ' || p_subject || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'Reply-To: ' || p_from || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'MIME-Version: 1.0' || UTL_TCP.crlf);
  UTL_SMTP.write_data(l_mail_conn, 'Content-Type: multipart/mixed; boundary="' || l_boundary || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

  IF p_text_msg IS NOT NULL THEN
    UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);
    UTL_SMTP.write_data(l_mail_conn, 'Content-Type: text/plain; charset="iso-8859-1"' || UTL_TCP.crlf || UTL_TCP.crlf);

    UTL_SMTP.write_data(l_mail_conn, p_text_msg);
    UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);
  END IF;

  IF p_attach_name IS NOT NULL THEN
    UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);
    UTL_SMTP.write_data(l_mail_conn, 'Content-Type: ' || p_attach_mime || '; name="' || p_attach_name || '"' || UTL_TCP.crlf);
    UTL_SMTP.write_data(l_mail_conn, 'Content-Disposition: attachment; filename="' || p_attach_name || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

    FOR i IN 0 .. TRUNC((DBMS_LOB.getlength(p_attach_blob) - 1 )/l_step) LOOP
      UTL_SMTP.write_data(l_mail_conn, UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(DBMS_LOB.substr(p_attach_blob, l_step, i * l_step + 1))));
    END LOOP;

    UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);
  END IF;

  UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || '--' || UTL_TCP.crlf);
  UTL_SMTP.close_data(l_mail_conn);

  UTL_SMTP.quit(l_mail_conn);
END;

---

我使用了不同的MIME类型，但在“application/vnd.openxmlformats of icedocument.spreadsheetml.sheet”中，我得到了不完整的文件（散列信息）使用“application/vnd.ms excel”，我得到了无法打开的文件

将此文件与我得到的可用代码进行比较，您似乎缺少mime头属性内容传输编码，它应该是Base64

UTL_SMTP.write_data(l_mail_conn, 'Content-Transfer-Encoding: Base64' || UTL_TCP.crlf);

---

<> P>在附件变得非常大或代码被扩展为允许多个附件的情况下要考虑的另一件事是在打开到SMTP服务器的连接之前执行Base64编码。否则，在转换/写入过程中，您可能会因使会话长时间处于活动状态而超时。

您使用的是哪一版本的Oracle？如果是10g或更高版本，您肯定应该使用UTL_邮件包，而不是尝试使用低级组件构建自己的邮件包。它有专门处理附件的程序。然而，您的实际问题似乎是获取正确的MIME类型。在.is

xls

处有一个管道不是二进制格式，mime类型应该是

application/msexcel

和

application/vnd.openxmlformats of cedocument.spreadsheetml.sheet

mime类型用于

xlsx

数据格式？@APC，

UTL\u-MAIL

仅支持

RAW

附件，该附件限制为2000字节。这对于Excel文件是不够的。当我创建一个新的空Excel工作表时，它已经有了7.4KB，也许可以将您的代码与此代码进行比较：@APC your are right，我将其与列数据类型的限制混合在一起。无论如何，32k对于Excel文件可能不够。

UTL_SMTP.write_data(l_mail_conn, 'Content-Transfer-Encoding: Base64' || UTL_TCP.crlf);