Actionscript 3 adobe flash cs3错误1119:ball.vx显示为未定义属性

下面是我制作多弹簧动画的代码。但我得到了这个错误。 ball.vx和ball.vy显示为未定义属性

我试过基思·彼得斯的“基金会”里的代码 ActionScript 3.0动画 让事情动起来！”

有人知道怎么修吗

package
{
import flash.display.Sprite;
import flash.events.Event;
public class Chain extends Sprite
{
private var ball0:Ball;
private var ball1:Ball;
private var ball2:Ball;
private var vx:Number = 0;
private var vy:Number = 0;
private var spring:Number = 0.1;
private var friction:Number = 0.8;
private var gravity:Number = 5;

public function Chain()
{
init();
}
private function init():void
{
ball0 = new Ball(20);
addChild(ball0);
ball1 = new Ball(20);
addChild(ball1);
ball2 = new Ball(20);
addChild(ball2);
addEventListener(Event.ENTER_FRAME, onEnterFrame);
}
private function onEnterFrame(event:Event):void
{
moveBall(ball0, mouseX, mouseY);
moveBall(ball1, ball0.x, ball0.y);
moveBall(ball2, ball1.x, ball1.y);
graphics.clear();
graphics.lineStyle(1);
graphics.moveTo(mouseX, mouseY);
graphics.lineTo(ball0.x, ball0.y);
graphics.lineTo(ball1.x, ball1.y);
graphics.lineTo(ball2.x, ball2.y);
}
private function moveBall(ball:Ball,
targetX:Number,
targetY:Number):void
{
ball.vx += (targetX - ball.x) * spring;
ball.vy += (targetY - ball.y) * spring;
ball.vy += gravity;
ball.vx *= friction;
ball.vy *= friction;
ball.x += ball.vx;
ball.y += ball.vy;
}
}
}

---

我想，你面临着这个问题：

源代码每个文件夹都有一个

球。因为

有些不同。ch03，ch05

Ball.as

没有属性

vx

，

vy

。您应该导入ch06或上方文件夹

Ball。因为
它们有一个
vx
，
vy
，如下所示：

package {
    import flash.display.Sprite;

    public class Ball extends Sprite {
        public var radius:Number;
        private var color:uint;
        public var vx:Number = 0;
        public var vy:Number = 0;

        public function Ball(radius:Number=40, color:uint=0xff0000) {
            this.radius = radius;
            this.color = color;
            init();
        }
        public function init():void {
            graphics.beginFill(color);
            graphics.drawCircle(0, 0, radius);
            graphics.endFill();
        }
    }
}

你能给我们看棒球课吗？可能vx和vx没有声明。
我使用的是ball.as，从没有包括vx和vy属性的章节开始。现在我找到了解决办法。谢谢你的支持。非常感谢你小小但宝贵的支持。我在浪费时间，但没能找出问题所在。另一方面，我不能离开这个。致以最良好的祝愿（布鲁斯）