Gnuplot pm3d和调色板

在multiplot中，我用不同的调色板颜色绘制了3幅地图（请参见下面的代码）。 在乘法运算的第四个平方中，我希望得到其他三个部分的总和，即红色部分、蓝色部分、绿色部分，以及红色+蓝色+绿色的组合，具体取决于第14、15和16列的值

set view map; set size square
set xlabel "delta mu Al"
set ylabel "delta mu Mn"
set zlabel "fraction atomique"

set multiplot layout 2,2
set title "Fer"
set palette defined (0 "white", 1 "red")
splot "res700.dat" u 3:4:($16/3456) t "Fe"  with pm3d

set title "Alu"
set palette defined (0 "white", 1 "green")
splot "res700.dat" u 3:4:($14/3456) t "Fe"  with pm3d

set title "Mn"
set palette defined (0 "white", 1 "blue")
splot "res700.dat" u 3:4:($15/3456) t "Fe"  with pm3d

unset multiplot

---

使用

rgb变量

。以黑色作为无信号颜色，可提供：

set view map; set size square
set xlabel "delta mu Al"
set ylabel "delta mu Mn"
set zlabel "fraction atomique"

set isosample 100
Fe(x,y)=x*y
Al(x,y)=(1-x)*y
Mn(x,y)=x*(1-y)

set multiplot layout 2,2
set title "Fer"
set palette defined (0 "black", 1 "red")
splot [0:1][0:1] "++" u 1:2:(Fe($1,$2)) t "Fe"  with pm3d

set title "Alu"
set palette defined (0 "black", 1 "green")
splot [0:1][0:1] "++" u 1:2:(Al($1,$2)) t "Al"  with pm3d

set title "Mn"
set palette defined (0 "black", 1 "blue")
splot [0:1][0:1] "++" u 1:2:(Mn($1,$2)) t "Mn"  with pm3d

set title ""
rgb(r,g,b) = 65536 * int(255*r) + 256 * int(255*g) + int(255*b)
unset colorbox
splot [0:1][0:1] "++" u 1:2:(rgb(Fe($1,$2),Al($1,$2),Mn($1,$2))) t "" with pm3d lc rgb variable

unset multiplot

---

我想要白色作为无信号。因此，我将

rgb

函数更改为：

rgb（r，g，b）=65536*int（255*r）+256*int（255*g）+int（255*b）

您未设置颜色栏。是否可以绘制一个三角形：一个红色角标记为“Fer”，一个绿色角标记为“Alu”，最后一个角标记为“Mn”？是的，您可以在multiplot内创建一个单独的绘图，其坐标应明确输入。为了清楚起见，如果你需要帮助，你应该问一个单独的问题。