Xml 在XSL中，如何从逗号分割字符串并将分割的子字符串替换为其他字符串？

我有这样一个XML：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <users>1, 2, 3</users>
</root>

1, 2, 3

我想将ID 1、2、3转换为各自的名称，如“Albert”、“Brown”、“Clark”，并通过“；”对它们进行编码。ID和名称是固定的，所以我只需要简单地将名称逐个映射到ID。 我想用XSLT 1.0，结果XML是这样的：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <users>Albert;Brown;Clark</users>
</root>

艾伯特；棕色；克拉克

---

我是XSL新手，有什么建议可以帮助我完成这项工作吗？非常感谢

这里实际上有两个问题：（1）如何标记字符串输入，以及（2）如何查找每个标记代码的对应名称。试着这样做：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <users>Albert;Brown;Clark</users>
</root>

XSLT1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="users">
    <user code="1">Albert</user>
    <user code="2">Brown</user>
    <user code="3">Clark</user>
</xsl:variable>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="users">
    <xsl:copy>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="."/>
        </xsl:call-template>        
    </xsl:copy>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="', '"/>
    <xsl:variable name="code" select="substring-before(concat($text, $delimiter), $delimiter)" />
    <xsl:variable name="name" select="exsl:node-set($users)/user[@code=$code]" /> 
    <xsl:choose>
        <xsl:when test="$name">
            <xsl:value-of select="$name"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="concat('No user found for code', $code)"/>
        </xsl:otherwise>
    </xsl:choose>
    <xsl:if test="contains($text, $delimiter)">
        <xsl:text>;</xsl:text>
        <!-- recursive call -->
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

艾伯特
棕色的
克拉克
;

---

注意：可以使用外部XML文档来保存代码索引并从中查找名称，而不是使用变量-例如，请参见：

这些名称来自何处？--另外，请说明是使用XSLT 1.0还是2.0。可能要遵循一些XSL教程，自己尝试一些东西，如果失败了，请添加您厌倦的代码，并解释错误/您不理解的地方。我更新了我的问题。谢谢，非常感谢。您的解决方案在我的分离环境中工作。我真的很想投你的票，但不幸的是我还没有足够的信用。在集成编译环境中运行它仍然有一些问题，但我想我已经接近它了。