将节点插入到另一个XML中，创建新元素（或更新现有元素）并对结果文档重新排序

好吧，即使我在刻苦地使用这个网站，也要发布我的第一个问题。在过去的两天里，我一直在尝试解决这个问题，但没有成功。使用这个网站上类似问题的一些答案（，，还有许多其他的），我已经取得了一些进展，但我仍然没有找到完整（正确的！）解决方案

我有一个现有的XML（file1.XML），我必须根据我正在生成的另一个XML（file2.XML）进行更新：file2的内容必须包含在file1中，遵守一些规则，我将在后面说明（文件的内容过于简化，仅显示相关元素）：

file1.xml

<?xml version="1.0" encoding="UTF-8"?>
<list>
    <decade lastyear="2012" firstyear="2011">
        <year value="2012">
            <issue year="2012"  number="242" />
            <issue year="2012"  number="241" />
            <issue year="2012"  number="240" />
        </year>
        <year value="2011">
            <issue year="2011"  number="238" />
            <issue year="2011"  number="237" />
            <issue year="2011"  number="236" />
            <issue year="2011"  number="235" />
        </year>
    </decade>
    <decade lastyear="2010" firstyear="2001">
        <year value="2010">
            <issue year="2010"  number="234" />
            <issue year="2010"  number="233" />
            <issue year="2010"  number="232" />
            <issue year="2010"  number="231" />
            <issue year="2010"  number="230" />
        </year>
        <year value="2009">
            <issue year="2009"  number="229" />
            <issue year="2009"  number="228" />
            <issue year="2009"  number="227" />
            <issue year="2009"  number="226" />
            <issue year="2009"  number="225" />
        </year>
           ...
    </decade>
 </list>

<?xml version="1.0" encoding="UTF-8"?>
<issue year="2013" number="245" />
...

...

file2.xml

<?xml version="1.0" encoding="UTF-8"?>
<list>
    <decade lastyear="2012" firstyear="2011">
        <year value="2012">
            <issue year="2012"  number="242" />
            <issue year="2012"  number="241" />
            <issue year="2012"  number="240" />
        </year>
        <year value="2011">
            <issue year="2011"  number="238" />
            <issue year="2011"  number="237" />
            <issue year="2011"  number="236" />
            <issue year="2011"  number="235" />
        </year>
    </decade>
    <decade lastyear="2010" firstyear="2001">
        <year value="2010">
            <issue year="2010"  number="234" />
            <issue year="2010"  number="233" />
            <issue year="2010"  number="232" />
            <issue year="2010"  number="231" />
            <issue year="2010"  number="230" />
        </year>
        <year value="2009">
            <issue year="2009"  number="229" />
            <issue year="2009"  number="228" />
            <issue year="2009"  number="227" />
            <issue year="2009"  number="226" />
            <issue year="2009"  number="225" />
        </year>
           ...
    </decade>
 </list>

<?xml version="1.0" encoding="UTF-8"?>
<issue year="2013" number="245" />
...

...

如前所述，文件2的内容必须插入到文件1中，并遵守一些规则：

• 如果文件1中不存在发行年份（即，如果插入当年的第一期），则必须创建（已完成）
• 新版本必须插入相应年份下（已完成）
• 必须更新“十年”以反映插入的最后一年（这一年有问题！）
• 问题元素必须按年份和编号降序排列
• 如果发行年份属于新的十年，则必须创建该十年以及相应的子年度和发行
• 在生成的文档中，所有元素必须按降序排列：十年（去年）、年（值）和发行（年和编号）

我使用的是Saxon HE 9.4.0.6，到目前为止我使用的xsl是：

XSL

<?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs"
    version="2.0">
    <xsl:output method="xml" omit-xml-declaration="yes" indent="no" encoding="UTF-8"/>

    <xsl:variable name="up" select="document('../test/ExcelStory/file2.xml')"/>
    <xsl:variable name="year" select="$up/issue/@year" />

    <xsl:template match="@* | node()" >
       <xsl:copy>
           <xsl:apply-templates select="@*|node()">
               <xsl:sort select="//issue/@year" />
            </xsl:apply-templates>
       </xsl:copy>
    </xsl:template>

    <xsl:template match="decade" >
        <xsl:copy>
            <xsl:apply-templates select="* | @*"/>
            <xsl:choose>
                <xsl:when test="year[1]/@value lt $year">
                    <year value="{$year}"/>
                </xsl:when>
            </xsl:choose>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="year[@value=$year]">
        <xsl:copy>
            <xsl:apply-templates select="* | @*"/>
            <xsl:apply-templates select="$up/*" />
        </xsl:copy>
    </xsl:template>    
</xsl:stylesheet>

此样式表假定file1.xml上的内容在读取时已排序（就是这样）

我想知道我是否必须使用“模式”进行多次传递，首先根据年份创建十年（如有必要），然后在正确的十年中插入年份（第二次传递？？），然后在正确的年份（第三次传递？？）插入问题，最后重新排列所有元素（甚至另一次传递？？）或者，如果可以更有效地进行所有必需的处理（一次或两次）。Michael Key先生建议在其他地方使用xsl:for-each进行这种处理，但我不知道在这种情况下它是否更适合（更容易？）

即使这个问题看起来与stackoverflow上的其他一些问题相似，我认为还有一些额外的复杂性，值得一读（我希望这可能是答案！）

---

如果您能就如何进行提供一些想法，或者您能为我指出其他资源，我将不胜感激

我要做的不是尝试添加新的

问题

，而是合并两个文件中的所有

问题

，然后重新创建结构

这可能不适用于您的实际用例，因为您说过：

（文件内容过于简化，只显示相关内容。） 元素）

但希望它能给你另一个视角和/或起点

您可能需要添加标识转换，并将

xsl:copy of

和

xsl:perform sort

替换为

xsl:apply templates

。您还需要更新

xsl:param

以指向外部文件

XML输入（稍加修改以增加年份并更改测试编号）

XSLT2.0

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <!--This can be changed to point to an external XML file.-->
    <xsl:param name="up">
        <issue year="2013" number="245" />
        <issue year="2002" number="135" />
        <issue year="2011" number="239" />
    </xsl:param>

    <xsl:template match="/*">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:for-each-group select="($up/issue|*/*/issue)" group-by="floor((number(@year) - 1) div 10)">
                <xsl:sort select="@year" data-type="number" order="descending"/>
                <decade lastyear="{max(current-group()/@year)}" firstyear="{min(current-group()/@year)}">
                    <xsl:for-each-group select="current-group()" group-by="@year">
                        <xsl:sort select="current-grouping-key()" data-type="number" order="descending"/>                   
                        <year value="{current-grouping-key()}">
                            <xsl:perform-sort select="current-group()">
                                <xsl:sort select="@number" data-type="number" order="descending"/>
                            </xsl:perform-sort>
                        </year>
                    </xsl:for-each-group>
                </decade>
            </xsl:for-each-group>           
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

XML输出

<list>
   <decade lastyear="2013" firstyear="2011">
      <year value="2013">
         <issue year="2013" number="245"/>
      </year>
      <year value="2012">
         <issue year="2012" number="242"/>
         <issue year="2012" number="241"/>
         <issue year="2012" number="240"/>
      </year>
      <year value="2011">
         <issue year="2011" number="239"/>
         <issue year="2011" number="238"/>
         <issue year="2011" number="237"/>
         <issue year="2011" number="236"/>
         <issue year="2011" number="235"/>
      </year>
   </decade>
   <decade lastyear="2010" firstyear="2001">
      <year value="2010">
         <issue year="2010" number="234"/>
         <issue year="2010" number="233"/>
         <issue year="2010" number="232"/>
         <issue year="2010" number="231"/>
         <issue year="2010" number="230"/>
      </year>
      <year value="2009">
         <issue year="2009" number="229"/>
         <issue year="2009" number="228"/>
         <issue year="2009" number="227"/>
         <issue year="2009" number="226"/>
         <issue year="2009" number="225"/>
      </year>
      <year value="2002">
         <issue year="2002" number="135"/>
      </year>
      <year value="2001">
         <issue year="2001" number="123"/>
      </year>
   </decade>
</list>

我做了一些修改，加入了其他元素，效果很好！谢谢@oswcab-不客气。问题也很好。