Charts 使用libreoffice basic调整和修改所选图表的大小
我正在使用libreofficebasic编写一个宏,用于修改电子表格中选定(且仅选定)图表的样式和大小。 经过多次阅读文档和尝试,我终于找到了问题的部分解决方案: 修改所有图表样式 我通过索引选择了一个图表,并使用以下宏修改了它的样式:Charts 使用libreoffice basic调整和修改所选图表的大小,charts,resize,libreoffice,libreoffice-calc,libreoffice-basic,Charts,Resize,Libreoffice,Libreoffice Calc,Libreoffice Basic,我正在使用libreofficebasic编写一个宏,用于修改电子表格中选定(且仅选定)图表的样式和大小。 经过多次阅读文档和尝试,我终于找到了问题的部分解决方案: 修改所有图表样式 我通过索引选择了一个图表,并使用以下宏修改了它的样式: Sub ModifyChart Dim oDoc As Object Dim oChart As Object Dim aSize as new com.sun.star.awt.Size oSheet = ThisComponent.sheets(
Sub ModifyChart
Dim oDoc As Object
Dim oChart As Object
Dim aSize as new com.sun.star.awt.Size
oSheet = ThisComponent.sheets(0)
oCharts = oSheet.getCharts()
oChart = oCharts.getByIndex(0).getEmbeddedObject()
MsgBox oChart.ImplementationName
oChart.Title.String = "My title"
oChart.Title.CharColor = RGB(0,0,200)
oChart.Title.CharFontName = "Arial"
oChart.Title.CharHeight = 16
oChart.SubTitle.String = "My subtitle"
oChart.SubTitle.CharColor = RGB(0,0,200)
oChart.SubTitle.CharFontName = "Arial"
oChart.SubTitle.CharHeight = 12
oChart.Diagram.Wall.FillStyle = com.sun.star.drawing.FillStyle.SOLID
oChart.Diagram.Wall.FillColor = RGB(200,50,150)
oChart.Area.FillStyle = com.sun.star.drawing.FillStyle.SOLID
oChart.Area.FillColor = RGB(100,50,250)
aSize.Width=640
aSize.Height=400
oChart.setsize(aSize) ' Error occur at this point
End Sub
问题:它不适用于所选图表,并且我无法调整其大小。方法setsize
不适用于此类对象。我试图获取图表的父对象(框架?或形状?),但没有成功
使用ImplementationName
,我发现对象是com.sun.star.comp.sc.scshapeobj
修改所选图表大小
我使用此宏成功地修改了所选图表的大小
Sub ResizeChart
Dim oCurrSel As Object
Dim oItem As Object
Dim aSize As New com.sun.star.awt.Size
oCurrSel = ThisComponent.getCurrentSelection()
oItem = oCurrSel.getByIndex(0)
MsgBox oItem.ImplementationName
aSize.width=16000
aSize.height=12000
oItem.setsize(aSize)
End Sub
问题:我无法访问图表的其他样式。我试图找到一种方法来获取对象内容,但没有成功。我还尝试使用oItem.dbg_属性
和oItem.dbg_方法
调查对象,但没有发现任何有用的东西
使用ImplementationName
,我发现对象是com.sun.star.comp.chart2.chartmodel
我看了一下,但是我没有发现这两种物体是如何联系在一起的
是否可以使用libreoffice basic实现我想要的功能?
是否有人可以向我解释libreoffice图表对象(父母、孩子等)的层次结构以及如何处理它?是的,你完全正确-解析当前选择不是一项简单的任务 由于当前选择可能包含多种对象-单元格、单元格范围、SheetCellRanges、形状、ShapeCollection、GraphicObjectShape,甚至在某些情况下仅包含文本,解析与游戏“Miner”类似-下一步需要额外检查(或在“错误恢复下一步”的帮助下“盲目”处理错误) 你的想法使用ImplementationName标识对象通常是好的。但Andrew Pitonyak在文中写道“要确定文档类型,请查看它支持的服务……我认为这比使用getImplementationName()更安全”,我倾向于相信他 从当前选择到嵌入图表的转换可以如下所示:
Sub ModifyChartInCurrentSelection
Dim oCurrentSelection As Variant
Dim i As Long
Dim oNextElementOfSelection As Variant
Dim oEmbeddedObject As Variant
Dim oComponent As Variant
Dim aSize As New com.sun.star.awt.Size
oCurrentSelection = ThisComponent.getCurrentSelection()
If oCurrentSelection.supportsService("com.sun.star.drawing.ShapeCollection") Then
For i = 0 To oCurrentSelection.getCount()-1
oNextElementOfSelection = oCurrentSelection.getByIndex(i)
If oNextElementOfSelection.supportsService("com.sun.star.drawing.OLE2Shape") Then
Rem Size of shape (outer wrapper around the chart)
If oNextElementOfSelection.supportsService("com.sun.star.drawing.Shape") Then
aSize = oNextElementOfSelection.getSize()
aSize.Height = aSize.Height * 2 ' or any other
aSize.Width = aSize.Width / 2
oNextElementOfSelection.setSize(aSize)
EndIf
Rem Properties of EmbeddedObject
oEmbeddedObject = oNextElementOfSelection.EmbeddedObject
If Not IsEmpty(oEmbeddedObject) Then
oComponent = oEmbeddedObject.getComponent()
oComponent.getTitle().String = "Foo-bar Foo-bar Foo-bar"
Rem and other settings...
EndIf
EndIf
Next i
EndIf
End Sub