Excel 简化'；另存为CSV'；程序

当我尝试在Excel中保存.csv文件时，系统会提示我进入另外三个窗口，要求我保存一些内容。我不想费心阅读，但每次单击

No

或

Cancel

都会让人感到厌倦：

当我按下CTRL+S时，如何设置Excel以仅保存文件？

如果您习惯性地使用CTRL+S，那么重写该按键组合可能是不明智的。但是，通过将新的“另存为CSV”指定给Ctrl+Shift+S，没有什么可以阻止您扩展它的用途

放置以下内容的最佳位置将在某种程度上取决于您的个人情况，目前还没有提供多少。建议使用Personal.xlsb；嵌入启用宏的模板是另一种方法，当然，您只需将它们放入当前正在处理的工作簿中的模块代码表中即可

Sub no_training_wheels(Optional ws As Worksheet)
    Dim fn As String
    If IsEmpty(ws) Then Set ws = ActiveSheet
    With ws
        .Activate
        If CBool(Application.CountA(.Cells)) Then
            If CBool(Len(.Parent.Path)) Then
                fn = .Parent.Path & Chr(92) & Left(.Parent.Name & Chr(46), InStr(1, .Parent.Name, Chr(46)) - 1)
            Else
                fn = Application.GetSaveAsFilename( _
                    InitialFileName:=Environ("USERPROFILE") & Chr(92) & ActiveSheet.Name, _
                    fileFilter:="Comma Separated Value files (*.csv), *.csv")
                If LCase(fn) = "false" Then fn = Environ("TEMP") & Chr(92) & .Name
            End If
            Application.DisplayAlerts = False
            .Parent.SaveAs Filename:=fn, FileFormat:=xlCSV, Local:=True
            Application.DisplayAlerts = True
        End If
    End With
End Sub

Sub take_training_wheels_off()
    Application.MacroOptions Macro:="no_training_wheels", ShortcutKey:="S", _
                             Description:="Alternate Save-to-CSV without warnings"
End Sub

Sub put_training_wheels_on()
    Application.MacroOptions Macro:="no_training_wheels", ShortcutKey:="", _
                             Description:="Alternate Save-to-CSV without warnings"
End Sub

宏有一个可选的工作表参数，可将其用途扩展到其他编码例程。这还具有从“宏运行”对话框中的“宏名称：列表”中删除的效果。有两个“助手”例程可用于启用和禁用Ctrl+Shift+S组合键。使用Ctrl+s的常规保存操作不受影响

我已经从您希望避免对话和大多数交互的叙述中推断出“我不想费心阅读，但每次单击“否”或“取消”都会让人感到厌倦”，并且您乐于接受默认设置，只希望保存到CSV，并且尽可能少的交互。为此，我做了一些假设。在使用常规全权委托之前，您可能需要对其进行审查

---

我编辑了代码并制作了屏幕截图。我编辑了“注释”并粘贴了屏幕截图。您可以专门为csv文件编写宏并为其指定快捷键。是否将该宏保存在personal.xlsb中？