Vbscript 复制部分条形码并写入txt文件

我有一个VBScript：

Dim Stuff, myFSO, WriteStuff, dateStamp

Stuff = "Whatever you want written"

Set myFSO = CreateObject("Scripting.FileSystemObject")
Set WriteStuff = myFSO.OpenTextFile("C:\Label_1\yourtextfile.txt", 8, True)
WriteStuff.WriteLine(var1)
WriteStuff.Close
SET WriteStuff = NOTHING
SET myFSO = NOTHING

这是放置在关键的行动。 在变量“var1”中，条形码读取器读取条形码EAN13，然后按下文本文件“C:\Label\u 1\yourtextfile.txt”的键 写入值为“var1”的新行，即条形码

2914750018247

2914750007463

再说一遍，我们什么时候扫描条形码

2914750018247

2914750007463

然后按下按钮 也将保存在文本文件中

录制将如下所示：

2914750018247
2914750007463

当然，扫描的文件“C:\Label\u 1\yourtextfile.txt”会更多，例如70个不同的代码，但总是EAN13

如何使用VBScript复制或分发5个字符，即：

01824
00746
...

---

以前在文件“C:\Label\u 1\yourtextfile.txt”中存储了所有值（每个值5个字符），但当代码（每个值5个字符）仅为70行时，这些值会相加并保存一个新的文件txt？

看看下面的示例，它处理源文件的行并将每行剪切为子字符串：

sSrc = "C:\Users\DELL\Desktop\barcode.txt"
sDst = "C:\Users\DELL\Desktop\barcode_part.txt"

' Read content of the source file
sCont = ReadTextFile(sSrc, 0) ' ASCII
' Split source file string into array of lines
aLines = Split(sCont, vbCrLf)
' Loop through each of the lines in array
For i = 0 To UBound(aLines)
    ' Change the value of the element to cut substring
    aLines(i) = Mid(aLines(i), 8, 5)
Next
' Join processed array into resulting string with line breaks
sCont = Join(aLines, vbCrLf)
' Write content to the destination file
WriteTextFile sCont, sDst, 0 ' ASCII

Function ReadTextFile(sPath, lFormat)
    ' lFormat -2 - System default, -1 - Unicode, 0 - ASCII
    With CreateObject("Scripting.FileSystemObject").OpenTextFile(sPath, 1, False, lFormat)
        ReadTextFile = ""
        If Not .AtEndOfStream Then ReadTextFile = .ReadAll
        .Close
    End With
End Function

Sub WriteTextFile(sContent, sPath, lFormat)
    ' lFormat -2 - System default, -1 - Unicode, 0 - ASCII
    With CreateObject("Scripting.FileSystemObject").OpenTextFile(sPath, 2, True, lFormat)
        .Write sContent
        .Close
    End With
End Sub

---

你好，欧米普斯。详细的内容说明，可以重新考虑吗？非常感谢您的帮助