Delphi 删除在运行时创建的TLabel

如何删除已创建的标签。我尝试了

FindComponent

但失败了，我该怎么办？我应该设置其他组件的父级，如TPanel还是什么

procedure TForm1.Button1Click(Sender: TObject);
var
  lblLink: TLabel;
begin
   for i := 0 to stringtList.Count-1 do
   begin 
     lblLink := TLabel.create(self);

     with lblLink do
     begin
       name:='lblLink'+inttostr(i);
       caption:inttostr(i);
       Parent := self;
       font.style := [fsUnderline];
       cursor := crHandPoint;
       color := clBlue;
       font.Color := clBlue;
     end;
   end;
end;

---

您可以迭代Components属性，然后检查组件的名称，最后释放组件

Var
  LIndex : Integer;
  LComponent : TComponent;
begin
  for LIndex := ComponentCount-1 downto 0 do
    if StartsText('lblLink',Components[LIndex].Name) then
    begin
     LComponent:=Components[LIndex];
     FreeAndNil(LComponent);
    end;
end;

---

你不必释放它。您赋予了将其释放到带有

lblLink:=TLabel.create（self）的表单的责任。当窗体被释放时，窗体将释放标签

但是，尽管如此，您可以通过循环表单的
组件来释放它：

procedure TForm1.DeleteLabel(const LabelName: string);
var
  i: Integer;
begin
  for i := ComponentCount - 1 downto 0 do
  begin
    if Components[i] is TLabel then
      if Components[i].Name = LabelName then
      begin
        Components[i].Free;
        Break;
      end;
  end;
end;

您为每个
TLabel
都分配了
所有者
和
父项
，因此从技术上讲，您根本不需要释放它们。业主和家长都会为您处理。但是，如果您想更早地释放它们，可以在所有者的
组件
列表或父级的
控件
列表中循环，手动查找标签。一个更好的选择是保留您自己创建的标签列表，然后您可以在需要时循环浏览该列表，例如：

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  ...
  private
    Labels: TList;
    procedure FreeLabels;
  ...
  end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Labels := TList.Create;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  Labels.Free;
end;

procedure TForm1.FreeLabels;
var
  I: Integer;
begin
  for I := 0 to Labels.Count-1 do
    TLabel(Labels[I]).Free;
  Labels.Clear;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  lblLink : TLabel;
  ...
begin 
  ...
  for I := 0 to StringList.Count-1 do
  begin 
    lblLink := TLabel.Create(Self);
    try
      with lblLink do
      begin
        Name := 'lblLink' + IntToStr(i);
        Parent := Self;
        Caption := IntToStr(i);
        Font.Style := [fsUnderline];
        Cursor := crHandPoint;
        Color := clBlue;
        Font.Color := clBlue;
      end;
      Labels.Add(lblLink);
    except
      lblLink.Free;
      raise;
    end;
  end;
end;

我认为FindComponent没有理由找不到您的标签，您是否传递了像“lblLink0”这样的名称？是的，但这是个坏主意！因为标签的数量取决于
stringtList
的计数，它肯定是不稳定的