Automation 是否可以自动将脚本附加到文件夹

我每天都添加新文件夹。是否可以将现有文件夹操作脚本自动链接到新文件夹？

由于某些原因，它们一直处于隐藏状态，但是系统事件脚本字典中有

将操作附加到
和
从
命令中删除操作。在雪豹时代前后，语法也发生了一些变化，这也没什么帮助。用于附加文件夹操作脚本（在Mojave中测试）的通用处理程序如下：

on run -- example
    set theFolder to (choose folder with prompt "Choose folder to attach:" default location path to desktop)
    set theScript to (choose file with prompt "Choose folder action script:" default location path to Folder Action scripts)
    tell application "System Events" to set theName to name of theScript
    attachAction(theFolder, theName)
end run

on attachAction(folderPath, scriptName)
    (*
        attach a script from "~/Library/Scripts/Folder Action Scripts" to a folder
            parameters -        folderPath [text or alias]: the folder to attach to
                                scriptName [text]: the name of the script to attach
            returns [boolean]:  true if successfully attached, false otherwise
        *)
    tell application "System Events"
        try -- enable existing folder action
            set folderName to name of disk item (folderPath as text)
            set enabled of folder action folderName to true
        on error errmess -- create new
            log errmess
            try
                make new folder action at end of folder actions with properties {enabled:true, name:folderName, path:folderPath}
            on error errmess -- oops (bad path, etc)
                log errmess
                return false
            end try
        end try
        try -- enable existing folder action script
            tell folder action folderName to set enabled of script scriptName to true
        on error errmess -- create new
            log errmess
            try
                tell folder action folderName to make new script at end of scripts with properties {name:scriptName}
            on error errmess -- oops (bad name, etc)
                log errmess
                return false
            end try
        end try
        return true
    end tell
end attachAction

是的，这是可能的。